Synnefo » Ganeti Instance Image

AC_PREREQ(2.59)

AC_INIT(ganeti-instance-image, 0.5.1, lance@osuosl.org)

AC_CONFIG_AUX_DIR(autotools)

AC_CONFIG_SRCDIR(configure)

AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])

#Handle --disable-windows-support

AC_ARG_ENABLE(windows_support,

              AS_HELP_STRING([--disable-windows-support],

                             [disable Windows support]),

                             , enable_windows_support=yes)

AM_CONDITIONAL(WINSUPPORT, [test "x$enable_windows_support" = "xyes"])

# --with-os-dir=...

AC_ARG_WITH([os-dir],

  [AS_HELP_STRING([--with-os-dir=DIR],

    [top-level OS directory under which to install]

    [ (default is $datadir/ganeti/os)]

  )],

  [os_dir="$withval"],

  [os_dir="$datadir/ganeti/os"])

AC_SUBST(OS_DIR, $os_dir)

# --with-os-name=...

AC_ARG_WITH([os-name],

  [AS_HELP_STRING([--with-os-name=OSNAME],

    [the name of the OS provider which will be the directory to install its files]

    [ (default is image)]

  )],

  [os_name="$withval"],

  [os_name="image"])

AC_SUBST(OS_NAME, $os_name)

# --with-default-dir=...

AC_ARG_WITH([default-dir],

  [AS_HELP_STRING([--with-default-dir=DIR],

    [top-level default config directory under which to install]

    [ (default is $sysconfdir/default)]

  )],

  [default_dir="$withval"],

  [default_dir="$sysconfdir/default"])

AC_SUBST(DEFAULT_DIR, $default_dir)

# Check common programs

AC_PROG_INSTALL

AC_PROG_LN_S

AC_PROG_AWK

AC_PROG_MKDIR_P

AC_PATH_PROG(RESTORE, [restore], [], [$PATH:/usr/sbin:/sbin])

if test -z "$RESTORE" ; then

  AC_MSG_ERROR([restore not found in $PATH])

fi

AC_PATH_PROG(DUMP, [dump], [], [$PATH:/usr/sbin:/sbin])

if test -z "$DUMP" ; then

  AC_MSG_ERROR([dump not found in $PATH])

fi

AC_PATH_PROG(LOSETUP, [losetup], [], [$PATH:/usr/sbin:/sbin])

if test -z "$LOSETUP" ; then

  AC_MSG_ERROR([losetup not found in $PATH])

fi

AC_PATH_PROG(KPARTX, [kpartx], [], [$PATH:/usr/sbin:/sbin])

if test -z "$KPARTX" ; then

  AC_MSG_ERROR([kpartx not found in $PATH])

fi

AC_PATH_PROG(SFDISK, [sfdisk], [], [$PATH:/usr/sbin:/sbin])

if test -z "$SFDISK" ; then

  AC_MSG_ERROR([sfdisk not found in $PATH])

fi

AC_PATH_PROG(QEMU_IMG, [qemu-img], [], [$PATH:/usr/sbin:/sbin])

if test -z "$QEMU_IMG" ; then

  AC_MSG_ERROR([qemu-img not found in $PATH])

fi

if test "x$enable_windows_support" = "xyes"

then

    AC_PATH_PROG(NTFSMOUNT, [ntfsmount], [], [$PATH:/usr/sbin:/sbin])

    if test -z "$NTFSMOUNT" ; then

        AC_MSG_ERROR([ntfsmount is needed for Windows but not found in $PATH]

        [To disable windows support run with --disable-windows-support])

    fi

    AC_PATH_PROG(NTFSCLONE, [ntfsclone], [], [$PATH:/usr/sbin:/sbin])

    if test -z "$NTFSCLONE" ; then

        AC_MSG_ERROR([ntfsclone is needed for Windows but not found in $PATH]

        [To disable windows support run with --disable-windows-support])

    fi

    AC_PATH_PROG(NTFSRESIZE, [ntfsresize], [], [$PATH:/usr/sbin:/sbin])

    if test -z "$NTFSRESIZE" ; then

        AC_MSG_ERROR([ntfsresize is needed for Windows but not found in $PATH]

        [To disable windows support run with --disable-windows-support])

    fi

    AC_PATH_PROG(XMLSTARLET, [xmlstarlet], [], [$PATH:/usr/sbin:/sbin])

    if test -z "$XMLSTARLET" ; then

        AC_MSG_ERROR([xmlstarlet is needed for Windows but not found in $PATH]

        [To disable windows support run with --disable-windows-support])

    fi

    AC_PATH_PROG(INSTALL_MBR, [install-mbr], [], [$PATH:/usr/sbin:/sbin])

    if test -z "$INSTALL_MBR" ; then

        AC_MSG_ERROR([install-mbr is needed for Windows but not found in $PATH]

        [To disable windows support run with --disable-windows-support])

    fi

fi

AC_CONFIG_FILES([

    Makefile

    common.sh

])

AC_OUTPUT