configure: check for socat and its escape feature

[ganeti-local] / configure.ac

diff --git a/configure.ac b/configure.ac
index 3df6caa..c681e03 100644 (file)
--- a/configure.ac
+++ b/configure.ac
@@ -1,8 +1,8 @@
 # Configure script for Ganeti
 m4_define([gnt_version_major], [2])
-m4_define([gnt_version_minor], [0])
+m4_define([gnt_version_minor], [1])
 m4_define([gnt_version_revision], [0])
-m4_define([gnt_version_suffix], [~alpha1])
+m4_define([gnt_version_suffix], [~beta2])
 m4_define([gnt_version_full],
           m4_format([%d.%d.%d%s],
                     gnt_version_major, gnt_version_minor,
@@ -61,6 +61,15 @@ AC_ARG_WITH([iallocator-search-path],
   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
 
+# --with-xen-bootloader=...
+AC_ARG_WITH([xen-bootloader],
+  [AS_HELP_STRING([--with-xen-bootloader=PATH],
+    [bootloader for Xen hypervisor (default is empty)]
+  )],
+  [xen_bootloader="$withval"],
+  [xen_bootloader=])
+AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
+
 # --with-xen-kernel=...
 AC_ARG_WITH([xen-kernel],
   [AS_HELP_STRING([--with-xen-kernel=PATH],
@@ -99,15 +108,40 @@ AC_ARG_WITH([kvm-path],
   [kvm_path="/usr/bin/kvm"])
 AC_SUBST(KVM_PATH, $kvm_path)
 
+# --with-kvm-migration-port=...
+AC_ARG_WITH([kvm-migration-port],
+  [AS_HELP_STRING([--with-kvm-migration-port=PORT],
+    [tcp port used for kvm instance live migration]
+    [ (default is 8102)]
+  )],
+  [kvm_migration_port="$withval"],
+  [kvm_migration_port="8102"])
+AC_SUBST(KVM_MIGRATION_PORT, $kvm_migration_port)
+
 # --with-socat-path=...
 AC_ARG_WITH([socat-path],
   [AS_HELP_STRING([--with-socat-path=PATH],
     [absolute path to the socat binary]
-    [ (default is /usr/bin/socat)]
+    [ (default is to let configure search for it)]
+  )],
+  [SOCAT="$withval"],
+  [])
+
+AC_ARG_WITH([socat-escape],
+  [AS_HELP_STRING([--with-socat-escape],
+    [enable escape functionality found in newer socat])],
+  [],
+  [check_socat_escape=yes])
+
+# ---with-lvm-stripecount=...
+AC_ARG_WITH([lvm-stripecount],
+  [AS_HELP_STRING([--with-lvm-stripecount=NUM],
+    [the number of stripes to use for LVM volumes]
+    [ (default is 1)]
   )],
-  [socat_path="$withval"],
-  [socat_path="/usr/bin/socat"])
-AC_SUBST(SOCAT_PATH, $socat_path)
+  [lvm_stripecount="$withval"],
+  [lvm_stripecount="1"])
+AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 
 # Check common programs
 AC_PROG_INSTALL
@@ -118,29 +152,22 @@ AC_ARG_VAR(DOCBOOK2MAN, [docbook2man path])
 AC_PATH_PROG(DOCBOOK2MAN, [docbook2man], [])
 if test -z "$DOCBOOK2MAN"
 then
-  AC_MSG_ERROR([docbook2man not found])
-fi
-
-AC_ARG_VAR(DOCBOOK2PDF, [docbook2pdf path])
-AC_PATH_PROG(DOCBOOK2PDF, [docbook2pdf], [])
-if test -z "$DOCBOOK2PDF"
-then
-  AC_MSG_ERROR([docbook2pdf not found])
+  AC_MSG_WARN([docbook2man not found, man pages rebuild will not be possible])
 fi
 
 AC_ARG_VAR(DOCBOOK2HTML, [docbook2html path])
 AC_PATH_PROG(DOCBOOK2HTML, [docbook2html], [])
 if test -z "$DOCBOOK2HTML"
 then
-  AC_MSG_ERROR([docbook2html not found])
+  AC_MSG_WARN([docbook2html not found, man pages rebuild will not be possible])
 fi
 
-# Check for rst programs
-AC_ARG_VAR(RST2HTML, [rst2html path])
-AC_PATH_PROG(RST2HTML, [rst2html], [])
-if test -z "$RST2HTML"
+# Check for python-sphinx
+AC_ARG_VAR(SPHINX, [sphinx-build path])
+AC_PATH_PROG(SPHINX, [sphinx-build], [])
+if test -z "$SPHINX"
 then
-  AC_MSG_ERROR([rst2html not found])
+  AC_MSG_WARN([sphinx-build not found, documentation rebuild will not be possible])
 fi
 
 # Check for graphviz (dot)
@@ -148,7 +175,33 @@ AC_ARG_VAR(DOT, [dot path])
 AC_PATH_PROG(DOT, [dot], [])
 if test -z "$DOT"
 then
-  AC_MSG_ERROR([dot (from the graphviz suite) not found])
+  AC_MSG_WARN([dot (from the graphviz suite) not found, documentation rebuild not possible])
+fi
+
+if test -z "$SOCAT" -a -n "$check_socat_escape"
+then
+AC_CACHE_CHECK([for socat with the escape feature], [ac_cv_path_SOCAT],
+  [AC_PATH_PROGS_FEATURE_CHECK(SOCAT, [socat],
+            [[$ac_path_SOCAT -hh | grep -q escape \
+              && ac_cv_path_SOCAT=$ac_path_SOCAT \
+                 SOCAT=$ac_cv_path_SOCAT \
+                 with_socat_escape=yes ac_path_SOCAT_found=:]],
+            [AC_MSG_WARN([no escape feature found])])])
+fi
+
+if test -z "$SOCAT"
+then
+AC_CACHE_CHECK([for socat], [ac_cv_path_SOCAT],
+  [AC_PATH_PROGS_FEATURE_CHECK(SOCAT, [socat],
+            [[ac_cv_path_SOCAT=$ac_path_SOCAT \
+              SOCAT=$ac_cv_path_SOCAT ac_path_SOCAT_found=:]],
+            [AC_MSG_ERROR([socat not found])])])
+fi
+
+AC_SUBST([SOCAT_PATH], [$SOCAT])
+if test "x$with_socat_escape" = xyes
+then
+  AC_SUBST([SOCAT_ESCAPE], [1])
 fi
 
 # Check for Python
@@ -157,6 +210,7 @@ AM_PATH_PYTHON(2.4)
 AC_PYTHON_MODULE(OpenSSL, t)
 AC_PYTHON_MODULE(simplejson, t)
 AC_PYTHON_MODULE(pyparsing, t)
+AC_PYTHON_MODULE(pyinotify, t)
 
 AC_CONFIG_FILES([ Makefile ])