code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [1])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~rc5])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-os-search-path=...
  43 # do a bit of black sed magic to for quoting of the strings in the list
  44 AC_ARG_WITH([os-search-path],
  45   [AS_HELP_STRING([--with-os-search-path=LIST],
  46     [comma separated list of directories to]
  47     [ search for OS images (default is /srv/ganeti/os)]
  48   )],
  49   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  50   [os_search_path="'/srv/ganeti/os'"])
  51 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  52
  53 # --with-iallocator-search-path=...
  54 # do a bit of black sed magic to for quoting of the strings in the list
  55 AC_ARG_WITH([iallocator-search-path],
  56   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  57     [comma separated list of directories to]
  58     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  59   )],
  60   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  61   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  62 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  63
  64 # --with-xen-bootloader=...
  65 AC_ARG_WITH([xen-bootloader],
  66   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  67     [bootloader for Xen hypervisor (default is empty)]
  68   )],
  69   [xen_bootloader="$withval"],
  70   [xen_bootloader=])
  71 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  72
  73 # --with-xen-kernel=...
  74 AC_ARG_WITH([xen-kernel],
  75   [AS_HELP_STRING([--with-xen-kernel=PATH],
  76     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-2.6-xenU)]
  77   )],
  78   [xen_kernel="$withval"],
  79   [xen_kernel="/boot/vmlinuz-2.6-xenU"])
  80 AC_SUBST(XEN_KERNEL, $xen_kernel)
  81
  82 # --with-xen-initrd=...
  83 AC_ARG_WITH([xen-initrd],
  84   [AS_HELP_STRING([--with-xen-initrd=PATH],
  85     [DomU initrd image for Xen hypervisor (default is /boot/initrd-2.6-xenU)]
  86   )],
  87   [xen_initrd="$withval"],
  88   [xen_initrd="/boot/initrd-2.6-xenU"])
  89 AC_SUBST(XEN_INITRD, $xen_initrd)
  90
  91 # --with-file-storage-dir=...
  92 AC_ARG_WITH([file-storage-dir],
  93   [AS_HELP_STRING([--with-file-storage-dir=PATH],
  94     [directory to store files for file-based backend]
  95     [ (default is /srv/ganeti/file-storage)]
  96   )],
  97   [file_storage_dir="$withval"],
  98   [file_storage_dir="/srv/ganeti/file-storage"])
  99 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 100
 101 # --with-kvm-path=...
 102 AC_ARG_WITH([kvm-path],
 103   [AS_HELP_STRING([--with-kvm-path=PATH],
 104     [absolute path to the kvm binary]
 105     [ (default is /usr/bin/kvm)]
 106   )],
 107   [kvm_path="$withval"],
 108   [kvm_path="/usr/bin/kvm"])
 109 AC_SUBST(KVM_PATH, $kvm_path)
 110
 111 # --with-lvm-stripecount=...
 112 AC_ARG_WITH([lvm-stripecount],
 113   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 114     [the number of stripes to use for LVM volumes]
 115     [ (default is 1)]
 116   )],
 117   [lvm_stripecount="$withval"],
 118   [lvm_stripecount="1"])
 119 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 120
 121 # --enable-drbd-barriers
 122 AC_ARG_ENABLE([drbd-barriers],
 123   [AS_HELP_STRING([--enable-drbd-barriers],
 124     [enable the DRBD barrier functionality (>= 8.0.12) (default: enabled)])],
 125   [[if test "$enableval" != no; then
 126       DRBD_BARRIERS=True
 127     else
 128       DRBD_BARRIERS=False
 129     fi
 130   ]],
 131   [DRBD_BARRIERS=True])
 132 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 133
 134 # --enable-syslog[=no/yes/only]
 135 AC_ARG_ENABLE([syslog],
 136   [AS_HELP_STRING([--enable-syslog],
 137     [enable use of syslog (default: disabled), one of no/yes/only])],
 138   [[case "$enableval" in
 139       no)
 140         SYSLOG=no
 141         ;;
 142       yes)
 143         SYSLOG=yes
 144         ;;
 145       only)
 146         SYSLOG=only
 147         ;;
 148       *)
 149         SYSLOG=
 150         ;;
 151     esac
 152   ]],
 153   [SYSLOG=no])
 154
 155 if test -z "$SYSLOG"
 156 then
 157   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 158 fi
 159 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 160
 161 # Check common programs
 162 AC_PROG_INSTALL
 163 AC_PROG_LN_S
 164
 165 # Check for docbook programs
 166 AC_ARG_VAR(DOCBOOK2MAN, [docbook2man path])
 167 AC_PATH_PROG(DOCBOOK2MAN, [docbook2man], [])
 168 if test -z "$DOCBOOK2MAN"
 169 then
 170   AC_MSG_WARN([docbook2man not found, man pages rebuild will not be possible])
 171 fi
 172
 173 AC_ARG_VAR(DOCBOOK2HTML, [docbook2html path])
 174 AC_PATH_PROG(DOCBOOK2HTML, [docbook2html], [])
 175 if test -z "$DOCBOOK2HTML"
 176 then
 177   AC_MSG_WARN([docbook2html not found, man pages rebuild will not be possible])
 178 fi
 179
 180 # Check for python-sphinx
 181 AC_ARG_VAR(SPHINX, [sphinx-build path])
 182 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 183 if test -z "$SPHINX"
 184 then
 185   AC_MSG_WARN([sphinx-build not found, documentation rebuild will not be possible])
 186 fi
 187
 188 # Check for graphviz (dot)
 189 AC_ARG_VAR(DOT, [dot path])
 190 AC_PATH_PROG(DOT, [dot], [])
 191 if test -z "$DOT"
 192 then
 193   AC_MSG_WARN([dot (from the graphviz suite) not found, documentation rebuild not possible])
 194 fi
 195
 196 # Check for pylint
 197 AC_ARG_VAR(PYLINT, [pylint path])
 198 AC_PATH_PROG(PYLINT, [pylint], [])
 199 if test -z "$PYLINT"
 200 then
 201   AC_MSG_WARN([pylint not found, checking code will not be possible])
 202 fi
 203
 204 # Check for socat
 205 AC_ARG_VAR(SOCAT, [socat path])
 206 AC_PATH_PROG(SOCAT, [socat], [])
 207 if test -z "$SOCAT"
 208 then
 209   AC_MSG_ERROR([socat not found])
 210 fi
 211
 212 SOCAT_USE_ESCAPE=
 213 AC_ARG_ENABLE([socat-escape],
 214   [AS_HELP_STRING([--enable-socat-escape],
 215     [use escape functionality available in socat >= 1.7 (default: detect
 216      automatically)])],
 217   [[if test "$enableval" = yes; then
 218       SOCAT_USE_ESCAPE=True
 219     else
 220       SOCAT_USE_ESCAPE=False
 221     fi
 222   ]])
 223
 224 if test -z "$SOCAT_USE_ESCAPE"
 225 then
 226   if $SOCAT -hh | grep -w -q escape; then
 227     SOCAT_USE_ESCAPE=True
 228   else
 229     SOCAT_USE_ESCAPE=False
 230   fi
 231 fi
 232
 233 AC_SUBST(SOCAT_USE_ESCAPE)
 234
 235 # Check for Python
 236 AM_PATH_PYTHON(2.4)
 237
 238 AC_PYTHON_MODULE(OpenSSL, t)
 239 AC_PYTHON_MODULE(simplejson, t)
 240 AC_PYTHON_MODULE(pyparsing, t)
 241 AC_PYTHON_MODULE(pyinotify, t)
 242
 243 AC_CONFIG_FILES([ Makefile ])
 244
 245 AC_OUTPUT