code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [6])
   4 m4_define([gnt_version_revision], [1])
   5 m4_define([gnt_version_suffix], [])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-os-search-path=...
  53 # do a bit of black sed magic to for quoting of the strings in the list
  54 AC_ARG_WITH([os-search-path],
  55   [AS_HELP_STRING([--with-os-search-path=LIST],
  56     [comma separated list of directories to]
  57     [ search for OS images (default is /srv/ganeti/os)]
  58   )],
  59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  60   [os_search_path="'/srv/ganeti/os'"])
  61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  62
  63 # --with-iallocator-search-path=...
  64 # do a bit of black sed magic to for quoting of the strings in the list
  65 AC_ARG_WITH([iallocator-search-path],
  66   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  67     [comma separated list of directories to]
  68     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  69   )],
  70   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  71   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  72 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  73
  74 # --with-xen-bootloader=...
  75 AC_ARG_WITH([xen-bootloader],
  76   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  77     [bootloader for Xen hypervisor (default is empty)]
  78   )],
  79   [xen_bootloader="$withval"],
  80   [xen_bootloader=])
  81 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  82
  83 # --with-xen-kernel=...
  84 AC_ARG_WITH([xen-kernel],
  85   [AS_HELP_STRING([--with-xen-kernel=PATH],
  86     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
  87   )],
  88   [xen_kernel="$withval"],
  89   [xen_kernel="/boot/vmlinuz-3-xenU"])
  90 AC_SUBST(XEN_KERNEL, $xen_kernel)
  91
  92 # --with-xen-initrd=...
  93 AC_ARG_WITH([xen-initrd],
  94   [AS_HELP_STRING([--with-xen-initrd=PATH],
  95     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
  96   )],
  97   [xen_initrd="$withval"],
  98   [xen_initrd="/boot/initrd-3-xenU"])
  99 AC_SUBST(XEN_INITRD, $xen_initrd)
 100
 101 # --with-xen-cmd=...
 102 AC_ARG_WITH([xen-cmd],
 103   [AS_HELP_STRING([--with-xen-cmd=CMD],
 104     [Sets the xen cli interface command (default is xm)]
 105   )],
 106   [xen_cmd="$withval"],
 107   [xen_cmd="xm"])
 108 AC_SUBST(XEN_CMD, $xen_cmd)
 109
 110 if ! test "$XEN_CMD" = xl -o "$XEN_CMD" = xm; then
 111   AC_MSG_ERROR([Unsupported xen command specified])
 112 fi
 113
 114 # --with-kvm-kernel=...
 115 AC_ARG_WITH([kvm-kernel],
 116   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 117     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 118   )],
 119   [kvm_kernel="$withval"],
 120   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 121 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 122
 123 # --with-file-storage-dir=...
 124 AC_ARG_WITH([file-storage-dir],
 125   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 126     [directory to store files for file-based backend]
 127     [ (default is /srv/ganeti/file-storage)]
 128   )],
 129   [[file_storage_dir="$withval";
 130     if test "$withval" != no; then
 131       enable_file_storage=True
 132     else
 133       enable_file_storage=False
 134     fi
 135   ]],
 136   [[file_storage_dir="/srv/ganeti/file-storage";
 137     enable_file_storage="True"]])
 138 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 139 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 140
 141 # --with-shared-file-storage-dir=...
 142 AC_ARG_WITH([shared-file-storage-dir],
 143   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 144     [directory to store files for shared file-based backend]
 145     [ (default is /srv/ganeti/shared-file-storage)]
 146   )],
 147   [[shared_file_storage_dir="$withval";
 148     if test "$withval" != no; then
 149       enable_shared_file_storage=True
 150     else
 151       enable_shared_file_storage=False
 152     fi
 153   ]],
 154   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 155     enable_shared_file_storage="True"]])
 156 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 157 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 158
 159 # --with-kvm-path=...
 160 AC_ARG_WITH([kvm-path],
 161   [AS_HELP_STRING([--with-kvm-path=PATH],
 162     [absolute path to the kvm binary]
 163     [ (default is /usr/bin/kvm)]
 164   )],
 165   [kvm_path="$withval"],
 166   [kvm_path="/usr/bin/kvm"])
 167 AC_SUBST(KVM_PATH, $kvm_path)
 168
 169 # --with-lvm-stripecount=...
 170 AC_ARG_WITH([lvm-stripecount],
 171   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 172     [the default number of stripes to use for LVM volumes]
 173     [ (default is 1)]
 174   )],
 175   [lvm_stripecount="$withval"],
 176   [lvm_stripecount="1"])
 177 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 178
 179 # --with-ssh-login-user=...
 180 AC_ARG_WITH([ssh-login-user],
 181   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 182     [user to use for SSH logins within the cluster (default is root)]
 183   )],
 184   [ssh_login_user="$withval"],
 185   [ssh_login_user=root])
 186 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 187
 188 # --with-ssh-console-user=...
 189 AC_ARG_WITH([ssh-console-user],
 190   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 191     [user to use for SSH logins to access instance consoles (default is root)]
 192   )],
 193   [ssh_console_user="$withval"],
 194   [ssh_console_user=root])
 195 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 196
 197 # --with-default-user=...
 198 AC_ARG_WITH([default-user],
 199   [AS_HELP_STRING([--with-default-user=USERNAME],
 200     [default user for daemons]
 201     [ (default is to run all daemons as root)]
 202   )],
 203   [user_default="$withval"],
 204   [user_default=root])
 205
 206 # --with-default-group=...
 207 AC_ARG_WITH([default-group],
 208   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 209     [default group for daemons]
 210     [ (default is to run all daemons under group root)]
 211   )],
 212   [group_default="$withval"],
 213   [group_default=root])
 214
 215 # --with-user-prefix=...
 216 AC_ARG_WITH([user-prefix],
 217   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 218     [prefix for daemon users]
 219     [ (default is to run all daemons as root; use --with-default-user]
 220     [ to change the default)]
 221   )],
 222   [user_masterd="${withval}masterd";
 223    user_rapi="${withval}rapi";
 224    user_confd="${withval}confd";
 225    user_noded="$user_default"],
 226   [user_masterd="$user_default";
 227    user_rapi="$user_default";
 228    user_confd="$user_default";
 229    user_noded="$user_default"])
 230 AC_SUBST(MASTERD_USER, $user_masterd)
 231 AC_SUBST(RAPI_USER, $user_rapi)
 232 AC_SUBST(CONFD_USER, $user_confd)
 233 AC_SUBST(NODED_USER, $user_noded)
 234
 235 # --with-group-prefix=...
 236 AC_ARG_WITH([group-prefix],
 237   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 238     [prefix for daemon POSIX groups]
 239     [ (default is to run all daemons under group root; use]
 240     [ --with-default-group to change the default)]
 241   )],
 242   [group_rapi="${withval}rapi";
 243    group_admin="${withval}admin";
 244    group_confd="${withval}confd";
 245    group_masterd="${withval}masterd";
 246    group_noded="$group_default";
 247    group_daemons="${withval}daemons";],
 248   [group_rapi="$group_default";
 249    group_admin="$group_default";
 250    group_confd="$group_default";
 251    group_masterd="$group_default";
 252    group_noded="$group_default";
 253    group_daemons="$group_default"])
 254 AC_SUBST(RAPI_GROUP, $group_rapi)
 255 AC_SUBST(ADMIN_GROUP, $group_admin)
 256 AC_SUBST(CONFD_GROUP, $group_confd)
 257 AC_SUBST(MASTERD_GROUP, $group_masterd)
 258 AC_SUBST(NODED_GROUP, $group_noded)
 259 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 260
 261 # Print the config to the user
 262 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 263 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 264 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 265 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 266 AC_MSG_NOTICE([Group for clients is $group_admin])
 267
 268 # --enable-drbd-barriers
 269 AC_ARG_ENABLE([drbd-barriers],
 270   [AS_HELP_STRING([--enable-drbd-barriers],
 271     [enable by default the DRBD barriers functionality (>= 8.0.12) (default: enabled)])],
 272   [[if test "$enableval" != no; then
 273       DRBD_BARRIERS=n
 274       DRBD_NO_META_FLUSH=False
 275     else
 276       DRBD_BARRIERS=bf
 277       DRBD_NO_META_FLUSH=True
 278     fi
 279   ]],
 280   [DRBD_BARRIERS=n
 281    DRBD_NO_META_FLUSH=False
 282   ])
 283 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 284 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 285
 286 # --enable-syslog[=no/yes/only]
 287 AC_ARG_ENABLE([syslog],
 288   [AS_HELP_STRING([--enable-syslog],
 289     [enable use of syslog (default: disabled), one of no/yes/only])],
 290   [[case "$enableval" in
 291       no)
 292         SYSLOG=no
 293         ;;
 294       yes)
 295         SYSLOG=yes
 296         ;;
 297       only)
 298         SYSLOG=only
 299         ;;
 300       *)
 301         SYSLOG=
 302         ;;
 303     esac
 304   ]],
 305   [SYSLOG=no])
 306
 307 if test -z "$SYSLOG"
 308 then
 309   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 310 fi
 311 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 312
 313 # --with-disk-separator=...
 314 AC_ARG_WITH([disk-separator],
 315   [AS_HELP_STRING([--with-disk-separator=STRING],
 316     [Disk index separator, useful if the default of ':' is handled]
 317     [ specially by the hypervisor]
 318   )],
 319   [disk_separator="$withval"],
 320   [disk_separator=":"])
 321 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 322
 323 # Check common programs
 324 AC_PROG_INSTALL
 325 AC_PROG_LN_S
 326
 327 # Check for the ip command
 328 AC_ARG_VAR(IP_PATH, [ip path])
 329 AC_PATH_PROG(IP_PATH, [ip], [])
 330 if test -z "$IP_PATH"
 331 then
 332   AC_MSG_ERROR([ip command not found])
 333 fi
 334
 335 # Check for pandoc
 336 AC_ARG_VAR(PANDOC, [pandoc path])
 337 AC_PATH_PROG(PANDOC, [pandoc], [])
 338 if test -z "$PANDOC"
 339 then
 340   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 341 fi
 342
 343 # Check for python-sphinx
 344 AC_ARG_VAR(SPHINX, [sphinx-build path])
 345 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 346 if test -z "$SPHINX"
 347 then
 348   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 349                             not be possible]))
 350 fi
 351
 352 # Check for graphviz (dot)
 353 AC_ARG_VAR(DOT, [dot path])
 354 AC_PATH_PROG(DOT, [dot], [])
 355 if test -z "$DOT"
 356 then
 357   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 358                             documentation rebuild not possible]))
 359 fi
 360
 361 # Check for pylint
 362 AC_ARG_VAR(PYLINT, [pylint path])
 363 AC_PATH_PROG(PYLINT, [pylint], [])
 364 if test -z "$PYLINT"
 365 then
 366   AC_MSG_WARN([pylint not found, checking code will not be possible])
 367 fi
 368
 369 # Check for pep8
 370 AC_ARG_VAR(PEP8, [pep8 path])
 371 AC_PATH_PROG(PEP8, [pep8], [])
 372 if test -z "$PEP8"
 373 then
 374   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 375 fi
 376 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 377
 378 # Check for python-coverage
 379 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 380 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 381 if test -z "$PYCOVERAGE"
 382 then
 383   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 384                             Python test coverage will not be possible]))
 385 fi
 386
 387 # Check for socat
 388 AC_ARG_VAR(SOCAT, [socat path])
 389 AC_PATH_PROG(SOCAT, [socat], [])
 390 if test -z "$SOCAT"
 391 then
 392   AC_MSG_ERROR([socat not found])
 393 fi
 394
 395 # Check for qemu-img
 396 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 397 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 398 if test -z "$QEMUIMG_PATH"
 399 then
 400   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 401 fi
 402
 403 # --enable-htools-rapi
 404 HTOOLS_RAPI=
 405 AC_ARG_ENABLE([htools-rapi],
 406         [AS_HELP_STRING([--enable-htools-rapi],
 407         [enable use of curl in the Haskell code (default: check)])],
 408         [],
 409         [enable_htools_rapi=check])
 410
 411 # --enable-confd
 412 ENABLE_CONFD=
 413 AC_ARG_ENABLE([confd],
 414   [AS_HELP_STRING([--enable-confd],
 415   [enable the ganeti-confd daemon (default: check)])],
 416   [],
 417   [enable_confd=check])
 418
 419 # Check for ghc
 420 AC_ARG_VAR(GHC, [ghc path])
 421 AC_PATH_PROG(GHC, [ghc], [])
 422 if test -z "$GHC"; then
 423   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 424 fi
 425
 426 # Check for ghc-pkg
 427 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 428 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 429 if test -z "$GHC_PKG"; then
 430   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 431 fi
 432
 433 # check for modules, first custom/special checks
 434 AC_MSG_NOTICE([checking for required haskell modules])
 435 HTOOLS_NOCURL=-DNO_CURL
 436 if test "$enable_htools_rapi" != "no"; then
 437   AC_GHC_PKG_CHECK([curl], [HTOOLS_NOCURL=], [])
 438   if test -n "$HTOOLS_NOCURL"; then
 439     if test "$enable_htools_rapi" = "check"; then
 440       AC_MSG_WARN(m4_normalize([The curl library was not found, Haskell
 441                                 code will be compiled without RAPI support]))
 442     else
 443       AC_MSG_FAILURE(m4_normalize([The curl library was not found, but it has
 444                                    been requested]))
 445     fi
 446   else
 447     AC_MSG_NOTICE([Enabling curl/RAPI/RPC usage in Haskell code])
 448   fi
 449 fi
 450 AC_SUBST(HTOOLS_NOCURL)
 451
 452 HTOOLS_PARALLEL3=
 453 AC_GHC_PKG_CHECK([parallel-3.*], [HTOOLS_PARALLEL3=-DPARALLEL3],
 454                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 455 AC_SUBST(HTOOLS_PARALLEL3)
 456
 457 # and now standard modules
 458 AC_GHC_PKG_REQUIRE(json)
 459 AC_GHC_PKG_REQUIRE(network)
 460 AC_GHC_PKG_REQUIRE(mtl)
 461 AC_GHC_PKG_REQUIRE(bytestring)
 462 AC_GHC_PKG_REQUIRE(utf8-string)
 463
 464 # extra modules for confd functionality
 465 HTOOLS_REGEX_PCRE=-DNO_REGEX_PCRE
 466 has_confd=False
 467 if test "$enable_confd" != "no"; then
 468   CONFD_PKG=
 469   AC_GHC_PKG_CHECK([regex-pcre], [HTOOLS_REGEX_PCRE=],
 470                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 471   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 472   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 473   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 474   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 475   if test -z "$CONFD_PKG"; then
 476     has_confd=True
 477   else
 478     if test "$enable_confd" = "check"; then
 479       AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 480                                 not found ($CONFD_PKG), confd disabled]))
 481     else
 482       AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 483                                    required libraries were not found:
 484                                    $CONFD_PKG]))
 485     fi
 486   fi
 487 fi
 488 AC_SUBST(HTOOLS_REGEX_PCRE)
 489 if test "$has_confd" = "True"; then
 490   AC_MSG_NOTICE([Enabling confd usage])
 491 fi
 492 AC_SUBST(ENABLE_CONFD, $has_confd)
 493 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 494
 495 # development modules
 496 HTOOLS_NODEV=
 497 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HTOOLS_NODEV=1], t)
 498 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HTOOLS_NODEV=1], t)
 499 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HTOOLS_NODEV=1])
 500 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HTOOLS_NODEV=1])
 501 if test -n "$HTOOLS_NODEV"; then
 502    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 503                              you won't be able to run Haskell unittests]))
 504 else
 505    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 506 fi
 507 AC_SUBST(HTOOLS_NODEV)
 508
 509 HTOOLS=yes
 510 AC_SUBST(HTOOLS)
 511
 512 # --enable-split-query
 513 ENABLE_SPLIT_QUERY=
 514 AC_ARG_ENABLE([split-query],
 515   [AS_HELP_STRING([--enable-split-query],
 516   [enable use of custom query daemon via confd])],
 517   [[case "$enableval" in
 518       no)
 519         enable_split_query=False
 520         ;;
 521       yes)
 522         enable_split_query=True
 523         ;;
 524       *)
 525         echo "Invalid value for enable-confd '$enableval'"
 526         exit 1
 527         ;;
 528     esac
 529   ]],
 530   [[case "x${has_confd}x${HTOOLS_NOCURL}x" in
 531      xTruexx)
 532        enable_split_query=True
 533        ;;
 534      *)
 535        enable_split_query=False
 536        ;;
 537    esac]])
 538 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 539
 540 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 541   AC_MSG_ERROR([Split queries require the confd daemon])
 542 fi
 543
 544 if test x$enable_split_query = xTrue -a x$HTOOLS_NOCURL != x; then
 545   AC_MSG_ERROR([Split queries require the htools-rapi feature (curl library)])
 546 fi
 547
 548 if test x$enable_split_query = xTrue; then
 549   AC_MSG_NOTICE([Split query functionality enabled])
 550 fi
 551
 552 # Check for HsColour
 553 HTOOLS_APIDOC=no
 554 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 555 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 556 if test -z "$HSCOLOUR"; then
 557   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 558                             not be generated]))
 559 fi
 560
 561 # Check for haddock
 562 AC_ARG_VAR(HADDOCK, [haddock path])
 563 AC_PATH_PROG(HADDOCK, [haddock], [])
 564 if test -z "$HADDOCK"; then
 565   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 566                             not be generated]))
 567 fi
 568 if test "$HADDOCK" && test "$HSCOLOUR"; then
 569   HTOOLS_APIDOC=yes
 570 fi
 571 AC_SUBST(HTOOLS_APIDOC)
 572
 573 # Check for hlint
 574 HLINT=no
 575 AC_ARG_VAR(HLINT, [hlint path])
 576 AC_PATH_PROG(HLINT, [hlint], [])
 577 if test -z "$HLINT"; then
 578   AC_MSG_WARN([hlint not found, checking code will not be possible])
 579 fi
 580
 581 if test "$HTOOLS" != "yes" && test "$ENABLE_CONFD" = "True"; then
 582    AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 583                               htools support is not enabled]))
 584 fi
 585
 586 AM_CONDITIONAL([WANT_HTOOLS], [test x$HTOOLS = xyes])
 587 AM_CONDITIONAL([WANT_HTOOLSTESTS], [test "x$HTOOLS_NODEV" = x])
 588 AM_CONDITIONAL([WANT_HTOOLSAPIDOC], [test x$HTOOLS_APIDOC = xyes])
 589 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 590
 591 # Check for fakeroot
 592 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 593 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 594 if test -z "$FAKEROOT_PATH"; then
 595   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 596                             will not be executed]))
 597 fi
 598 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 599
 600 SOCAT_USE_ESCAPE=
 601 AC_ARG_ENABLE([socat-escape],
 602   [AS_HELP_STRING([--enable-socat-escape],
 603     [use escape functionality available in socat >= 1.7 (default: detect
 604      automatically)])],
 605   [[if test "$enableval" = yes; then
 606       SOCAT_USE_ESCAPE=True
 607     else
 608       SOCAT_USE_ESCAPE=False
 609     fi
 610   ]])
 611
 612 if test -z "$SOCAT_USE_ESCAPE"
 613 then
 614   if $SOCAT -hh | grep -w -q escape; then
 615     SOCAT_USE_ESCAPE=True
 616   else
 617     SOCAT_USE_ESCAPE=False
 618   fi
 619 fi
 620
 621 AC_SUBST(SOCAT_USE_ESCAPE)
 622
 623 SOCAT_USE_COMPRESS=
 624 AC_ARG_ENABLE([socat-compress],
 625   [AS_HELP_STRING([--enable-socat-compress],
 626     [use OpenSSL compression option available in patched socat builds
 627      (see INSTALL for details; default: detect automatically)])],
 628   [[if test "$enableval" = yes; then
 629       SOCAT_USE_COMPRESS=True
 630     else
 631       SOCAT_USE_COMPRESS=False
 632     fi
 633   ]])
 634
 635 if test -z "$SOCAT_USE_COMPRESS"
 636 then
 637   if $SOCAT -hhh | grep -w -q openssl-compress; then
 638     SOCAT_USE_COMPRESS=True
 639   else
 640     SOCAT_USE_COMPRESS=False
 641   fi
 642 fi
 643
 644 AC_SUBST(SOCAT_USE_COMPRESS)
 645
 646 if man --help | grep -q -e --warnings
 647 then
 648   MAN_HAS_WARNINGS=1
 649 else
 650   MAN_HAS_WARNINGS=
 651   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 652                             will not be possible]))
 653 fi
 654
 655 AC_SUBST(MAN_HAS_WARNINGS)
 656
 657 # Check for Python
 658 AM_PATH_PYTHON(2.4)
 659
 660 AC_PYTHON_MODULE(OpenSSL, t)
 661 AC_PYTHON_MODULE(simplejson, t)
 662 AC_PYTHON_MODULE(pyparsing, t)
 663 AC_PYTHON_MODULE(pyinotify, t)
 664 AC_PYTHON_MODULE(pycurl, t)
 665 AC_PYTHON_MODULE(affinity)
 666 AC_PYTHON_MODULE(paramiko)
 667
 668 AC_CONFIG_FILES([ Makefile ])
 669
 670 AC_OUTPUT