code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [3])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~rc0])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-os-search-path=...
  53 # do a bit of black sed magic to for quoting of the strings in the list
  54 AC_ARG_WITH([os-search-path],
  55   [AS_HELP_STRING([--with-os-search-path=LIST],
  56     [comma separated list of directories to]
  57     [ search for OS images (default is /srv/ganeti/os)]
  58   )],
  59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  60   [os_search_path="'/srv/ganeti/os'"])
  61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  62
  63 # --with-iallocator-search-path=...
  64 # do a bit of black sed magic to for quoting of the strings in the list
  65 AC_ARG_WITH([iallocator-search-path],
  66   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  67     [comma separated list of directories to]
  68     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  69   )],
  70   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  71   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  72 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  73
  74 # --with-xen-bootloader=...
  75 AC_ARG_WITH([xen-bootloader],
  76   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  77     [bootloader for Xen hypervisor (default is empty)]
  78   )],
  79   [xen_bootloader="$withval"],
  80   [xen_bootloader=])
  81 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  82
  83 # --with-xen-kernel=...
  84 AC_ARG_WITH([xen-kernel],
  85   [AS_HELP_STRING([--with-xen-kernel=PATH],
  86     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-2.6-xenU)]
  87   )],
  88   [xen_kernel="$withval"],
  89   [xen_kernel="/boot/vmlinuz-2.6-xenU"])
  90 AC_SUBST(XEN_KERNEL, $xen_kernel)
  91
  92 # --with-xen-initrd=...
  93 AC_ARG_WITH([xen-initrd],
  94   [AS_HELP_STRING([--with-xen-initrd=PATH],
  95     [DomU initrd image for Xen hypervisor (default is /boot/initrd-2.6-xenU)]
  96   )],
  97   [xen_initrd="$withval"],
  98   [xen_initrd="/boot/initrd-2.6-xenU"])
  99 AC_SUBST(XEN_INITRD, $xen_initrd)
 100
 101 # --with-file-storage-dir=...
 102 AC_ARG_WITH([file-storage-dir],
 103   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 104     [directory to store files for file-based backend]
 105     [ (default is /srv/ganeti/file-storage)]
 106   )],
 107   [[file_storage_dir="$withval";
 108     if test "$withval" != no; then
 109       enable_file_storage=True
 110     else
 111       enable_file_storage=False
 112     fi
 113   ]],
 114   [[file_storage_dir="/srv/ganeti/file-storage"; enable_file_storage="True"]])
 115 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 116 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 117
 118 # --with-kvm-path=...
 119 AC_ARG_WITH([kvm-path],
 120   [AS_HELP_STRING([--with-kvm-path=PATH],
 121     [absolute path to the kvm binary]
 122     [ (default is /usr/bin/kvm)]
 123   )],
 124   [kvm_path="$withval"],
 125   [kvm_path="/usr/bin/kvm"])
 126 AC_SUBST(KVM_PATH, $kvm_path)
 127
 128 # --with-lvm-stripecount=...
 129 AC_ARG_WITH([lvm-stripecount],
 130   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 131     [the number of stripes to use for LVM volumes]
 132     [ (default is 1)]
 133   )],
 134   [lvm_stripecount="$withval"],
 135   [lvm_stripecount="1"])
 136 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 137
 138 # --with-user-prefix=...
 139 AC_ARG_WITH([user-prefix],
 140   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 141     [prefix for daemon users]
 142     [ (default is to run all daemons as root)]
 143   )],
 144   [user_masterd="${withval}masterd";
 145    user_rapi="${withval}rapi";
 146    user_confd="${withval}confd";
 147    user_noded="root"],
 148   [user_masterd="root";
 149    user_rapi="root";
 150    user_confd="root";
 151    user_noded="root"])
 152 AC_SUBST(MASTERD_USER, $user_masterd)
 153 AC_SUBST(RAPI_USER, $user_rapi)
 154 AC_SUBST(CONFD_USER, $user_confd)
 155 AC_SUBST(NODED_USER, $user_noded)
 156
 157 # --with-group-prefix=...
 158 AC_ARG_WITH([group-prefix],
 159   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 160     [prefix for daemon POSIX groups]
 161     [ (default is to run all daemons under group root)]
 162   )],
 163   [group_rapi="${withval}rapi";
 164    group_admin="${withval}admin";
 165    group_confd="${withval}confd";
 166    group_masterd="${withval}masterd";
 167    group_daemons="${withval}daemons";],
 168   [group_rapi="root";
 169    group_admin="root";
 170    group_confd="root";
 171    group_masterd="root";
 172    group_daemons="root"])
 173 AC_SUBST(RAPI_GROUP, $group_rapi)
 174 AC_SUBST(ADMIN_GROUP, $group_admin)
 175 AC_SUBST(CONFD_GROUP, $group_confd)
 176 AC_SUBST(MASTERD_GROUP, $group_masterd)
 177 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 178
 179 # Print the config to the user
 180 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 181 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 182 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 183 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 184 AC_MSG_NOTICE([Group for clients is $group_admin])
 185
 186 # --enable-drbd-barriers
 187 AC_ARG_ENABLE([drbd-barriers],
 188   [AS_HELP_STRING([--enable-drbd-barriers],
 189     [enable the DRBD barrier functionality (>= 8.0.12) (default: enabled)])],
 190   [[if test "$enableval" != no; then
 191       DRBD_BARRIERS=True
 192     else
 193       DRBD_BARRIERS=False
 194     fi
 195   ]],
 196   [DRBD_BARRIERS=True])
 197 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 198
 199 # --enable-syslog[=no/yes/only]
 200 AC_ARG_ENABLE([syslog],
 201   [AS_HELP_STRING([--enable-syslog],
 202     [enable use of syslog (default: disabled), one of no/yes/only])],
 203   [[case "$enableval" in
 204       no)
 205         SYSLOG=no
 206         ;;
 207       yes)
 208         SYSLOG=yes
 209         ;;
 210       only)
 211         SYSLOG=only
 212         ;;
 213       *)
 214         SYSLOG=
 215         ;;
 216     esac
 217   ]],
 218   [SYSLOG=no])
 219
 220 if test -z "$SYSLOG"
 221 then
 222   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 223 fi
 224 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 225
 226 # Check common programs
 227 AC_PROG_INSTALL
 228 AC_PROG_LN_S
 229
 230 # Check for pandoc
 231 AC_ARG_VAR(PANDOC, [pandoc path])
 232 AC_PATH_PROG(PANDOC, [pandoc], [])
 233 if test -z "$PANDOC"
 234 then
 235   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 236 fi
 237
 238 # Check for python-sphinx
 239 AC_ARG_VAR(SPHINX, [sphinx-build path])
 240 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 241 if test -z "$SPHINX"
 242 then
 243   AC_MSG_WARN([sphinx-build not found, documentation rebuild will not be possible])
 244 fi
 245
 246 # Check for graphviz (dot)
 247 AC_ARG_VAR(DOT, [dot path])
 248 AC_PATH_PROG(DOT, [dot], [])
 249 if test -z "$DOT"
 250 then
 251   AC_MSG_WARN([dot (from the graphviz suite) not found, documentation rebuild not possible])
 252 fi
 253
 254 # Check for pylint
 255 AC_ARG_VAR(PYLINT, [pylint path])
 256 AC_PATH_PROG(PYLINT, [pylint], [])
 257 if test -z "$PYLINT"
 258 then
 259   AC_MSG_WARN([pylint not found, checking code will not be possible])
 260 fi
 261
 262 # Check for socat
 263 AC_ARG_VAR(SOCAT, [socat path])
 264 AC_PATH_PROG(SOCAT, [socat], [])
 265 if test -z "$SOCAT"
 266 then
 267   AC_MSG_ERROR([socat not found])
 268 fi
 269
 270 SOCAT_USE_ESCAPE=
 271 AC_ARG_ENABLE([socat-escape],
 272   [AS_HELP_STRING([--enable-socat-escape],
 273     [use escape functionality available in socat >= 1.7 (default: detect
 274      automatically)])],
 275   [[if test "$enableval" = yes; then
 276       SOCAT_USE_ESCAPE=True
 277     else
 278       SOCAT_USE_ESCAPE=False
 279     fi
 280   ]])
 281
 282 if test -z "$SOCAT_USE_ESCAPE"
 283 then
 284   if $SOCAT -hh | grep -w -q escape; then
 285     SOCAT_USE_ESCAPE=True
 286   else
 287     SOCAT_USE_ESCAPE=False
 288   fi
 289 fi
 290
 291 AC_SUBST(SOCAT_USE_ESCAPE)
 292
 293 SOCAT_USE_COMPRESS=
 294 AC_ARG_ENABLE([socat-compress],
 295   [AS_HELP_STRING([--enable-socat-compress],
 296     [use OpenSSL compression option available in patched socat builds
 297      (see INSTALL for details; default: detect automatically)])],
 298   [[if test "$enableval" = yes; then
 299       SOCAT_USE_COMPRESS=True
 300     else
 301       SOCAT_USE_COMPRESS=False
 302     fi
 303   ]])
 304
 305 if test -z "$SOCAT_USE_COMPRESS"
 306 then
 307   if $SOCAT -hhh | grep -w -q openssl-compress; then
 308     SOCAT_USE_COMPRESS=True
 309   else
 310     SOCAT_USE_COMPRESS=False
 311   fi
 312 fi
 313
 314 AC_SUBST(SOCAT_USE_COMPRESS)
 315
 316 if man --help | grep -q -e --warnings
 317 then
 318   MAN_HAS_WARNINGS=1
 319 else
 320   MAN_HAS_WARNINGS=
 321   AC_MSG_WARN([man doesn't support --warnings, man pages checks
 322                will not be possible])
 323 fi
 324
 325 AC_SUBST(MAN_HAS_WARNINGS)
 326
 327 # Check for Python
 328 AM_PATH_PYTHON(2.4)
 329
 330 AC_PYTHON_MODULE(OpenSSL, t)
 331 AC_PYTHON_MODULE(simplejson, t)
 332 AC_PYTHON_MODULE(pyparsing, t)
 333 AC_PYTHON_MODULE(pyinotify, t)
 334 AC_PYTHON_MODULE(pycurl, t)
 335
 336 # This is optional but then we've limited functionality
 337 AC_PYTHON_MODULE(paramiko)
 338 if test "$HAVE_PYMOD_PARAMIKO" = "no"; then
 339   AC_MSG_WARN([You do not have paramiko installed. While this is optional you
 340                have to setup SSH and noded on the joining nodes yourself.])
 341 fi
 342
 343 AC_CONFIG_FILES([ Makefile ])
 344
 345 AC_OUTPUT