code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [9])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~alpha1])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-xen-config-dir=...
  53 AC_ARG_WITH([xen-config-dir],
  54   [AS_HELP_STRING([--with-xen-config-dir=DIR],
  55                   m4_normalize([Xen configuration directory
  56                                 (default: /etc/xen)]))],
  57   [xen_config_dir="$withval"],
  58   [xen_config_dir=/etc/xen])
  59 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
  60
  61 # --with-os-search-path=...
  62 # do a bit of black sed magic to for quoting of the strings in the list
  63 AC_ARG_WITH([os-search-path],
  64   [AS_HELP_STRING([--with-os-search-path=LIST],
  65     [comma separated list of directories to]
  66     [ search for OS images (default is /srv/ganeti/os)]
  67   )],
  68   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  69   [os_search_path="'/srv/ganeti/os'"])
  70 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  71
  72 # --with-extstorage-search-path=...
  73 # same black sed magic for quoting of the strings in the list
  74 AC_ARG_WITH([extstorage-search-path],
  75   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  76     [comma separated list of directories to]
  77     [ search for External Storage Providers]
  78     [ (default is /srv/ganeti/extstorage)]
  79   )],
  80   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  81   [es_search_path="'/srv/ganeti/extstorage'"])
  82 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  83
  84 # --with-iallocator-search-path=...
  85 # do a bit of black sed magic to for quoting of the strings in the list
  86 AC_ARG_WITH([iallocator-search-path],
  87   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  88     [comma separated list of directories to]
  89     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  90   )],
  91   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  92   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  93 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  94
  95 # --with-xen-bootloader=...
  96 AC_ARG_WITH([xen-bootloader],
  97   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  98     [bootloader for Xen hypervisor (default is empty)]
  99   )],
 100   [xen_bootloader="$withval"],
 101   [xen_bootloader=])
 102 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
 103
 104 # --with-xen-kernel=...
 105 AC_ARG_WITH([xen-kernel],
 106   [AS_HELP_STRING([--with-xen-kernel=PATH],
 107     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
 108   )],
 109   [xen_kernel="$withval"],
 110   [xen_kernel="/boot/vmlinuz-3-xenU"])
 111 AC_SUBST(XEN_KERNEL, $xen_kernel)
 112
 113 # --with-xen-initrd=...
 114 AC_ARG_WITH([xen-initrd],
 115   [AS_HELP_STRING([--with-xen-initrd=PATH],
 116     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 117   )],
 118   [xen_initrd="$withval"],
 119   [xen_initrd="/boot/initrd-3-xenU"])
 120 AC_SUBST(XEN_INITRD, $xen_initrd)
 121
 122 # --with-kvm-kernel=...
 123 AC_ARG_WITH([kvm-kernel],
 124   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 125     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 126   )],
 127   [kvm_kernel="$withval"],
 128   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 129 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 130
 131 # --with-shared-file-storage-dir=...
 132 AC_ARG_WITH([shared-file-storage-dir],
 133   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 134     [directory to store files for shared file-based backend]
 135     [ (default is /srv/ganeti/shared-file-storage)]
 136   )],
 137   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage"]])
 138 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 139
 140 # --with-kvm-path=...
 141 AC_ARG_WITH([kvm-path],
 142   [AS_HELP_STRING([--with-kvm-path=PATH],
 143     [absolute path to the kvm binary]
 144     [ (default is /usr/bin/kvm)]
 145   )],
 146   [kvm_path="$withval"],
 147   [kvm_path="/usr/bin/kvm"])
 148 AC_SUBST(KVM_PATH, $kvm_path)
 149
 150 # --with-lvm-stripecount=...
 151 AC_ARG_WITH([lvm-stripecount],
 152   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 153     [the default number of stripes to use for LVM volumes]
 154     [ (default is 1)]
 155   )],
 156   [lvm_stripecount="$withval"],
 157   [lvm_stripecount=1])
 158 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 159
 160 # --with-ssh-login-user=...
 161 AC_ARG_WITH([ssh-login-user],
 162   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 163     [user to use for SSH logins within the cluster (default is root)]
 164   )],
 165   [ssh_login_user="$withval"],
 166   [ssh_login_user=root])
 167 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 168
 169 # --with-ssh-console-user=...
 170 AC_ARG_WITH([ssh-console-user],
 171   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 172     [user to use for SSH logins to access instance consoles (default is root)]
 173   )],
 174   [ssh_console_user="$withval"],
 175   [ssh_console_user=root])
 176 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 177
 178 # --with-default-user=...
 179 AC_ARG_WITH([default-user],
 180   [AS_HELP_STRING([--with-default-user=USERNAME],
 181     [default user for daemons]
 182     [ (default is to run all daemons as root)]
 183   )],
 184   [user_default="$withval"],
 185   [user_default=root])
 186
 187 # --with-default-group=...
 188 AC_ARG_WITH([default-group],
 189   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 190     [default group for daemons]
 191     [ (default is to run all daemons under group root)]
 192   )],
 193   [group_default="$withval"],
 194   [group_default=root])
 195
 196 # --with-user-prefix=...
 197 AC_ARG_WITH([user-prefix],
 198   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 199     [prefix for daemon users]
 200     [ (default is to run all daemons as root; use --with-default-user]
 201     [ to change the default)]
 202   )],
 203   [user_masterd="${withval}masterd";
 204    user_rapi="${withval}rapi";
 205    user_confd="${withval}confd";
 206    user_luxid="${withval}luxid";
 207    user_noded="$user_default";
 208    user_mond="$user_default"],
 209   [user_masterd="$user_default";
 210    user_rapi="$user_default";
 211    user_confd="$user_default";
 212    user_luxid="$user_default";
 213    user_noded="$user_default";
 214    user_mond="$user_default"])
 215 AC_SUBST(MASTERD_USER, $user_masterd)
 216 AC_SUBST(RAPI_USER, $user_rapi)
 217 AC_SUBST(CONFD_USER, $user_confd)
 218 AC_SUBST(LUXID_USER, $user_luxid)
 219 AC_SUBST(NODED_USER, $user_noded)
 220 AC_SUBST(MOND_USER, $user_mond)
 221
 222 # --with-group-prefix=...
 223 AC_ARG_WITH([group-prefix],
 224   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 225     [prefix for daemon POSIX groups]
 226     [ (default is to run all daemons under group root; use]
 227     [ --with-default-group to change the default)]
 228   )],
 229   [group_rapi="${withval}rapi";
 230    group_admin="${withval}admin";
 231    group_confd="${withval}confd";
 232    group_luxid="${withval}luxid";
 233    group_masterd="${withval}masterd";
 234    group_noded="$group_default";
 235    group_daemons="${withval}daemons";
 236    group_mond="$group_default"],
 237   [group_rapi="$group_default";
 238    group_admin="$group_default";
 239    group_confd="$group_default";
 240    group_luxid="$group_default";
 241    group_masterd="$group_default";
 242    group_noded="$group_default";
 243    group_daemons="$group_default";
 244    group_mond="$group_default"])
 245 AC_SUBST(RAPI_GROUP, $group_rapi)
 246 AC_SUBST(ADMIN_GROUP, $group_admin)
 247 AC_SUBST(CONFD_GROUP, $group_confd)
 248 AC_SUBST(LUXID_GROUP, $group_luxid)
 249 AC_SUBST(MASTERD_GROUP, $group_masterd)
 250 AC_SUBST(NODED_GROUP, $group_noded)
 251 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 252 AC_SUBST(MOND_GROUP, $group_mond)
 253
 254 # Print the config to the user
 255 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 256 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 257 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 258 AC_MSG_NOTICE([Running ganeti-luxid as $user_luxid:$group_luxid])
 259 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 260 AC_MSG_NOTICE([Group for clients is $group_admin])
 261
 262 # --enable-drbd-barriers
 263 AC_ARG_ENABLE([drbd-barriers],
 264   [AS_HELP_STRING([--enable-drbd-barriers],
 265                   m4_normalize([enable the DRBD barriers functionality by
 266                                 default (>= 8.0.12) (default: enabled)]))],
 267   [[if test "$enableval" != no; then
 268       DRBD_BARRIERS=n
 269       DRBD_NO_META_FLUSH=False
 270     else
 271       DRBD_BARRIERS=bf
 272       DRBD_NO_META_FLUSH=True
 273     fi
 274   ]],
 275   [DRBD_BARRIERS=n
 276    DRBD_NO_META_FLUSH=False
 277   ])
 278 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 279 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 280
 281 # --enable-syslog[=no/yes/only]
 282 AC_ARG_ENABLE([syslog],
 283   [AS_HELP_STRING([--enable-syslog],
 284     [enable use of syslog (default: disabled), one of no/yes/only])],
 285   [[case "$enableval" in
 286       no)
 287         SYSLOG=no
 288         ;;
 289       yes)
 290         SYSLOG=yes
 291         ;;
 292       only)
 293         SYSLOG=only
 294         ;;
 295       *)
 296         SYSLOG=
 297         ;;
 298     esac
 299   ]],
 300   [SYSLOG=no])
 301
 302 if test -z "$SYSLOG"
 303 then
 304   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 305 fi
 306 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 307
 308 AC_ARG_ENABLE([restricted-commands],
 309   [AS_HELP_STRING([--enable-restricted-commands],
 310                   m4_normalize([enable restricted commands in the node daemon
 311                                 (default: disabled)]))],
 312   [[if test "$enableval" = no; then
 313       enable_restricted_commands=False
 314     else
 315       enable_restricted_commands=True
 316     fi
 317   ]],
 318   [enable_restricted_commands=False])
 319 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 320
 321 # --with-disk-separator=...
 322 AC_ARG_WITH([disk-separator],
 323   [AS_HELP_STRING([--with-disk-separator=STRING],
 324     [Disk index separator, useful if the default of ':' is handled]
 325     [ specially by the hypervisor]
 326   )],
 327   [disk_separator="$withval"],
 328   [disk_separator=":"])
 329 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 330
 331 # Check common programs
 332 AC_PROG_INSTALL
 333 AC_PROG_LN_S
 334
 335 # Check for the ip command
 336 AC_ARG_VAR(IP_PATH, [ip path])
 337 AC_PATH_PROG(IP_PATH, [ip], [])
 338 if test -z "$IP_PATH"
 339 then
 340   AC_MSG_ERROR([ip command not found])
 341 fi
 342
 343 # Check for pandoc
 344 AC_ARG_VAR(PANDOC, [pandoc path])
 345 AC_PATH_PROG(PANDOC, [pandoc], [])
 346 if test -z "$PANDOC"
 347 then
 348   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 349 fi
 350
 351 # Check for python-sphinx
 352 AC_ARG_VAR(SPHINX, [sphinx-build path])
 353 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 354 if test -z "$SPHINX"
 355 then
 356   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 357                             not be possible]))
 358 else
 359   # Sphinx exits with code 1 when it prints its usage
 360   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
 361
 362   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
 363     AC_MSG_ERROR([Unable to determine Sphinx version])
 364
 365   # Note: Character classes ([...]) need to be double quoted due to autoconf
 366   # using m4
 367   elif ! echo "$sphinxver" | grep -q -E '^Sphinx[[[:space:]]]+v[[1-9]]\>'; then
 368     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
 369   fi
 370 fi
 371
 372 AC_ARG_ENABLE([manpages-in-doc],
 373   [AS_HELP_STRING([--enable-manpages-in-doc],
 374                   m4_normalize([include man pages in HTML documentation
 375                                 (requires sphinx; default disabled)]))],
 376   [case "$enableval" in
 377       yes) manpages_in_doc=yes ;;
 378       no) manpages_in_doc= ;;
 379       *)
 380         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 381         ;;
 382     esac
 383   ],
 384   [manpages_in_doc=])
 385 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 386 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 387
 388 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 389   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 390 fi
 391
 392 # Check for graphviz (dot)
 393 AC_ARG_VAR(DOT, [dot path])
 394 AC_PATH_PROG(DOT, [dot], [])
 395 if test -z "$DOT"
 396 then
 397   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 398                             documentation rebuild not possible]))
 399 fi
 400
 401 # Check for pylint
 402 AC_ARG_VAR(PYLINT, [pylint path])
 403 AC_PATH_PROG(PYLINT, [pylint], [])
 404 if test -z "$PYLINT"
 405 then
 406   AC_MSG_WARN([pylint not found, checking code will not be possible])
 407 fi
 408
 409 # Check for pep8
 410 AC_ARG_VAR(PEP8, [pep8 path])
 411 AC_PATH_PROG(PEP8, [pep8], [])
 412 if test -z "$PEP8"
 413 then
 414   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 415 fi
 416 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 417
 418 # Check for python-coverage
 419 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 420 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 421 if test -z "$PYCOVERAGE"
 422 then
 423   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 424                             Python test coverage will not be possible]))
 425 fi
 426
 427 # Check for socat
 428 AC_ARG_VAR(SOCAT, [socat path])
 429 AC_PATH_PROG(SOCAT, [socat], [])
 430 if test -z "$SOCAT"
 431 then
 432   AC_MSG_ERROR([socat not found])
 433 fi
 434
 435 # Check for qemu-img
 436 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 437 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 438 if test -z "$QEMUIMG_PATH"
 439 then
 440   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 441 fi
 442
 443 # --enable-confd
 444 ENABLE_CONFD=
 445 AC_ARG_ENABLE([confd],
 446   [AS_HELP_STRING([--enable-confd],
 447   [enable the ganeti-confd daemon (default: check)])],
 448   [],
 449   [enable_confd=check])
 450
 451 ENABLE_MOND=
 452 AC_ARG_ENABLE([monitoring],
 453   [AS_HELP_STRING([--enable-monitoring],
 454   [enable the ganeti monitoring daemon (default: check)])],
 455   [],
 456   [enable_monitoring=check])
 457
 458 # Check for ghc
 459 AC_ARG_VAR(GHC, [ghc path])
 460 AC_PATH_PROG(GHC, [ghc], [])
 461 if test -z "$GHC"; then
 462   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 463 fi
 464
 465 AC_MSG_CHECKING([checking for extra GHC flags])
 466 GHC_BYVERSION_FLAGS=
 467 # check for GHC supported flags that vary accross versions
 468 for flag in -fwarn-incomplete-uni-patterns; do
 469   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 470    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 471   fi
 472 done
 473 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 474 AC_SUBST(GHC_BYVERSION_FLAGS)
 475
 476 # Check for ghc-pkg
 477 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 478 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 479 if test -z "$GHC_PKG"; then
 480   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 481 fi
 482
 483 # check for modules, first custom/special checks
 484 AC_MSG_NOTICE([checking for required haskell modules])
 485 HS_PARALLEL3=
 486 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 487                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 488 AC_SUBST(HS_PARALLEL3)
 489
 490 # and now standard modules
 491 AC_GHC_PKG_REQUIRE(curl)
 492 AC_GHC_PKG_REQUIRE(json)
 493 AC_GHC_PKG_REQUIRE(network)
 494 AC_GHC_PKG_REQUIRE(mtl)
 495 AC_GHC_PKG_REQUIRE(bytestring)
 496 AC_GHC_PKG_REQUIRE(utf8-string)
 497
 498 # extra modules for confd functionality
 499 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 500 has_confd=False
 501 if test "$enable_confd" != no; then
 502   CONFD_PKG=
 503   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 504                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 505   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 506   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 507   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 508   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 509   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 510   if test -z "$CONFD_PKG"; then
 511     has_confd=True
 512   elif test "$enable_confd" = check; then
 513     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 514                               not found ($CONFD_PKG), confd disabled]))
 515   else
 516     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 517                                  required libraries were not found:
 518                                  $CONFD_PKG]))
 519   fi
 520 fi
 521 AC_SUBST(HS_REGEX_PCRE)
 522 if test "$has_confd" = True; then
 523   AC_MSG_NOTICE([Enabling confd usage])
 524 fi
 525 AC_SUBST(ENABLE_CONFD, $has_confd)
 526 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 527
 528 #extra modules for monitoring daemon functionality
 529 has_monitoring=False
 530 if test "$enable_monitoring" != no; then
 531   MONITORING_PKG=
 532   AC_GHC_PKG_CHECK([attoparsec], [],
 533                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 534   AC_GHC_PKG_CHECK([snap-server], [],
 535                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
 536   AC_GHC_PKG_CHECK([process], [],
 537                    [MONITORING_PKG="$MONITORING_PKG process"])
 538   MONITORING_DEP=
 539   if test "$has_confd" = False; then
 540     MONITORING_DEP="$MONITORING_DEP confd"
 541   fi
 542   has_monitoring_pkg=False
 543   if test -z "$MONITORING_PKG"; then
 544     has_monitoring_pkg=True
 545   elif test "$enable_monitoring" = check; then
 546     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 547                               daemon were not found ($MONITORING_PKG),
 548                               monitoring disabled]))
 549   else
 550     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 551                                  required libraries were not found:
 552                                  $MONITORING_PKG]))
 553   fi
 554   has_monitoring_dep=False
 555   if test -z "$MONITORING_DEP"; then
 556     has_monitoring_dep=True
 557   elif test "$enable_monitoring" = check; then
 558     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
 559                               monitoring agent were not enabled
 560                               ($MONITORING_DEP), monitoring disabled]))
 561   else
 562     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 563                                  required optional Ganeti components were not
 564                                  found: $MONITORING_DEP]))
 565   fi
 566
 567 fi
 568 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
 569   has_monitoring=True
 570   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 571 fi
 572 AC_SUBST(ENABLE_MOND, $has_monitoring)
 573 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
 574
 575 # development modules
 576 HS_NODEV=
 577 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 578 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 579 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 580 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 581 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 582 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 583 #        that are needed to execute the tests, avoiding the duplication
 584 #        of the checks.
 585 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 586 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 587 AC_GHC_PKG_CHECK([process], [],
 588                  [MONITORING_PKG="$MONITORING_PKG process"])
 589 if test -n "$HS_NODEV"; then
 590    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 591                              you won't be able to run Haskell unittests]))
 592 else
 593    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 594 fi
 595 AC_SUBST(HS_NODEV)
 596
 597 HTOOLS=yes
 598 AC_SUBST(HTOOLS)
 599
 600 # --enable-split-query
 601 ENABLE_SPLIT_QUERY=
 602 AC_ARG_ENABLE([split-query],
 603   [AS_HELP_STRING([--enable-split-query],
 604   [enable use of custom query daemon via confd])],
 605   [[case "$enableval" in
 606       no)
 607         enable_split_query=False
 608         ;;
 609       yes)
 610         enable_split_query=True
 611         ;;
 612       *)
 613         echo "Invalid value for enable-confd '$enableval'"
 614         exit 1
 615         ;;
 616     esac
 617   ]],
 618   [[case "x${has_confd}x" in
 619      xTruex)
 620        enable_split_query=True
 621        ;;
 622      *)
 623        enable_split_query=False
 624        ;;
 625    esac]])
 626 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 627
 628 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 629   AC_MSG_ERROR([Split queries require the confd daemon])
 630 fi
 631
 632 if test x$enable_split_query = xTrue; then
 633   AC_MSG_NOTICE([Split query functionality enabled])
 634 fi
 635
 636 # Check for HsColour
 637 HS_APIDOC=no
 638 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 639 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 640 if test -z "$HSCOLOUR"; then
 641   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 642                             not be generated]))
 643 fi
 644
 645 # Check for haddock
 646 AC_ARG_VAR(HADDOCK, [haddock path])
 647 AC_PATH_PROG(HADDOCK, [haddock], [])
 648 if test -z "$HADDOCK"; then
 649   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 650                             not be generated]))
 651 fi
 652 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 653   HS_APIDOC=yes
 654 fi
 655 AC_SUBST(HS_APIDOC)
 656
 657 # Check for hlint
 658 AC_ARG_VAR(HLINT, [hlint path])
 659 AC_PATH_PROG(HLINT, [hlint], [])
 660 if test -z "$HLINT"; then
 661   AC_MSG_WARN([hlint not found, checking code will not be possible])
 662 fi
 663
 664 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 665   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 666                              htools support is not enabled]))
 667 fi
 668
 669 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 670 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 671 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 672 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 673
 674 # Check for fakeroot
 675 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 676 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 677 if test -z "$FAKEROOT_PATH"; then
 678   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 679                             will not be executed]))
 680 fi
 681 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 682
 683 SOCAT_USE_ESCAPE=
 684 AC_ARG_ENABLE([socat-escape],
 685   [AS_HELP_STRING([--enable-socat-escape],
 686     [use escape functionality available in socat >= 1.7 (default: detect
 687      automatically)])],
 688   [[if test "$enableval" = yes; then
 689       SOCAT_USE_ESCAPE=True
 690     else
 691       SOCAT_USE_ESCAPE=False
 692     fi
 693   ]])
 694
 695 if test -z "$SOCAT_USE_ESCAPE"
 696 then
 697   if $SOCAT -hh | grep -w -q escape; then
 698     SOCAT_USE_ESCAPE=True
 699   else
 700     SOCAT_USE_ESCAPE=False
 701   fi
 702 fi
 703
 704 AC_SUBST(SOCAT_USE_ESCAPE)
 705
 706 SOCAT_USE_COMPRESS=
 707 AC_ARG_ENABLE([socat-compress],
 708   [AS_HELP_STRING([--enable-socat-compress],
 709     [use OpenSSL compression option available in patched socat builds
 710      (see INSTALL for details; default: detect automatically)])],
 711   [[if test "$enableval" = yes; then
 712       SOCAT_USE_COMPRESS=True
 713     else
 714       SOCAT_USE_COMPRESS=False
 715     fi
 716   ]])
 717
 718 if test -z "$SOCAT_USE_COMPRESS"
 719 then
 720   if $SOCAT -hhh | grep -w -q openssl-compress; then
 721     SOCAT_USE_COMPRESS=True
 722   else
 723     SOCAT_USE_COMPRESS=False
 724   fi
 725 fi
 726
 727 AC_SUBST(SOCAT_USE_COMPRESS)
 728
 729 if man --help | grep -q -e --warnings
 730 then
 731   MAN_HAS_WARNINGS=1
 732 else
 733   MAN_HAS_WARNINGS=
 734   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 735                             will not be possible]))
 736 fi
 737
 738 AC_SUBST(MAN_HAS_WARNINGS)
 739
 740 # Check for Python
 741 AM_PATH_PYTHON(2.6)
 742
 743 AC_PYTHON_MODULE(OpenSSL, t)
 744 AC_PYTHON_MODULE(simplejson, t)
 745 AC_PYTHON_MODULE(pyparsing, t)
 746 AC_PYTHON_MODULE(pyinotify, t)
 747 AC_PYTHON_MODULE(pycurl, t)
 748 AC_PYTHON_MODULE(bitarray, t)
 749 AC_PYTHON_MODULE(ipaddr, t)
 750 AC_PYTHON_MODULE(mock)
 751 AC_PYTHON_MODULE(affinity)
 752 AC_PYTHON_MODULE(paramiko)
 753
 754 # Development-only Python modules
 755 PY_NODEV=
 756 AC_PYTHON_MODULE(yaml)
 757 if test $HAVE_PYMOD_YAML == "no"; then
 758   PY_NODEV="$PY_NODEV yaml"
 759 fi
 760
 761 if test -n "$PY_NODEV"; then
 762   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
 763                             found, you won't be able to run Python unittests]))
 764 else
 765   AC_MSG_NOTICE([Python development modules found, unittests enabled])
 766 fi
 767 AC_SUBST(PY_NODEV)
 768 AM_CONDITIONAL([PY_UNIT], [test -n $PY_NODEV])
 769
 770 AC_CONFIG_FILES([ Makefile ])
 771
 772 AC_OUTPUT