code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [6])
   4 m4_define([gnt_version_revision], [2])
   5 m4_define([gnt_version_suffix], [])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-os-search-path=...
  53 # do a bit of black sed magic to for quoting of the strings in the list
  54 AC_ARG_WITH([os-search-path],
  55   [AS_HELP_STRING([--with-os-search-path=LIST],
  56     [comma separated list of directories to]
  57     [ search for OS images (default is /srv/ganeti/os)]
  58   )],
  59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  60   [os_search_path="'/srv/ganeti/os'"])
  61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  62
  63 # --with-extstorage-search-path=...
  64 # same black sed magic for quoting of the strings in the list
  65 AC_ARG_WITH([extstorage-search-path],
  66   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  67     [comma separated list of directories to]
  68     [ search for External Storage Providers]
  69     [ (default is /srv/ganeti/extstorage)]
  70   )],
  71   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  72   [es_search_path="'/srv/ganeti/extstorage'"])
  73 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  74
  75 # --with-iallocator-search-path=...
  76 # do a bit of black sed magic to for quoting of the strings in the list
  77 AC_ARG_WITH([iallocator-search-path],
  78   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  79     [comma separated list of directories to]
  80     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  81   )],
  82   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  83   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  84 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  85
  86 # --with-xen-bootloader=...
  87 AC_ARG_WITH([xen-bootloader],
  88   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  89     [bootloader for Xen hypervisor (default is empty)]
  90   )],
  91   [xen_bootloader="$withval"],
  92   [xen_bootloader=])
  93 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  94
  95 # --with-xen-kernel=...
  96 AC_ARG_WITH([xen-kernel],
  97   [AS_HELP_STRING([--with-xen-kernel=PATH],
  98     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
  99   )],
 100   [xen_kernel="$withval"],
 101   [xen_kernel="/boot/vmlinuz-3-xenU"])
 102 AC_SUBST(XEN_KERNEL, $xen_kernel)
 103
 104 # --with-xen-initrd=...
 105 AC_ARG_WITH([xen-initrd],
 106   [AS_HELP_STRING([--with-xen-initrd=PATH],
 107     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 108   )],
 109   [xen_initrd="$withval"],
 110   [xen_initrd="/boot/initrd-3-xenU"])
 111 AC_SUBST(XEN_INITRD, $xen_initrd)
 112
 113 # --with-xen-cmd=...
 114 AC_ARG_WITH([xen-cmd],
 115   [AS_HELP_STRING([--with-xen-cmd=CMD],
 116     [Sets the xen cli interface command (default is xm)]
 117   )],
 118   [xen_cmd="$withval"],
 119   [xen_cmd=xm])
 120 AC_SUBST(XEN_CMD, $xen_cmd)
 121
 122 if ! test "$XEN_CMD" = xl -o "$XEN_CMD" = xm; then
 123   AC_MSG_ERROR([Unsupported xen command specified])
 124 fi
 125
 126 # --with-kvm-kernel=...
 127 AC_ARG_WITH([kvm-kernel],
 128   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 129     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 130   )],
 131   [kvm_kernel="$withval"],
 132   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 133 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 134
 135 # --with-file-storage-dir=...
 136 AC_ARG_WITH([file-storage-dir],
 137   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 138     [directory to store files for file-based backend]
 139     [ (default is /srv/ganeti/file-storage)]
 140   )],
 141   [[file_storage_dir="$withval";
 142     if test "$withval" != no; then
 143       enable_file_storage=True
 144     else
 145       enable_file_storage=False
 146     fi
 147   ]],
 148   [[file_storage_dir="/srv/ganeti/file-storage";
 149     enable_file_storage=True]])
 150 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 151 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 152
 153 # --with-shared-file-storage-dir=...
 154 AC_ARG_WITH([shared-file-storage-dir],
 155   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 156     [directory to store files for shared file-based backend]
 157     [ (default is /srv/ganeti/shared-file-storage)]
 158   )],
 159   [[shared_file_storage_dir="$withval";
 160     if test "$withval" != no; then
 161       enable_shared_file_storage=True
 162     else
 163       enable_shared_file_storage=False
 164     fi
 165   ]],
 166   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 167     enable_shared_file_storage=True]])
 168 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 169 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 170
 171 # --with-kvm-path=...
 172 AC_ARG_WITH([kvm-path],
 173   [AS_HELP_STRING([--with-kvm-path=PATH],
 174     [absolute path to the kvm binary]
 175     [ (default is /usr/bin/kvm)]
 176   )],
 177   [kvm_path="$withval"],
 178   [kvm_path="/usr/bin/kvm"])
 179 AC_SUBST(KVM_PATH, $kvm_path)
 180
 181 # --with-lvm-stripecount=...
 182 AC_ARG_WITH([lvm-stripecount],
 183   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 184     [the default number of stripes to use for LVM volumes]
 185     [ (default is 1)]
 186   )],
 187   [lvm_stripecount="$withval"],
 188   [lvm_stripecount=1])
 189 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 190
 191 # --with-ssh-login-user=...
 192 AC_ARG_WITH([ssh-login-user],
 193   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 194     [user to use for SSH logins within the cluster (default is root)]
 195   )],
 196   [ssh_login_user="$withval"],
 197   [ssh_login_user=root])
 198 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 199
 200 # --with-ssh-console-user=...
 201 AC_ARG_WITH([ssh-console-user],
 202   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 203     [user to use for SSH logins to access instance consoles (default is root)]
 204   )],
 205   [ssh_console_user="$withval"],
 206   [ssh_console_user=root])
 207 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 208
 209 # --with-default-user=...
 210 AC_ARG_WITH([default-user],
 211   [AS_HELP_STRING([--with-default-user=USERNAME],
 212     [default user for daemons]
 213     [ (default is to run all daemons as root)]
 214   )],
 215   [user_default="$withval"],
 216   [user_default=root])
 217
 218 # --with-default-group=...
 219 AC_ARG_WITH([default-group],
 220   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 221     [default group for daemons]
 222     [ (default is to run all daemons under group root)]
 223   )],
 224   [group_default="$withval"],
 225   [group_default=root])
 226
 227 # --with-user-prefix=...
 228 AC_ARG_WITH([user-prefix],
 229   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 230     [prefix for daemon users]
 231     [ (default is to run all daemons as root; use --with-default-user]
 232     [ to change the default)]
 233   )],
 234   [user_masterd="${withval}masterd";
 235    user_rapi="${withval}rapi";
 236    user_confd="${withval}confd";
 237    user_noded="$user_default"],
 238   [user_masterd="$user_default";
 239    user_rapi="$user_default";
 240    user_confd="$user_default";
 241    user_noded="$user_default"])
 242 AC_SUBST(MASTERD_USER, $user_masterd)
 243 AC_SUBST(RAPI_USER, $user_rapi)
 244 AC_SUBST(CONFD_USER, $user_confd)
 245 AC_SUBST(NODED_USER, $user_noded)
 246
 247 # --with-group-prefix=...
 248 AC_ARG_WITH([group-prefix],
 249   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 250     [prefix for daemon POSIX groups]
 251     [ (default is to run all daemons under group root; use]
 252     [ --with-default-group to change the default)]
 253   )],
 254   [group_rapi="${withval}rapi";
 255    group_admin="${withval}admin";
 256    group_confd="${withval}confd";
 257    group_masterd="${withval}masterd";
 258    group_noded="$group_default";
 259    group_daemons="${withval}daemons";],
 260   [group_rapi="$group_default";
 261    group_admin="$group_default";
 262    group_confd="$group_default";
 263    group_masterd="$group_default";
 264    group_noded="$group_default";
 265    group_daemons="$group_default"])
 266 AC_SUBST(RAPI_GROUP, $group_rapi)
 267 AC_SUBST(ADMIN_GROUP, $group_admin)
 268 AC_SUBST(CONFD_GROUP, $group_confd)
 269 AC_SUBST(MASTERD_GROUP, $group_masterd)
 270 AC_SUBST(NODED_GROUP, $group_noded)
 271 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 272
 273 # Print the config to the user
 274 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 275 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 276 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 277 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 278 AC_MSG_NOTICE([Group for clients is $group_admin])
 279
 280 # --enable-drbd-barriers
 281 AC_ARG_ENABLE([drbd-barriers],
 282   [AS_HELP_STRING([--enable-drbd-barriers],
 283                   m4_normalize([enable the DRBD barriers functionality by
 284                                 default (>= 8.0.12) (default: enabled)]))],
 285   [[if test "$enableval" != no; then
 286       DRBD_BARRIERS=n
 287       DRBD_NO_META_FLUSH=False
 288     else
 289       DRBD_BARRIERS=bf
 290       DRBD_NO_META_FLUSH=True
 291     fi
 292   ]],
 293   [DRBD_BARRIERS=n
 294    DRBD_NO_META_FLUSH=False
 295   ])
 296 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 297 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 298
 299 # --enable-syslog[=no/yes/only]
 300 AC_ARG_ENABLE([syslog],
 301   [AS_HELP_STRING([--enable-syslog],
 302     [enable use of syslog (default: disabled), one of no/yes/only])],
 303   [[case "$enableval" in
 304       no)
 305         SYSLOG=no
 306         ;;
 307       yes)
 308         SYSLOG=yes
 309         ;;
 310       only)
 311         SYSLOG=only
 312         ;;
 313       *)
 314         SYSLOG=
 315         ;;
 316     esac
 317   ]],
 318   [SYSLOG=no])
 319
 320 if test -z "$SYSLOG"
 321 then
 322   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 323 fi
 324 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 325
 326 AC_ARG_ENABLE([restricted-commands],
 327   [AS_HELP_STRING([--enable-restricted-commands],
 328                   m4_normalize([enable restricted commands in the node daemon
 329                                 (default: disabled)]))],
 330   [[if test "$enableval" = no; then
 331       enable_restricted_commands=False
 332     else
 333       enable_restricted_commands=True
 334     fi
 335   ]],
 336   [enable_restricted_commands=False])
 337 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 338
 339 # --with-disk-separator=...
 340 AC_ARG_WITH([disk-separator],
 341   [AS_HELP_STRING([--with-disk-separator=STRING],
 342     [Disk index separator, useful if the default of ':' is handled]
 343     [ specially by the hypervisor]
 344   )],
 345   [disk_separator="$withval"],
 346   [disk_separator=":"])
 347 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 348
 349 # Check common programs
 350 AC_PROG_INSTALL
 351 AC_PROG_LN_S
 352
 353 # Check for the ip command
 354 AC_ARG_VAR(IP_PATH, [ip path])
 355 AC_PATH_PROG(IP_PATH, [ip], [])
 356 if test -z "$IP_PATH"
 357 then
 358   AC_MSG_ERROR([ip command not found])
 359 fi
 360
 361 # Check for pandoc
 362 AC_ARG_VAR(PANDOC, [pandoc path])
 363 AC_PATH_PROG(PANDOC, [pandoc], [])
 364 if test -z "$PANDOC"
 365 then
 366   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 367 fi
 368
 369 # Check for python-sphinx
 370 AC_ARG_VAR(SPHINX, [sphinx-build path])
 371 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 372 if test -z "$SPHINX"
 373 then
 374   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 375                             not be possible]))
 376 fi
 377
 378 AC_ARG_ENABLE([manpages-in-doc],
 379   [AS_HELP_STRING([--enable-manpages-in-doc],
 380                   m4_normalize([include man pages in HTML documentation
 381                                 (requires sphinx; default disabled)]))],
 382   [case "$enableval" in
 383       yes) manpages_in_doc=yes ;;
 384       no) manpages_in_doc= ;;
 385       *)
 386         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 387         ;;
 388     esac
 389   ],
 390   [manpages_in_doc=])
 391 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 392 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 393
 394 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 395   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 396 fi
 397
 398 # Check for graphviz (dot)
 399 AC_ARG_VAR(DOT, [dot path])
 400 AC_PATH_PROG(DOT, [dot], [])
 401 if test -z "$DOT"
 402 then
 403   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 404                             documentation rebuild not possible]))
 405 fi
 406
 407 # Check for pylint
 408 AC_ARG_VAR(PYLINT, [pylint path])
 409 AC_PATH_PROG(PYLINT, [pylint], [])
 410 if test -z "$PYLINT"
 411 then
 412   AC_MSG_WARN([pylint not found, checking code will not be possible])
 413 fi
 414
 415 # Check for pep8
 416 AC_ARG_VAR(PEP8, [pep8 path])
 417 AC_PATH_PROG(PEP8, [pep8], [])
 418 if test -z "$PEP8"
 419 then
 420   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 421 fi
 422 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 423
 424 # Check for python-coverage
 425 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 426 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 427 if test -z "$PYCOVERAGE"
 428 then
 429   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 430                             Python test coverage will not be possible]))
 431 fi
 432
 433 # Check for socat
 434 AC_ARG_VAR(SOCAT, [socat path])
 435 AC_PATH_PROG(SOCAT, [socat], [])
 436 if test -z "$SOCAT"
 437 then
 438   AC_MSG_ERROR([socat not found])
 439 fi
 440
 441 # Check for qemu-img
 442 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 443 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 444 if test -z "$QEMUIMG_PATH"
 445 then
 446   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 447 fi
 448
 449 # --enable-htools-rapi
 450 HTOOLS_RAPI=
 451 AC_ARG_ENABLE([htools-rapi],
 452         [AS_HELP_STRING([--enable-htools-rapi],
 453         [enable use of curl in the Haskell code (default: check)])],
 454         [],
 455         [enable_htools_rapi=check])
 456
 457 # --enable-confd
 458 ENABLE_CONFD=
 459 AC_ARG_ENABLE([confd],
 460   [AS_HELP_STRING([--enable-confd],
 461   [enable the ganeti-confd daemon (default: check)])],
 462   [],
 463   [enable_confd=check])
 464
 465 ENABLE_MONITORING=
 466 AC_ARG_ENABLE([monitoring],
 467   [AS_HELP_STRING([--enable-monitoring],
 468   [enable the ganeti monitoring agent (default: check)])],
 469   [],
 470   [enable_monitoring=check])
 471
 472 # Check for ghc
 473 AC_ARG_VAR(GHC, [ghc path])
 474 AC_PATH_PROG(GHC, [ghc], [])
 475 if test -z "$GHC"; then
 476   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 477 fi
 478
 479 AC_MSG_CHECKING([checking for extra GHC flags])
 480 GHC_BYVERSION_FLAGS=
 481 # check for GHC supported flags that vary accross versions
 482 for flag in -fwarn-incomplete-uni-patterns; do
 483   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 484    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 485   fi
 486 done
 487 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 488 AC_SUBST(GHC_BYVERSION_FLAGS)
 489
 490 # Check for ghc-pkg
 491 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 492 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 493 if test -z "$GHC_PKG"; then
 494   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 495 fi
 496
 497 # check for modules, first custom/special checks
 498 AC_MSG_NOTICE([checking for required haskell modules])
 499 HS_NOCURL=-DNO_CURL
 500 if test "$enable_htools_rapi" != no; then
 501   AC_GHC_PKG_CHECK([curl], [HS_NOCURL=], [])
 502   if test -n "$HS_NOCURL"; then
 503     if test "$enable_htools_rapi" = check; then
 504       AC_MSG_WARN(m4_normalize([The curl library was not found, Haskell
 505                                 code will be compiled without RAPI support]))
 506     else
 507       AC_MSG_FAILURE(m4_normalize([The curl library was not found, but it has
 508                                    been requested]))
 509     fi
 510   else
 511     AC_MSG_NOTICE([Enabling curl/RAPI/RPC usage in Haskell code])
 512   fi
 513 fi
 514 AC_SUBST(HS_NOCURL)
 515
 516 HS_PARALLEL3=
 517 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 518                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 519 AC_SUBST(HS_PARALLEL3)
 520
 521 # and now standard modules
 522 AC_GHC_PKG_REQUIRE(json)
 523 AC_GHC_PKG_REQUIRE(network)
 524 AC_GHC_PKG_REQUIRE(mtl)
 525 AC_GHC_PKG_REQUIRE(bytestring)
 526 AC_GHC_PKG_REQUIRE(utf8-string)
 527
 528 # extra modules for confd functionality
 529 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 530 has_confd=False
 531 if test "$enable_confd" != no; then
 532   CONFD_PKG=
 533   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 534                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 535   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 536   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 537   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 538   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 539   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 540   if test -z "$CONFD_PKG"; then
 541     has_confd=True
 542   elif test "$enable_confd" = check; then
 543     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 544                               not found ($CONFD_PKG), confd disabled]))
 545   else
 546     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 547                                  required libraries were not found:
 548                                  $CONFD_PKG]))
 549   fi
 550 fi
 551 AC_SUBST(HS_REGEX_PCRE)
 552 if test "$has_confd" = True; then
 553   AC_MSG_NOTICE([Enabling confd usage])
 554 fi
 555 AC_SUBST(ENABLE_CONFD, $has_confd)
 556 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 557
 558 #extra modules for monitoring agent functionality
 559 has_monitoring=False
 560 if test "$enable_monitoring" != no; then
 561   MONITORING_PKG=
 562   AC_GHC_PKG_CHECK([attoparsec], [],
 563                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 564   if test -z "$MONITORING_PKG"; then
 565     has_monitoring=True
 566   elif test "$enable_monitoring" = check; then
 567     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 568                               agent were not found ($MONITORING_PKG),
 569                               monitoring disabled]))
 570   else
 571     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 572                                  required libraries were not found:
 573                                  $MONITORING_PKG]))
 574   fi
 575 fi
 576 if test "$has_monitoring" = True; then
 577   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 578 fi
 579 AC_SUBST(ENABLE_MONITORING, $has_monitoring)
 580 AM_CONDITIONAL([ENABLE_MONITORING], [test "$has_monitoring" = True])
 581
 582 # development modules
 583 HS_NODEV=
 584 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 585 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 586 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 587 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 588 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 589 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 590 #        that are needed to execute the tests, avoiding the duplication
 591 #        of the checks.
 592 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 593 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 594 if test -n "$HS_NODEV"; then
 595    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 596                              you won't be able to run Haskell unittests]))
 597 else
 598    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 599 fi
 600 AC_SUBST(HS_NODEV)
 601
 602 HTOOLS=yes
 603 AC_SUBST(HTOOLS)
 604
 605 # --enable-split-query
 606 ENABLE_SPLIT_QUERY=
 607 AC_ARG_ENABLE([split-query],
 608   [AS_HELP_STRING([--enable-split-query],
 609   [enable use of custom query daemon via confd])],
 610   [[case "$enableval" in
 611       no)
 612         enable_split_query=False
 613         ;;
 614       yes)
 615         enable_split_query=True
 616         ;;
 617       *)
 618         echo "Invalid value for enable-confd '$enableval'"
 619         exit 1
 620         ;;
 621     esac
 622   ]],
 623   [[case "x${has_confd}x${HS_NOCURL}x" in
 624      xTruexx)
 625        enable_split_query=True
 626        ;;
 627      *)
 628        enable_split_query=False
 629        ;;
 630    esac]])
 631 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 632
 633 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 634   AC_MSG_ERROR([Split queries require the confd daemon])
 635 fi
 636
 637 if test x$enable_split_query = xTrue -a x$HS_NOCURL != x; then
 638   AC_MSG_ERROR([Split queries require the htools-rapi feature (curl library)])
 639 fi
 640
 641 if test x$enable_split_query = xTrue; then
 642   AC_MSG_NOTICE([Split query functionality enabled])
 643 fi
 644
 645 # Check for HsColour
 646 HS_APIDOC=no
 647 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 648 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 649 if test -z "$HSCOLOUR"; then
 650   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 651                             not be generated]))
 652 fi
 653
 654 # Check for haddock
 655 AC_ARG_VAR(HADDOCK, [haddock path])
 656 AC_PATH_PROG(HADDOCK, [haddock], [])
 657 if test -z "$HADDOCK"; then
 658   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 659                             not be generated]))
 660 fi
 661 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 662   HS_APIDOC=yes
 663 fi
 664 AC_SUBST(HS_APIDOC)
 665
 666 # Check for hlint
 667 AC_ARG_VAR(HLINT, [hlint path])
 668 AC_PATH_PROG(HLINT, [hlint], [])
 669 if test -z "$HLINT"; then
 670   AC_MSG_WARN([hlint not found, checking code will not be possible])
 671 fi
 672
 673 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 674   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 675                              htools support is not enabled]))
 676 fi
 677
 678 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 679 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 680 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 681 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 682
 683 # Check for fakeroot
 684 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 685 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 686 if test -z "$FAKEROOT_PATH"; then
 687   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 688                             will not be executed]))
 689 fi
 690 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 691
 692 SOCAT_USE_ESCAPE=
 693 AC_ARG_ENABLE([socat-escape],
 694   [AS_HELP_STRING([--enable-socat-escape],
 695     [use escape functionality available in socat >= 1.7 (default: detect
 696      automatically)])],
 697   [[if test "$enableval" = yes; then
 698       SOCAT_USE_ESCAPE=True
 699     else
 700       SOCAT_USE_ESCAPE=False
 701     fi
 702   ]])
 703
 704 if test -z "$SOCAT_USE_ESCAPE"
 705 then
 706   if $SOCAT -hh | grep -w -q escape; then
 707     SOCAT_USE_ESCAPE=True
 708   else
 709     SOCAT_USE_ESCAPE=False
 710   fi
 711 fi
 712
 713 AC_SUBST(SOCAT_USE_ESCAPE)
 714
 715 SOCAT_USE_COMPRESS=
 716 AC_ARG_ENABLE([socat-compress],
 717   [AS_HELP_STRING([--enable-socat-compress],
 718     [use OpenSSL compression option available in patched socat builds
 719      (see INSTALL for details; default: detect automatically)])],
 720   [[if test "$enableval" = yes; then
 721       SOCAT_USE_COMPRESS=True
 722     else
 723       SOCAT_USE_COMPRESS=False
 724     fi
 725   ]])
 726
 727 if test -z "$SOCAT_USE_COMPRESS"
 728 then
 729   if $SOCAT -hhh | grep -w -q openssl-compress; then
 730     SOCAT_USE_COMPRESS=True
 731   else
 732     SOCAT_USE_COMPRESS=False
 733   fi
 734 fi
 735
 736 AC_SUBST(SOCAT_USE_COMPRESS)
 737
 738 if man --help | grep -q -e --warnings
 739 then
 740   MAN_HAS_WARNINGS=1
 741 else
 742   MAN_HAS_WARNINGS=
 743   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 744                             will not be possible]))
 745 fi
 746
 747 AC_SUBST(MAN_HAS_WARNINGS)
 748
 749 # Check for Python
 750 AM_PATH_PYTHON(2.4)
 751
 752 AC_PYTHON_MODULE(OpenSSL, t)
 753 AC_PYTHON_MODULE(simplejson, t)
 754 AC_PYTHON_MODULE(pyparsing, t)
 755 AC_PYTHON_MODULE(pyinotify, t)
 756 AC_PYTHON_MODULE(pycurl, t)
 757 AC_PYTHON_MODULE(bitarray, t)
 758 AC_PYTHON_MODULE(ipaddr, t)
 759 AC_PYTHON_MODULE(affinity)
 760 AC_PYTHON_MODULE(paramiko)
 761
 762 AC_CONFIG_FILES([ Makefile ])
 763
 764 AC_OUTPUT