code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [5])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~beta1])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-os-search-path=...
  53 # do a bit of black sed magic to for quoting of the strings in the list
  54 AC_ARG_WITH([os-search-path],
  55   [AS_HELP_STRING([--with-os-search-path=LIST],
  56     [comma separated list of directories to]
  57     [ search for OS images (default is /srv/ganeti/os)]
  58   )],
  59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  60   [os_search_path="'/srv/ganeti/os'"])
  61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  62
  63 # --with-iallocator-search-path=...
  64 # do a bit of black sed magic to for quoting of the strings in the list
  65 AC_ARG_WITH([iallocator-search-path],
  66   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  67     [comma separated list of directories to]
  68     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  69   )],
  70   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  71   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  72 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  73
  74 # --with-xen-bootloader=...
  75 AC_ARG_WITH([xen-bootloader],
  76   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  77     [bootloader for Xen hypervisor (default is empty)]
  78   )],
  79   [xen_bootloader="$withval"],
  80   [xen_bootloader=])
  81 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  82
  83 # --with-xen-kernel=...
  84 AC_ARG_WITH([xen-kernel],
  85   [AS_HELP_STRING([--with-xen-kernel=PATH],
  86     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-2.6-xenU)]
  87   )],
  88   [xen_kernel="$withval"],
  89   [xen_kernel="/boot/vmlinuz-2.6-xenU"])
  90 AC_SUBST(XEN_KERNEL, $xen_kernel)
  91
  92 # --with-xen-initrd=...
  93 AC_ARG_WITH([xen-initrd],
  94   [AS_HELP_STRING([--with-xen-initrd=PATH],
  95     [DomU initrd image for Xen hypervisor (default is /boot/initrd-2.6-xenU)]
  96   )],
  97   [xen_initrd="$withval"],
  98   [xen_initrd="/boot/initrd-2.6-xenU"])
  99 AC_SUBST(XEN_INITRD, $xen_initrd)
 100
 101 # --with-file-storage-dir=...
 102 AC_ARG_WITH([file-storage-dir],
 103   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 104     [directory to store files for file-based backend]
 105     [ (default is /srv/ganeti/file-storage)]
 106   )],
 107   [[file_storage_dir="$withval";
 108     if test "$withval" != no; then
 109       enable_file_storage=True
 110     else
 111       enable_file_storage=False
 112     fi
 113   ]],
 114   [[file_storage_dir="/srv/ganeti/file-storage";
 115     enable_file_storage="True"]])
 116 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 117 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 118
 119 # --with-shared-file-storage-dir=...
 120 AC_ARG_WITH([shared-file-storage-dir],
 121   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 122     [directory to store files for shared file-based backend]
 123     [ (default is /srv/ganeti/shared-file-storage)]
 124   )],
 125   [[shared_file_storage_dir="$withval";
 126     if test "$withval" != no; then
 127       enable_shared_file_storage=True
 128     else
 129       enable_shared_file_storage=False
 130     fi
 131   ]],
 132   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 133     enable_shared_file_storage="True"]])
 134 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 135 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 136
 137 # --with-kvm-path=...
 138 AC_ARG_WITH([kvm-path],
 139   [AS_HELP_STRING([--with-kvm-path=PATH],
 140     [absolute path to the kvm binary]
 141     [ (default is /usr/bin/kvm)]
 142   )],
 143   [kvm_path="$withval"],
 144   [kvm_path="/usr/bin/kvm"])
 145 AC_SUBST(KVM_PATH, $kvm_path)
 146
 147 # --with-lvm-stripecount=...
 148 AC_ARG_WITH([lvm-stripecount],
 149   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 150     [the number of stripes to use for LVM volumes]
 151     [ (default is 1)]
 152   )],
 153   [lvm_stripecount="$withval"],
 154   [lvm_stripecount="1"])
 155 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 156
 157 # --with-user-prefix=...
 158 AC_ARG_WITH([user-prefix],
 159   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 160     [prefix for daemon users]
 161     [ (default is to run all daemons as root)]
 162   )],
 163   [user_masterd="${withval}masterd";
 164    user_rapi="${withval}rapi";
 165    user_confd="${withval}confd";
 166    user_noded="root"],
 167   [user_masterd="root";
 168    user_rapi="root";
 169    user_confd="root";
 170    user_noded="root"])
 171 AC_SUBST(MASTERD_USER, $user_masterd)
 172 AC_SUBST(RAPI_USER, $user_rapi)
 173 AC_SUBST(CONFD_USER, $user_confd)
 174 AC_SUBST(NODED_USER, $user_noded)
 175
 176 # --with-group-prefix=...
 177 AC_ARG_WITH([group-prefix],
 178   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 179     [prefix for daemon POSIX groups]
 180     [ (default is to run all daemons under group root)]
 181   )],
 182   [group_rapi="${withval}rapi";
 183    group_admin="${withval}admin";
 184    group_confd="${withval}confd";
 185    group_masterd="${withval}masterd";
 186    group_noded="root";
 187    group_daemons="${withval}daemons";],
 188   [group_rapi="root";
 189    group_admin="root";
 190    group_confd="root";
 191    group_masterd="root";
 192    group_noded="root";
 193    group_daemons="root"])
 194 AC_SUBST(RAPI_GROUP, $group_rapi)
 195 AC_SUBST(ADMIN_GROUP, $group_admin)
 196 AC_SUBST(CONFD_GROUP, $group_confd)
 197 AC_SUBST(MASTERD_GROUP, $group_masterd)
 198 AC_SUBST(NODED_GROUP, $group_noded)
 199 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 200
 201 # Print the config to the user
 202 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 203 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 204 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 205 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 206 AC_MSG_NOTICE([Group for clients is $group_admin])
 207
 208 # --enable-drbd-barriers
 209 AC_ARG_ENABLE([drbd-barriers],
 210   [AS_HELP_STRING([--enable-drbd-barriers],
 211     [enable the DRBD barrier functionality (>= 8.0.12) (default: enabled)])],
 212   [[if test "$enableval" != no; then
 213       DRBD_BARRIERS=True
 214     else
 215       DRBD_BARRIERS=False
 216     fi
 217   ]],
 218   [DRBD_BARRIERS=True])
 219 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 220
 221 # --enable-syslog[=no/yes/only]
 222 AC_ARG_ENABLE([syslog],
 223   [AS_HELP_STRING([--enable-syslog],
 224     [enable use of syslog (default: disabled), one of no/yes/only])],
 225   [[case "$enableval" in
 226       no)
 227         SYSLOG=no
 228         ;;
 229       yes)
 230         SYSLOG=yes
 231         ;;
 232       only)
 233         SYSLOG=only
 234         ;;
 235       *)
 236         SYSLOG=
 237         ;;
 238     esac
 239   ]],
 240   [SYSLOG=no])
 241
 242 if test -z "$SYSLOG"
 243 then
 244   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 245 fi
 246 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 247
 248 # --enable-htools
 249 HTOOLS=
 250 AC_ARG_ENABLE([htools],
 251         [AS_HELP_STRING([--enable-htools],
 252         [enable use of htools (needs GHC and libraries, default: check)])],
 253         [],
 254         [enable_htools=check])
 255
 256 # --enable-htools-rapi
 257 HTOOLS_RAPI=
 258 AC_ARG_ENABLE([htools-rapi],
 259         [AS_HELP_STRING([--enable-htools-rapi],
 260         [enable use of RAPI in htools (needs curl, default: no)])],
 261         [],
 262         [enable_htools_rapi=no])
 263
 264 # --with-disk-separator=...
 265 AC_ARG_WITH([disk-separator],
 266   [AS_HELP_STRING([--with-disk-separator=STRING],
 267     [Disk index separator, useful if the default of ':' is handled]
 268     [ specially by the hypervisor]
 269   )],
 270   [disk_separator="$withval"],
 271   [disk_separator=":"])
 272 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 273
 274 # Check common programs
 275 AC_PROG_INSTALL
 276 AC_PROG_LN_S
 277
 278 # Check for the ip command
 279 AC_ARG_VAR(IP_PATH, [ip path])
 280 AC_PATH_PROG(IP_PATH, [ip], [])
 281 if test -z "$IP_PATH"
 282 then
 283   AC_MSG_ERROR([ip command not found])
 284 fi
 285
 286 # Check for pandoc
 287 AC_ARG_VAR(PANDOC, [pandoc path])
 288 AC_PATH_PROG(PANDOC, [pandoc], [])
 289 if test -z "$PANDOC"
 290 then
 291   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 292 fi
 293
 294 # Check for python-sphinx
 295 AC_ARG_VAR(SPHINX, [sphinx-build path])
 296 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 297 if test -z "$SPHINX"
 298 then
 299   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 300                             not be possible]))
 301 fi
 302
 303 # Check for graphviz (dot)
 304 AC_ARG_VAR(DOT, [dot path])
 305 AC_PATH_PROG(DOT, [dot], [])
 306 if test -z "$DOT"
 307 then
 308   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 309                             documentation rebuild not possible]))
 310 fi
 311
 312 # Check for pylint
 313 AC_ARG_VAR(PYLINT, [pylint path])
 314 AC_PATH_PROG(PYLINT, [pylint], [])
 315 if test -z "$PYLINT"
 316 then
 317   AC_MSG_WARN([pylint not found, checking code will not be possible])
 318 fi
 319
 320 # Check for socat
 321 AC_ARG_VAR(SOCAT, [socat path])
 322 AC_PATH_PROG(SOCAT, [socat], [])
 323 if test -z "$SOCAT"
 324 then
 325   AC_MSG_ERROR([socat not found])
 326 fi
 327
 328 if test "$enable_htools" != "no"; then
 329
 330 # Check for ghc
 331 AC_ARG_VAR(GHC, [ghc path])
 332 AC_PATH_PROG(GHC, [ghc], [])
 333 if test -z "$GHC"; then
 334   if test "$enable_htools" != "check"; then
 335     AC_MSG_FAILURE([ghc not found, htools compilation will not possible])
 336   fi
 337 fi
 338
 339 # Check for ghc-pkg
 340 HTOOLS_MODULES=
 341 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 342 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 343 if test -z "$GHC_PKG"; then
 344   if test "$enable_htools" != "check"; then
 345     AC_MSG_FAILURE([ghc-pkg not found, htools compilation will not be possible])
 346   fi
 347 else
 348   # check for modules
 349   AC_MSG_NOTICE([checking for required haskell modules])
 350   HTOOLS_NOCURL=-DNO_CURL
 351   if test "$enable_htools_rapi" != "no"; then
 352     AC_MSG_CHECKING([curl])
 353     GHC_PKG_CURL=$($GHC_PKG latest curl)
 354     if test -z "$GHC_PKG_CURL"; then
 355       if test "$enable_htools_rapi" = "check"; then
 356         AC_MSG_WARN(m4_normalize([The curl library not found, htools will be
 357                                   compiled without RAPI support]))
 358       else
 359         AC_MSG_FAILURE(m4_normalize([The curl library was not found, but it has
 360                                      been requested]))
 361       fi
 362     else
 363       HTOOLS_NOCURL=
 364     fi
 365     AC_MSG_RESULT($GHC_PKG_CURL)
 366   fi
 367   AC_SUBST(GHC_PKG_CURL)
 368   AC_SUBST(HTOOLS_NOCURL)
 369   AC_MSG_CHECKING([parallel])
 370   GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-3.*')
 371   if test -n "$GHC_PKG_PARALLEL"
 372   then
 373     HTOOLS_PARALLEL3=-DPARALLEL3
 374   else
 375     GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-2.*')
 376   fi
 377   if test -z "$GHC_PKG_PARALLEL"
 378   then
 379     GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-1.*')
 380   fi
 381   AC_SUBST(GHC_PKG_PARALLEL)
 382   AC_SUBST(HTOOLS_PARALLEL3)
 383   AC_MSG_RESULT($GHC_PKG_PARALLEL)
 384   AC_MSG_CHECKING([json])
 385   GHC_PKG_JSON=$($GHC_PKG latest json)
 386   AC_MSG_RESULT($GHC_PKG_JSON)
 387   AC_MSG_CHECKING([network])
 388   GHC_PKG_NETWORK=$($GHC_PKG latest network)
 389   AC_MSG_RESULT($GHC_PKG_NETWORK)
 390   AC_MSG_CHECKING([QuickCheck 2.x])
 391   GHC_PKG_QUICKCHECK=$($GHC_PKG --simple-output list 'QuickCheck-2.*')
 392   AC_MSG_RESULT($GHC_PKG_QUICKCHECK)
 393   if test -z "$GHC_PKG_PARALLEL" || test -z "$GHC_PKG_JSON" || \
 394      test -z "$GHC_PKG_NETWORK"; then
 395     if test "$enable_htools" != "check"; then
 396       AC_MSG_FAILURE(m4_normalize([Required Haskell modules not found, htools
 397                                    compilation disabled]))
 398     fi
 399   else
 400     # we leave the other modules to be auto-selected
 401     HTOOLS_MODULES="-package $GHC_PKG_PARALLEL"
 402   fi
 403   if test -z "$GHC_PKG_QUICKCHECK"; then
 404      AC_MSG_WARN(m4_normalize([The QuickCheck 2.x module was not found,
 405                                you won't be able to run Haskell unittests]))
 406   fi
 407 fi
 408 AC_SUBST(HTOOLS_MODULES)
 409 AC_SUBST(GHC_PKG_QUICKCHECK)
 410
 411 if test "$enable_htools" != "no"; then
 412   if test -z "$GHC" || test -z "$HTOOLS_MODULES"; then
 413     AC_MSG_WARN(m4_normalize([Haskell compiler/required libraries not found,
 414                               htools compilation disabled]))
 415   else
 416     HTOOLS=yes
 417   fi
 418 fi
 419 AC_SUBST(HTOOLS)
 420
 421 # Check for HsColour
 422 HTOOLS_APIDOC=no
 423 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 424 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 425 if test -z "$HSCOLOUR"; then
 426   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 427                             not be generated]))
 428 fi
 429
 430 # Check for haddock
 431 AC_ARG_VAR(HADDOCK, [haddock path])
 432 AC_PATH_PROG(HADDOCK, [haddock], [])
 433 if test -z "$HADDOCK"; then
 434   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 435                             not be generated]))
 436 fi
 437 if test "$HADDOCK" && test "$HSCOLOUR"; then
 438   HTOOLS_APIDOC=yes
 439 fi
 440 AC_SUBST(HTOOLS_APIDOC)
 441
 442 fi # end if enable_htools, define automake conditions
 443
 444 AM_CONDITIONAL([WANT_HTOOLS], [test x$HTOOLS = xyes])
 445 AM_CONDITIONAL([WANT_HTOOLSTESTS], [test x$GHC_PKG_QUICKCHECK != x])
 446 AM_CONDITIONAL([WANT_HTOOLSAPIDOC], [test x$HTOOLS_APIDOC = xyes])
 447
 448 SOCAT_USE_ESCAPE=
 449 AC_ARG_ENABLE([socat-escape],
 450   [AS_HELP_STRING([--enable-socat-escape],
 451     [use escape functionality available in socat >= 1.7 (default: detect
 452      automatically)])],
 453   [[if test "$enableval" = yes; then
 454       SOCAT_USE_ESCAPE=True
 455     else
 456       SOCAT_USE_ESCAPE=False
 457     fi
 458   ]])
 459
 460 if test -z "$SOCAT_USE_ESCAPE"
 461 then
 462   if $SOCAT -hh | grep -w -q escape; then
 463     SOCAT_USE_ESCAPE=True
 464   else
 465     SOCAT_USE_ESCAPE=False
 466   fi
 467 fi
 468
 469 AC_SUBST(SOCAT_USE_ESCAPE)
 470
 471 SOCAT_USE_COMPRESS=
 472 AC_ARG_ENABLE([socat-compress],
 473   [AS_HELP_STRING([--enable-socat-compress],
 474     [use OpenSSL compression option available in patched socat builds
 475      (see INSTALL for details; default: detect automatically)])],
 476   [[if test "$enableval" = yes; then
 477       SOCAT_USE_COMPRESS=True
 478     else
 479       SOCAT_USE_COMPRESS=False
 480     fi
 481   ]])
 482
 483 if test -z "$SOCAT_USE_COMPRESS"
 484 then
 485   if $SOCAT -hhh | grep -w -q openssl-compress; then
 486     SOCAT_USE_COMPRESS=True
 487   else
 488     SOCAT_USE_COMPRESS=False
 489   fi
 490 fi
 491
 492 AC_SUBST(SOCAT_USE_COMPRESS)
 493
 494 if man --help | grep -q -e --warnings
 495 then
 496   MAN_HAS_WARNINGS=1
 497 else
 498   MAN_HAS_WARNINGS=
 499   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 500                             will not be possible]))
 501 fi
 502
 503 AC_SUBST(MAN_HAS_WARNINGS)
 504
 505 # Check for Python
 506 AM_PATH_PYTHON(2.4)
 507
 508 AC_PYTHON_MODULE(OpenSSL, t)
 509 AC_PYTHON_MODULE(simplejson, t)
 510 AC_PYTHON_MODULE(pyparsing, t)
 511 AC_PYTHON_MODULE(pyinotify, t)
 512 AC_PYTHON_MODULE(pycurl, t)
 513
 514 # This is optional but then we've limited functionality
 515 AC_PYTHON_MODULE(paramiko)
 516 if test "$HAVE_PYMOD_PARAMIKO" = "no"; then
 517   AC_MSG_WARN(m4_normalize([You do not have Paramiko installed. While this is
 518                             optional you have to configure SSH and the node
 519                             daemon on the joining nodes yourself.]))
 520 fi
 521
 522 AC_CONFIG_FILES([ Makefile ])
 523
 524 AC_OUTPUT