code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [9])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~alpha1])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-xen-config-dir=...
  53 AC_ARG_WITH([xen-config-dir],
  54   [AS_HELP_STRING([--with-xen-config-dir=DIR],
  55                   m4_normalize([Xen configuration directory
  56                                 (default: /etc/xen)]))],
  57   [xen_config_dir="$withval"],
  58   [xen_config_dir=/etc/xen])
  59 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
  60
  61 # --with-os-search-path=...
  62 # do a bit of black sed magic to for quoting of the strings in the list
  63 AC_ARG_WITH([os-search-path],
  64   [AS_HELP_STRING([--with-os-search-path=LIST],
  65     [comma separated list of directories to]
  66     [ search for OS images (default is /srv/ganeti/os)]
  67   )],
  68   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  69   [os_search_path="'/srv/ganeti/os'"])
  70 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  71
  72 # --with-extstorage-search-path=...
  73 # same black sed magic for quoting of the strings in the list
  74 AC_ARG_WITH([extstorage-search-path],
  75   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  76     [comma separated list of directories to]
  77     [ search for External Storage Providers]
  78     [ (default is /srv/ganeti/extstorage)]
  79   )],
  80   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  81   [es_search_path="'/srv/ganeti/extstorage'"])
  82 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  83
  84 # --with-iallocator-search-path=...
  85 # do a bit of black sed magic to for quoting of the strings in the list
  86 AC_ARG_WITH([iallocator-search-path],
  87   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  88     [comma separated list of directories to]
  89     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  90   )],
  91   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  92   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  93 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  94
  95 # --with-xen-bootloader=...
  96 AC_ARG_WITH([xen-bootloader],
  97   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  98     [bootloader for Xen hypervisor (default is empty)]
  99   )],
 100   [xen_bootloader="$withval"],
 101   [xen_bootloader=])
 102 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
 103
 104 # --with-xen-kernel=...
 105 AC_ARG_WITH([xen-kernel],
 106   [AS_HELP_STRING([--with-xen-kernel=PATH],
 107     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
 108   )],
 109   [xen_kernel="$withval"],
 110   [xen_kernel="/boot/vmlinuz-3-xenU"])
 111 AC_SUBST(XEN_KERNEL, $xen_kernel)
 112
 113 # --with-xen-initrd=...
 114 AC_ARG_WITH([xen-initrd],
 115   [AS_HELP_STRING([--with-xen-initrd=PATH],
 116     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 117   )],
 118   [xen_initrd="$withval"],
 119   [xen_initrd="/boot/initrd-3-xenU"])
 120 AC_SUBST(XEN_INITRD, $xen_initrd)
 121
 122 # --with-kvm-kernel=...
 123 AC_ARG_WITH([kvm-kernel],
 124   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 125     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 126   )],
 127   [kvm_kernel="$withval"],
 128   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 129 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 130
 131 # --with-file-storage-dir=...
 132 AC_ARG_WITH([file-storage-dir],
 133   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 134     [directory to store files for file-based backend]
 135     [ (default is /srv/ganeti/file-storage)]
 136   )],
 137   [[file_storage_dir="/srv/ganeti/file-storage"]])
 138 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 139
 140 # --with-shared-file-storage-dir=...
 141 AC_ARG_WITH([shared-file-storage-dir],
 142   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 143     [directory to store files for shared file-based backend]
 144     [ (default is /srv/ganeti/shared-file-storage)]
 145   )],
 146   [[shared_file_storage_dir="$withval";
 147     if test "$withval" != no; then
 148       enable_shared_file_storage=True
 149     else
 150       enable_shared_file_storage=False
 151     fi
 152   ]],
 153   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 154     enable_shared_file_storage=True]])
 155 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 156 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 157
 158 # --with-kvm-path=...
 159 AC_ARG_WITH([kvm-path],
 160   [AS_HELP_STRING([--with-kvm-path=PATH],
 161     [absolute path to the kvm binary]
 162     [ (default is /usr/bin/kvm)]
 163   )],
 164   [kvm_path="$withval"],
 165   [kvm_path="/usr/bin/kvm"])
 166 AC_SUBST(KVM_PATH, $kvm_path)
 167
 168 # --with-lvm-stripecount=...
 169 AC_ARG_WITH([lvm-stripecount],
 170   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 171     [the default number of stripes to use for LVM volumes]
 172     [ (default is 1)]
 173   )],
 174   [lvm_stripecount="$withval"],
 175   [lvm_stripecount=1])
 176 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 177
 178 # --with-ssh-login-user=...
 179 AC_ARG_WITH([ssh-login-user],
 180   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 181     [user to use for SSH logins within the cluster (default is root)]
 182   )],
 183   [ssh_login_user="$withval"],
 184   [ssh_login_user=root])
 185 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 186
 187 # --with-ssh-console-user=...
 188 AC_ARG_WITH([ssh-console-user],
 189   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 190     [user to use for SSH logins to access instance consoles (default is root)]
 191   )],
 192   [ssh_console_user="$withval"],
 193   [ssh_console_user=root])
 194 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 195
 196 # --with-default-user=...
 197 AC_ARG_WITH([default-user],
 198   [AS_HELP_STRING([--with-default-user=USERNAME],
 199     [default user for daemons]
 200     [ (default is to run all daemons as root)]
 201   )],
 202   [user_default="$withval"],
 203   [user_default=root])
 204
 205 # --with-default-group=...
 206 AC_ARG_WITH([default-group],
 207   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 208     [default group for daemons]
 209     [ (default is to run all daemons under group root)]
 210   )],
 211   [group_default="$withval"],
 212   [group_default=root])
 213
 214 # --with-user-prefix=...
 215 AC_ARG_WITH([user-prefix],
 216   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 217     [prefix for daemon users]
 218     [ (default is to run all daemons as root; use --with-default-user]
 219     [ to change the default)]
 220   )],
 221   [user_masterd="${withval}masterd";
 222    user_rapi="${withval}rapi";
 223    user_confd="${withval}confd";
 224    user_noded="$user_default";
 225    user_mond="$user_default"],
 226   [user_masterd="$user_default";
 227    user_rapi="$user_default";
 228    user_confd="$user_default";
 229    user_noded="$user_default";
 230    user_mond="$user_default"])
 231 AC_SUBST(MASTERD_USER, $user_masterd)
 232 AC_SUBST(RAPI_USER, $user_rapi)
 233 AC_SUBST(CONFD_USER, $user_confd)
 234 AC_SUBST(NODED_USER, $user_noded)
 235 AC_SUBST(MOND_USER, $user_mond)
 236
 237 # --with-group-prefix=...
 238 AC_ARG_WITH([group-prefix],
 239   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 240     [prefix for daemon POSIX groups]
 241     [ (default is to run all daemons under group root; use]
 242     [ --with-default-group to change the default)]
 243   )],
 244   [group_rapi="${withval}rapi";
 245    group_admin="${withval}admin";
 246    group_confd="${withval}confd";
 247    group_masterd="${withval}masterd";
 248    group_noded="$group_default";
 249    group_daemons="${withval}daemons";
 250    group_mond="$group_default"],
 251   [group_rapi="$group_default";
 252    group_admin="$group_default";
 253    group_confd="$group_default";
 254    group_masterd="$group_default";
 255    group_noded="$group_default";
 256    group_daemons="$group_default";
 257    group_mond="$group_default"])
 258 AC_SUBST(RAPI_GROUP, $group_rapi)
 259 AC_SUBST(ADMIN_GROUP, $group_admin)
 260 AC_SUBST(CONFD_GROUP, $group_confd)
 261 AC_SUBST(MASTERD_GROUP, $group_masterd)
 262 AC_SUBST(NODED_GROUP, $group_noded)
 263 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 264 AC_SUBST(MOND_GROUP, $group_mond)
 265
 266 # Print the config to the user
 267 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 268 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 269 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 270 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 271 AC_MSG_NOTICE([Group for clients is $group_admin])
 272
 273 # --enable-drbd-barriers
 274 AC_ARG_ENABLE([drbd-barriers],
 275   [AS_HELP_STRING([--enable-drbd-barriers],
 276                   m4_normalize([enable the DRBD barriers functionality by
 277                                 default (>= 8.0.12) (default: enabled)]))],
 278   [[if test "$enableval" != no; then
 279       DRBD_BARRIERS=n
 280       DRBD_NO_META_FLUSH=False
 281     else
 282       DRBD_BARRIERS=bf
 283       DRBD_NO_META_FLUSH=True
 284     fi
 285   ]],
 286   [DRBD_BARRIERS=n
 287    DRBD_NO_META_FLUSH=False
 288   ])
 289 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 290 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 291
 292 # --enable-syslog[=no/yes/only]
 293 AC_ARG_ENABLE([syslog],
 294   [AS_HELP_STRING([--enable-syslog],
 295     [enable use of syslog (default: disabled), one of no/yes/only])],
 296   [[case "$enableval" in
 297       no)
 298         SYSLOG=no
 299         ;;
 300       yes)
 301         SYSLOG=yes
 302         ;;
 303       only)
 304         SYSLOG=only
 305         ;;
 306       *)
 307         SYSLOG=
 308         ;;
 309     esac
 310   ]],
 311   [SYSLOG=no])
 312
 313 if test -z "$SYSLOG"
 314 then
 315   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 316 fi
 317 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 318
 319 AC_ARG_ENABLE([restricted-commands],
 320   [AS_HELP_STRING([--enable-restricted-commands],
 321                   m4_normalize([enable restricted commands in the node daemon
 322                                 (default: disabled)]))],
 323   [[if test "$enableval" = no; then
 324       enable_restricted_commands=False
 325     else
 326       enable_restricted_commands=True
 327     fi
 328   ]],
 329   [enable_restricted_commands=False])
 330 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 331
 332 # --with-disk-separator=...
 333 AC_ARG_WITH([disk-separator],
 334   [AS_HELP_STRING([--with-disk-separator=STRING],
 335     [Disk index separator, useful if the default of ':' is handled]
 336     [ specially by the hypervisor]
 337   )],
 338   [disk_separator="$withval"],
 339   [disk_separator=":"])
 340 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 341
 342 # Check common programs
 343 AC_PROG_INSTALL
 344 AC_PROG_LN_S
 345
 346 # Check for the ip command
 347 AC_ARG_VAR(IP_PATH, [ip path])
 348 AC_PATH_PROG(IP_PATH, [ip], [])
 349 if test -z "$IP_PATH"
 350 then
 351   AC_MSG_ERROR([ip command not found])
 352 fi
 353
 354 # Check for pandoc
 355 AC_ARG_VAR(PANDOC, [pandoc path])
 356 AC_PATH_PROG(PANDOC, [pandoc], [])
 357 if test -z "$PANDOC"
 358 then
 359   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 360 fi
 361
 362 # Check for python-sphinx
 363 AC_ARG_VAR(SPHINX, [sphinx-build path])
 364 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 365 if test -z "$SPHINX"
 366 then
 367   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 368                             not be possible]))
 369 else
 370   # Sphinx exits with code 1 when it prints its usage
 371   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
 372
 373   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
 374     AC_MSG_ERROR([Unable to determine Sphinx version])
 375
 376   # Note: Character classes ([...]) need to be double quoted due to autoconf
 377   # using m4
 378   elif ! echo "$sphinxver" | grep -q -E '^Sphinx[[[:space:]]]+v[[1-9]]\>'; then
 379     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
 380   fi
 381 fi
 382
 383 AC_ARG_ENABLE([manpages-in-doc],
 384   [AS_HELP_STRING([--enable-manpages-in-doc],
 385                   m4_normalize([include man pages in HTML documentation
 386                                 (requires sphinx; default disabled)]))],
 387   [case "$enableval" in
 388       yes) manpages_in_doc=yes ;;
 389       no) manpages_in_doc= ;;
 390       *)
 391         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 392         ;;
 393     esac
 394   ],
 395   [manpages_in_doc=])
 396 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 397 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 398
 399 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 400   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 401 fi
 402
 403 # Check for graphviz (dot)
 404 AC_ARG_VAR(DOT, [dot path])
 405 AC_PATH_PROG(DOT, [dot], [])
 406 if test -z "$DOT"
 407 then
 408   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 409                             documentation rebuild not possible]))
 410 fi
 411
 412 # Check for pylint
 413 AC_ARG_VAR(PYLINT, [pylint path])
 414 AC_PATH_PROG(PYLINT, [pylint], [])
 415 if test -z "$PYLINT"
 416 then
 417   AC_MSG_WARN([pylint not found, checking code will not be possible])
 418 fi
 419
 420 # Check for pep8
 421 AC_ARG_VAR(PEP8, [pep8 path])
 422 AC_PATH_PROG(PEP8, [pep8], [])
 423 if test -z "$PEP8"
 424 then
 425   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 426 fi
 427 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 428
 429 # Check for python-coverage
 430 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 431 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 432 if test -z "$PYCOVERAGE"
 433 then
 434   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 435                             Python test coverage will not be possible]))
 436 fi
 437
 438 # Check for socat
 439 AC_ARG_VAR(SOCAT, [socat path])
 440 AC_PATH_PROG(SOCAT, [socat], [])
 441 if test -z "$SOCAT"
 442 then
 443   AC_MSG_ERROR([socat not found])
 444 fi
 445
 446 # Check for qemu-img
 447 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 448 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 449 if test -z "$QEMUIMG_PATH"
 450 then
 451   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 452 fi
 453
 454 # --enable-confd
 455 ENABLE_CONFD=
 456 AC_ARG_ENABLE([confd],
 457   [AS_HELP_STRING([--enable-confd],
 458   [enable the ganeti-confd daemon (default: check)])],
 459   [],
 460   [enable_confd=check])
 461
 462 ENABLE_MOND=
 463 AC_ARG_ENABLE([monitoring],
 464   [AS_HELP_STRING([--enable-monitoring],
 465   [enable the ganeti monitoring daemon (default: check)])],
 466   [],
 467   [enable_monitoring=check])
 468
 469 # Check for ghc
 470 AC_ARG_VAR(GHC, [ghc path])
 471 AC_PATH_PROG(GHC, [ghc], [])
 472 if test -z "$GHC"; then
 473   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 474 fi
 475
 476 AC_MSG_CHECKING([checking for extra GHC flags])
 477 GHC_BYVERSION_FLAGS=
 478 # check for GHC supported flags that vary accross versions
 479 for flag in -fwarn-incomplete-uni-patterns; do
 480   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 481    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 482   fi
 483 done
 484 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 485 AC_SUBST(GHC_BYVERSION_FLAGS)
 486
 487 # Check for ghc-pkg
 488 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 489 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 490 if test -z "$GHC_PKG"; then
 491   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 492 fi
 493
 494 # check for modules, first custom/special checks
 495 AC_MSG_NOTICE([checking for required haskell modules])
 496 HS_PARALLEL3=
 497 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 498                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 499 AC_SUBST(HS_PARALLEL3)
 500
 501 # and now standard modules
 502 AC_GHC_PKG_REQUIRE(curl)
 503 AC_GHC_PKG_REQUIRE(json)
 504 AC_GHC_PKG_REQUIRE(network)
 505 AC_GHC_PKG_REQUIRE(mtl)
 506 AC_GHC_PKG_REQUIRE(bytestring)
 507 AC_GHC_PKG_REQUIRE(utf8-string)
 508
 509 # extra modules for confd functionality
 510 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 511 has_confd=False
 512 if test "$enable_confd" != no; then
 513   CONFD_PKG=
 514   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 515                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 516   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 517   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 518   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 519   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 520   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 521   if test -z "$CONFD_PKG"; then
 522     has_confd=True
 523   elif test "$enable_confd" = check; then
 524     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 525                               not found ($CONFD_PKG), confd disabled]))
 526   else
 527     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 528                                  required libraries were not found:
 529                                  $CONFD_PKG]))
 530   fi
 531 fi
 532 AC_SUBST(HS_REGEX_PCRE)
 533 if test "$has_confd" = True; then
 534   AC_MSG_NOTICE([Enabling confd usage])
 535 fi
 536 AC_SUBST(ENABLE_CONFD, $has_confd)
 537 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 538
 539 #extra modules for monitoring daemon functionality
 540 has_monitoring=False
 541 if test "$enable_monitoring" != no; then
 542   MONITORING_PKG=
 543   AC_GHC_PKG_CHECK([attoparsec], [],
 544                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 545   AC_GHC_PKG_CHECK([snap-server], [],
 546                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
 547   AC_GHC_PKG_CHECK([process], [],
 548                    [MONITORING_PKG="$MONITORING_PKG process"])
 549   MONITORING_DEP=
 550   if test "$has_confd" = False; then
 551     MONITORING_DEP="$MONITORING_DEP confd"
 552   fi
 553   has_monitoring_pkg=False
 554   if test -z "$MONITORING_PKG"; then
 555     has_monitoring_pkg=True
 556   elif test "$enable_monitoring" = check; then
 557     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 558                               daemon were not found ($MONITORING_PKG),
 559                               monitoring disabled]))
 560   else
 561     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 562                                  required libraries were not found:
 563                                  $MONITORING_PKG]))
 564   fi
 565   has_monitoring_dep=False
 566   if test -z "$MONITORING_DEP"; then
 567     has_monitoring_dep=True
 568   elif test "$enable_monitoring" = check; then
 569     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
 570                               monitoring agent were not enabled
 571                               ($MONITORING_DEP), monitoring disabled]))
 572   else
 573     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 574                                  required optional Ganeti components were not
 575                                  found: $MONITORING_DEP]))
 576   fi
 577
 578 fi
 579 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
 580   has_monitoring=True
 581   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 582 fi
 583 AC_SUBST(ENABLE_MOND, $has_monitoring)
 584 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
 585
 586 # development modules
 587 HS_NODEV=
 588 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 589 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 590 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 591 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 592 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 593 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 594 #        that are needed to execute the tests, avoiding the duplication
 595 #        of the checks.
 596 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 597 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 598 AC_GHC_PKG_CHECK([process], [],
 599                  [MONITORING_PKG="$MONITORING_PKG process"])
 600 if test -n "$HS_NODEV"; then
 601    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 602                              you won't be able to run Haskell unittests]))
 603 else
 604    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 605 fi
 606 AC_SUBST(HS_NODEV)
 607
 608 HTOOLS=yes
 609 AC_SUBST(HTOOLS)
 610
 611 # --enable-split-query
 612 ENABLE_SPLIT_QUERY=
 613 AC_ARG_ENABLE([split-query],
 614   [AS_HELP_STRING([--enable-split-query],
 615   [enable use of custom query daemon via confd])],
 616   [[case "$enableval" in
 617       no)
 618         enable_split_query=False
 619         ;;
 620       yes)
 621         enable_split_query=True
 622         ;;
 623       *)
 624         echo "Invalid value for enable-confd '$enableval'"
 625         exit 1
 626         ;;
 627     esac
 628   ]],
 629   [[case "x${has_confd}x" in
 630      xTruex)
 631        enable_split_query=True
 632        ;;
 633      *)
 634        enable_split_query=False
 635        ;;
 636    esac]])
 637 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 638
 639 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 640   AC_MSG_ERROR([Split queries require the confd daemon])
 641 fi
 642
 643 if test x$enable_split_query = xTrue; then
 644   AC_MSG_NOTICE([Split query functionality enabled])
 645 fi
 646
 647 # Check for HsColour
 648 HS_APIDOC=no
 649 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 650 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 651 if test -z "$HSCOLOUR"; then
 652   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 653                             not be generated]))
 654 fi
 655
 656 # Check for haddock
 657 AC_ARG_VAR(HADDOCK, [haddock path])
 658 AC_PATH_PROG(HADDOCK, [haddock], [])
 659 if test -z "$HADDOCK"; then
 660   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 661                             not be generated]))
 662 fi
 663 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 664   HS_APIDOC=yes
 665 fi
 666 AC_SUBST(HS_APIDOC)
 667
 668 # Check for hlint
 669 AC_ARG_VAR(HLINT, [hlint path])
 670 AC_PATH_PROG(HLINT, [hlint], [])
 671 if test -z "$HLINT"; then
 672   AC_MSG_WARN([hlint not found, checking code will not be possible])
 673 fi
 674
 675 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 676   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 677                              htools support is not enabled]))
 678 fi
 679
 680 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 681 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 682 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 683 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 684
 685 # Check for fakeroot
 686 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 687 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 688 if test -z "$FAKEROOT_PATH"; then
 689   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 690                             will not be executed]))
 691 fi
 692 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 693
 694 SOCAT_USE_ESCAPE=
 695 AC_ARG_ENABLE([socat-escape],
 696   [AS_HELP_STRING([--enable-socat-escape],
 697     [use escape functionality available in socat >= 1.7 (default: detect
 698      automatically)])],
 699   [[if test "$enableval" = yes; then
 700       SOCAT_USE_ESCAPE=True
 701     else
 702       SOCAT_USE_ESCAPE=False
 703     fi
 704   ]])
 705
 706 if test -z "$SOCAT_USE_ESCAPE"
 707 then
 708   if $SOCAT -hh | grep -w -q escape; then
 709     SOCAT_USE_ESCAPE=True
 710   else
 711     SOCAT_USE_ESCAPE=False
 712   fi
 713 fi
 714
 715 AC_SUBST(SOCAT_USE_ESCAPE)
 716
 717 SOCAT_USE_COMPRESS=
 718 AC_ARG_ENABLE([socat-compress],
 719   [AS_HELP_STRING([--enable-socat-compress],
 720     [use OpenSSL compression option available in patched socat builds
 721      (see INSTALL for details; default: detect automatically)])],
 722   [[if test "$enableval" = yes; then
 723       SOCAT_USE_COMPRESS=True
 724     else
 725       SOCAT_USE_COMPRESS=False
 726     fi
 727   ]])
 728
 729 if test -z "$SOCAT_USE_COMPRESS"
 730 then
 731   if $SOCAT -hhh | grep -w -q openssl-compress; then
 732     SOCAT_USE_COMPRESS=True
 733   else
 734     SOCAT_USE_COMPRESS=False
 735   fi
 736 fi
 737
 738 AC_SUBST(SOCAT_USE_COMPRESS)
 739
 740 if man --help | grep -q -e --warnings
 741 then
 742   MAN_HAS_WARNINGS=1
 743 else
 744   MAN_HAS_WARNINGS=
 745   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 746                             will not be possible]))
 747 fi
 748
 749 AC_SUBST(MAN_HAS_WARNINGS)
 750
 751 # Check for Python
 752 AM_PATH_PYTHON(2.6)
 753
 754 AC_PYTHON_MODULE(OpenSSL, t)
 755 AC_PYTHON_MODULE(simplejson, t)
 756 AC_PYTHON_MODULE(pyparsing, t)
 757 AC_PYTHON_MODULE(pyinotify, t)
 758 AC_PYTHON_MODULE(pycurl, t)
 759 AC_PYTHON_MODULE(bitarray, t)
 760 AC_PYTHON_MODULE(ipaddr, t)
 761 AC_PYTHON_MODULE(mock)
 762 AC_PYTHON_MODULE(affinity)
 763 AC_PYTHON_MODULE(paramiko)
 764
 765 # Development-only Python modules
 766 PY_NODEV=
 767 AC_PYTHON_MODULE(yaml)
 768 if test $HAVE_PYMOD_YAML == "no"; then
 769   PY_NODEV="$PY_NODEV yaml"
 770 fi
 771
 772 if test -n "$PY_NODEV"; then
 773   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
 774                             found, you won't be able to run Python unittests]))
 775 else
 776    AC_MSG_NOTICE([Python development modules found, unittests enabled])
 777 fi
 778 AC_SUBST(PY_NODEV)
 779 AM_CONDITIONAL([PY_NODEV], [test -n $PY_NODEV])
 780
 781 AC_CONFIG_FILES([ Makefile ])
 782
 783 AC_OUTPUT