code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [8])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~beta1])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-xen-config-dir=...
  53 AC_ARG_WITH([xen-config-dir],
  54   [AS_HELP_STRING([--with-xen-config-dir=DIR],
  55                   m4_normalize([Xen configuration directory
  56                                 (default: /etc/xen)]))],
  57   [xen_config_dir="$withval"],
  58   [xen_config_dir=/etc/xen])
  59 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
  60
  61 # --with-os-search-path=...
  62 # do a bit of black sed magic to for quoting of the strings in the list
  63 AC_ARG_WITH([os-search-path],
  64   [AS_HELP_STRING([--with-os-search-path=LIST],
  65     [comma separated list of directories to]
  66     [ search for OS images (default is /srv/ganeti/os)]
  67   )],
  68   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  69   [os_search_path="'/srv/ganeti/os'"])
  70 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  71
  72 # --with-extstorage-search-path=...
  73 # same black sed magic for quoting of the strings in the list
  74 AC_ARG_WITH([extstorage-search-path],
  75   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  76     [comma separated list of directories to]
  77     [ search for External Storage Providers]
  78     [ (default is /srv/ganeti/extstorage)]
  79   )],
  80   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  81   [es_search_path="'/srv/ganeti/extstorage'"])
  82 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  83
  84 # --with-iallocator-search-path=...
  85 # do a bit of black sed magic to for quoting of the strings in the list
  86 AC_ARG_WITH([iallocator-search-path],
  87   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  88     [comma separated list of directories to]
  89     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  90   )],
  91   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  92   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  93 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  94
  95 # --with-xen-bootloader=...
  96 AC_ARG_WITH([xen-bootloader],
  97   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  98     [bootloader for Xen hypervisor (default is empty)]
  99   )],
 100   [xen_bootloader="$withval"],
 101   [xen_bootloader=])
 102 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
 103
 104 # --with-xen-kernel=...
 105 AC_ARG_WITH([xen-kernel],
 106   [AS_HELP_STRING([--with-xen-kernel=PATH],
 107     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
 108   )],
 109   [xen_kernel="$withval"],
 110   [xen_kernel="/boot/vmlinuz-3-xenU"])
 111 AC_SUBST(XEN_KERNEL, $xen_kernel)
 112
 113 # --with-xen-initrd=...
 114 AC_ARG_WITH([xen-initrd],
 115   [AS_HELP_STRING([--with-xen-initrd=PATH],
 116     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 117   )],
 118   [xen_initrd="$withval"],
 119   [xen_initrd="/boot/initrd-3-xenU"])
 120 AC_SUBST(XEN_INITRD, $xen_initrd)
 121
 122 # --with-xen-cmd=...
 123 AC_ARG_WITH([xen-cmd],
 124   [AS_HELP_STRING([--with-xen-cmd=CMD],
 125     [Sets the xen cli interface command (default is xm)]
 126   )],
 127   [xen_cmd="$withval"],
 128   [xen_cmd=xm])
 129 AC_SUBST(XEN_CMD, $xen_cmd)
 130
 131 if ! test "$XEN_CMD" = xl -o "$XEN_CMD" = xm; then
 132   AC_MSG_ERROR([Unsupported xen command specified])
 133 fi
 134
 135 # --with-kvm-kernel=...
 136 AC_ARG_WITH([kvm-kernel],
 137   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 138     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 139   )],
 140   [kvm_kernel="$withval"],
 141   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 142 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 143
 144 # --with-file-storage-dir=...
 145 AC_ARG_WITH([file-storage-dir],
 146   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 147     [directory to store files for file-based backend]
 148     [ (default is /srv/ganeti/file-storage)]
 149   )],
 150   [[file_storage_dir="$withval";
 151     if test "$withval" != no; then
 152       enable_file_storage=True
 153     else
 154       enable_file_storage=False
 155     fi
 156   ]],
 157   [[file_storage_dir="/srv/ganeti/file-storage";
 158     enable_file_storage=True]])
 159 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 160 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 161
 162 # --with-shared-file-storage-dir=...
 163 AC_ARG_WITH([shared-file-storage-dir],
 164   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 165     [directory to store files for shared file-based backend]
 166     [ (default is /srv/ganeti/shared-file-storage)]
 167   )],
 168   [[shared_file_storage_dir="$withval";
 169     if test "$withval" != no; then
 170       enable_shared_file_storage=True
 171     else
 172       enable_shared_file_storage=False
 173     fi
 174   ]],
 175   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 176     enable_shared_file_storage=True]])
 177 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 178 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 179
 180 # --with-kvm-path=...
 181 AC_ARG_WITH([kvm-path],
 182   [AS_HELP_STRING([--with-kvm-path=PATH],
 183     [absolute path to the kvm binary]
 184     [ (default is /usr/bin/kvm)]
 185   )],
 186   [kvm_path="$withval"],
 187   [kvm_path="/usr/bin/kvm"])
 188 AC_SUBST(KVM_PATH, $kvm_path)
 189
 190 # --with-lvm-stripecount=...
 191 AC_ARG_WITH([lvm-stripecount],
 192   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 193     [the default number of stripes to use for LVM volumes]
 194     [ (default is 1)]
 195   )],
 196   [lvm_stripecount="$withval"],
 197   [lvm_stripecount=1])
 198 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 199
 200 # --with-ssh-login-user=...
 201 AC_ARG_WITH([ssh-login-user],
 202   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 203     [user to use for SSH logins within the cluster (default is root)]
 204   )],
 205   [ssh_login_user="$withval"],
 206   [ssh_login_user=root])
 207 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 208
 209 # --with-ssh-console-user=...
 210 AC_ARG_WITH([ssh-console-user],
 211   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 212     [user to use for SSH logins to access instance consoles (default is root)]
 213   )],
 214   [ssh_console_user="$withval"],
 215   [ssh_console_user=root])
 216 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 217
 218 # --with-default-user=...
 219 AC_ARG_WITH([default-user],
 220   [AS_HELP_STRING([--with-default-user=USERNAME],
 221     [default user for daemons]
 222     [ (default is to run all daemons as root)]
 223   )],
 224   [user_default="$withval"],
 225   [user_default=root])
 226
 227 # --with-default-group=...
 228 AC_ARG_WITH([default-group],
 229   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 230     [default group for daemons]
 231     [ (default is to run all daemons under group root)]
 232   )],
 233   [group_default="$withval"],
 234   [group_default=root])
 235
 236 # --with-user-prefix=...
 237 AC_ARG_WITH([user-prefix],
 238   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 239     [prefix for daemon users]
 240     [ (default is to run all daemons as root; use --with-default-user]
 241     [ to change the default)]
 242   )],
 243   [user_masterd="${withval}masterd";
 244    user_rapi="${withval}rapi";
 245    user_confd="${withval}confd";
 246    user_luxid="${withval}luxid";
 247    user_noded="$user_default";
 248    user_mond="${withval}mond"],
 249   [user_masterd="$user_default";
 250    user_rapi="$user_default";
 251    user_confd="$user_default";
 252    user_luxid="$user_default";
 253    user_noded="$user_default";
 254    user_mond="$user_default"])
 255 AC_SUBST(MASTERD_USER, $user_masterd)
 256 AC_SUBST(RAPI_USER, $user_rapi)
 257 AC_SUBST(CONFD_USER, $user_confd)
 258 AC_SUBST(LUXID_USER, $user_luxid)
 259 AC_SUBST(NODED_USER, $user_noded)
 260 AC_SUBST(MOND_USER, $user_mond)
 261
 262 # --with-group-prefix=...
 263 AC_ARG_WITH([group-prefix],
 264   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 265     [prefix for daemon POSIX groups]
 266     [ (default is to run all daemons under group root; use]
 267     [ --with-default-group to change the default)]
 268   )],
 269   [group_rapi="${withval}rapi";
 270    group_admin="${withval}admin";
 271    group_confd="${withval}confd";
 272    group_luxid="${withval}luxid";
 273    group_masterd="${withval}masterd";
 274    group_noded="$group_default";
 275    group_daemons="${withval}daemons";
 276    group_mond="${withval}mond"],
 277   [group_rapi="$group_default";
 278    group_admin="$group_default";
 279    group_confd="$group_default";
 280    group_luxid="$group_default";
 281    group_masterd="$group_default";
 282    group_noded="$group_default";
 283    group_daemons="$group_default";
 284    group_mond="$group_default"])
 285 AC_SUBST(RAPI_GROUP, $group_rapi)
 286 AC_SUBST(ADMIN_GROUP, $group_admin)
 287 AC_SUBST(CONFD_GROUP, $group_confd)
 288 AC_SUBST(LUXID_GROUP, $group_luxid)
 289 AC_SUBST(MASTERD_GROUP, $group_masterd)
 290 AC_SUBST(NODED_GROUP, $group_noded)
 291 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 292 AC_SUBST(MOND_GROUP, $group_mond)
 293
 294 # Print the config to the user
 295 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 296 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 297 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 298 AC_MSG_NOTICE([Running ganeti-luxid as $user_luxid:$group_luxid])
 299 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 300 AC_MSG_NOTICE([Group for clients is $group_admin])
 301
 302 # --enable-drbd-barriers
 303 AC_ARG_ENABLE([drbd-barriers],
 304   [AS_HELP_STRING([--enable-drbd-barriers],
 305                   m4_normalize([enable the DRBD barriers functionality by
 306                                 default (>= 8.0.12) (default: enabled)]))],
 307   [[if test "$enableval" != no; then
 308       DRBD_BARRIERS=n
 309       DRBD_NO_META_FLUSH=False
 310     else
 311       DRBD_BARRIERS=bf
 312       DRBD_NO_META_FLUSH=True
 313     fi
 314   ]],
 315   [DRBD_BARRIERS=n
 316    DRBD_NO_META_FLUSH=False
 317   ])
 318 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 319 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 320
 321 # --enable-syslog[=no/yes/only]
 322 AC_ARG_ENABLE([syslog],
 323   [AS_HELP_STRING([--enable-syslog],
 324     [enable use of syslog (default: disabled), one of no/yes/only])],
 325   [[case "$enableval" in
 326       no)
 327         SYSLOG=no
 328         ;;
 329       yes)
 330         SYSLOG=yes
 331         ;;
 332       only)
 333         SYSLOG=only
 334         ;;
 335       *)
 336         SYSLOG=
 337         ;;
 338     esac
 339   ]],
 340   [SYSLOG=no])
 341
 342 if test -z "$SYSLOG"
 343 then
 344   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 345 fi
 346 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 347
 348 AC_ARG_ENABLE([restricted-commands],
 349   [AS_HELP_STRING([--enable-restricted-commands],
 350                   m4_normalize([enable restricted commands in the node daemon
 351                                 (default: disabled)]))],
 352   [[if test "$enableval" = no; then
 353       enable_restricted_commands=False
 354     else
 355       enable_restricted_commands=True
 356     fi
 357   ]],
 358   [enable_restricted_commands=False])
 359 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 360
 361 # --with-disk-separator=...
 362 AC_ARG_WITH([disk-separator],
 363   [AS_HELP_STRING([--with-disk-separator=STRING],
 364     [Disk index separator, useful if the default of ':' is handled]
 365     [ specially by the hypervisor]
 366   )],
 367   [disk_separator="$withval"],
 368   [disk_separator=":"])
 369 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 370
 371 # Check common programs
 372 AC_PROG_INSTALL
 373 AC_PROG_LN_S
 374
 375 # Check for the ip command
 376 AC_ARG_VAR(IP_PATH, [ip path])
 377 AC_PATH_PROG(IP_PATH, [ip], [])
 378 if test -z "$IP_PATH"
 379 then
 380   AC_MSG_ERROR([ip command not found])
 381 fi
 382
 383 # Check for pandoc
 384 AC_ARG_VAR(PANDOC, [pandoc path])
 385 AC_PATH_PROG(PANDOC, [pandoc], [])
 386 if test -z "$PANDOC"
 387 then
 388   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 389 fi
 390
 391 # Check for python-sphinx
 392 AC_ARG_VAR(SPHINX, [sphinx-build path])
 393 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 394 if test -z "$SPHINX"
 395 then
 396   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 397                             not be possible]))
 398 else
 399   # Sphinx exits with code 1 when it prints its usage
 400   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
 401
 402   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
 403     AC_MSG_ERROR([Unable to determine Sphinx version])
 404
 405   # Note: Character classes ([...]) need to be double quoted due to autoconf
 406   # using m4
 407   elif ! echo "$sphinxver" | grep -q -E '^Sphinx[[[:space:]]]+v[[1-9]]\>'; then
 408     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
 409   fi
 410 fi
 411 AM_CONDITIONAL([HAS_SPHINX], [test -n "$SPHINX"])
 412
 413 AC_ARG_ENABLE([manpages-in-doc],
 414   [AS_HELP_STRING([--enable-manpages-in-doc],
 415                   m4_normalize([include man pages in HTML documentation
 416                                 (requires sphinx; default disabled)]))],
 417   [case "$enableval" in
 418       yes) manpages_in_doc=yes ;;
 419       no) manpages_in_doc= ;;
 420       *)
 421         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 422         ;;
 423     esac
 424   ],
 425   [manpages_in_doc=])
 426 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 427 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 428
 429 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 430   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 431 fi
 432
 433 # Check for graphviz (dot)
 434 AC_ARG_VAR(DOT, [dot path])
 435 AC_PATH_PROG(DOT, [dot], [])
 436 if test -z "$DOT"
 437 then
 438   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 439                             documentation rebuild not possible]))
 440 fi
 441
 442 # Check for pylint
 443 AC_ARG_VAR(PYLINT, [pylint path])
 444 AC_PATH_PROG(PYLINT, [pylint], [])
 445 if test -z "$PYLINT"
 446 then
 447   AC_MSG_WARN([pylint not found, checking code will not be possible])
 448 fi
 449
 450 # Check for pep8
 451 AC_ARG_VAR(PEP8, [pep8 path])
 452 AC_PATH_PROG(PEP8, [pep8], [])
 453 if test -z "$PEP8"
 454 then
 455   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 456 fi
 457 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 458
 459 # Check for python-coverage
 460 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 461 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 462 if test -z "$PYCOVERAGE"
 463 then
 464   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 465                             Python test coverage will not be possible]))
 466 fi
 467
 468 # Check for socat
 469 AC_ARG_VAR(SOCAT, [socat path])
 470 AC_PATH_PROG(SOCAT, [socat], [])
 471 if test -z "$SOCAT"
 472 then
 473   AC_MSG_ERROR([socat not found])
 474 fi
 475
 476 # Check for qemu-img
 477 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 478 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 479 if test -z "$QEMUIMG_PATH"
 480 then
 481   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 482 fi
 483
 484 # --enable-confd
 485 ENABLE_CONFD=
 486 AC_ARG_ENABLE([confd],
 487   [AS_HELP_STRING([--enable-confd],
 488   [enable the ganeti-confd daemon (default: check)])],
 489   [],
 490   [enable_confd=check])
 491
 492 ENABLE_MOND=
 493 AC_ARG_ENABLE([monitoring],
 494   [AS_HELP_STRING([--enable-monitoring],
 495   [enable the ganeti monitoring daemon (default: check)])],
 496   [],
 497   [enable_monitoring=check])
 498
 499 # Check for ghc
 500 AC_ARG_VAR(GHC, [ghc path])
 501 AC_PATH_PROG(GHC, [ghc], [])
 502 if test -z "$GHC"; then
 503   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 504 fi
 505
 506 AC_MSG_CHECKING([checking for extra GHC flags])
 507 GHC_BYVERSION_FLAGS=
 508 # check for GHC supported flags that vary accross versions
 509 for flag in -fwarn-incomplete-uni-patterns; do
 510   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 511    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 512   fi
 513 done
 514 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 515 AC_SUBST(GHC_BYVERSION_FLAGS)
 516
 517 # Check for ghc-pkg
 518 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 519 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 520 if test -z "$GHC_PKG"; then
 521   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 522 fi
 523
 524 # check for modules, first custom/special checks
 525 AC_MSG_NOTICE([checking for required haskell modules])
 526 HS_PARALLEL3=
 527 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 528                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 529 AC_SUBST(HS_PARALLEL3)
 530
 531 # and now standard modules
 532 AC_GHC_PKG_REQUIRE(curl)
 533 AC_GHC_PKG_REQUIRE(json)
 534 AC_GHC_PKG_REQUIRE(network)
 535 AC_GHC_PKG_REQUIRE(mtl)
 536 AC_GHC_PKG_REQUIRE(bytestring)
 537 AC_GHC_PKG_REQUIRE(utf8-string)
 538
 539 # extra modules for confd functionality
 540 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 541 has_confd=False
 542 if test "$enable_confd" != no; then
 543   CONFD_PKG=
 544   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 545                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 546   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 547   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 548   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 549   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 550   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 551   if test -z "$CONFD_PKG"; then
 552     has_confd=True
 553   elif test "$enable_confd" = check; then
 554     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 555                               not found ($CONFD_PKG), confd disabled]))
 556   else
 557     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 558                                  required libraries were not found:
 559                                  $CONFD_PKG]))
 560   fi
 561 fi
 562 AC_SUBST(HS_REGEX_PCRE)
 563 if test "$has_confd" = True; then
 564   AC_MSG_NOTICE([Enabling confd usage])
 565 fi
 566 AC_SUBST(ENABLE_CONFD, $has_confd)
 567 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 568
 569 #extra modules for monitoring daemon functionality
 570 has_monitoring=False
 571 if test "$enable_monitoring" != no; then
 572   MONITORING_PKG=
 573   AC_GHC_PKG_CHECK([attoparsec], [],
 574                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 575   AC_GHC_PKG_CHECK([snap-server], [],
 576                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
 577   MONITORING_DEP=
 578   if test "$has_confd" = False; then
 579     MONITORING_DEP="$MONITORING_DEP confd"
 580   fi
 581   has_monitoring_pkg=False
 582   if test -z "$MONITORING_PKG"; then
 583     has_monitoring_pkg=True
 584   elif test "$enable_monitoring" = check; then
 585     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 586                               daemon were not found ($MONITORING_PKG),
 587                               monitoring disabled]))
 588   else
 589     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 590                                  required libraries were not found:
 591                                  $MONITORING_PKG]))
 592   fi
 593   has_monitoring_dep=False
 594   if test -z "$MONITORING_DEP"; then
 595     has_monitoring_dep=True
 596   elif test "$enable_monitoring" = check; then
 597     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
 598                               monitoring agent were not enabled
 599                               ($MONITORING_DEP), monitoring disabled]))
 600   else
 601     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 602                                  required optional Ganeti components were not
 603                                  found: $MONITORING_DEP]))
 604   fi
 605
 606 fi
 607 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
 608   has_monitoring=True
 609   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 610 fi
 611 AC_SUBST(ENABLE_MOND, $has_monitoring)
 612 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
 613
 614 # development modules
 615 HS_NODEV=
 616 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 617 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 618 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 619 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 620 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 621 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 622 #        that are needed to execute the tests, avoiding the duplication
 623 #        of the checks.
 624 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 625 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 626 if test -n "$HS_NODEV"; then
 627    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 628                              you won't be able to run Haskell unittests]))
 629 else
 630    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 631 fi
 632 AC_SUBST(HS_NODEV)
 633
 634 HTOOLS=yes
 635 AC_SUBST(HTOOLS)
 636
 637 # --enable-split-query
 638 ENABLE_SPLIT_QUERY=
 639 AC_ARG_ENABLE([split-query],
 640   [AS_HELP_STRING([--enable-split-query],
 641   [enable use of custom query daemon via confd])],
 642   [[case "$enableval" in
 643       no)
 644         enable_split_query=False
 645         ;;
 646       yes)
 647         enable_split_query=True
 648         ;;
 649       *)
 650         echo "Invalid value for enable-confd '$enableval'"
 651         exit 1
 652         ;;
 653     esac
 654   ]],
 655   [[case "x${has_confd}x" in
 656      xTruex)
 657        enable_split_query=True
 658        ;;
 659      *)
 660        enable_split_query=False
 661        ;;
 662    esac]])
 663 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 664
 665 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 666   AC_MSG_ERROR([Split queries require the confd daemon])
 667 fi
 668
 669 if test x$enable_split_query = xTrue; then
 670   AC_MSG_NOTICE([Split query functionality enabled])
 671 fi
 672
 673 # Check for HsColour
 674 HS_APIDOC=no
 675 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 676 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 677 if test -z "$HSCOLOUR"; then
 678   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 679                             not be generated]))
 680 fi
 681
 682 # Check for haddock
 683 AC_ARG_VAR(HADDOCK, [haddock path])
 684 AC_PATH_PROG(HADDOCK, [haddock], [])
 685 if test -z "$HADDOCK"; then
 686   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 687                             not be generated]))
 688 fi
 689 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 690   HS_APIDOC=yes
 691 fi
 692 AC_SUBST(HS_APIDOC)
 693
 694 # Check for hlint
 695 AC_ARG_VAR(HLINT, [hlint path])
 696 AC_PATH_PROG(HLINT, [hlint], [])
 697 if test -z "$HLINT"; then
 698   AC_MSG_WARN([hlint not found, checking code will not be possible])
 699 fi
 700
 701 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 702   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 703                              htools support is not enabled]))
 704 fi
 705
 706 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 707 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 708 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 709 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 710
 711 # Check for fakeroot
 712 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 713 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 714 if test -z "$FAKEROOT_PATH"; then
 715   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 716                             will not be executed]))
 717 fi
 718 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 719
 720 SOCAT_USE_ESCAPE=
 721 AC_ARG_ENABLE([socat-escape],
 722   [AS_HELP_STRING([--enable-socat-escape],
 723     [use escape functionality available in socat >= 1.7 (default: detect
 724      automatically)])],
 725   [[if test "$enableval" = yes; then
 726       SOCAT_USE_ESCAPE=True
 727     else
 728       SOCAT_USE_ESCAPE=False
 729     fi
 730   ]])
 731
 732 if test -z "$SOCAT_USE_ESCAPE"
 733 then
 734   if $SOCAT -hh | grep -w -q escape; then
 735     SOCAT_USE_ESCAPE=True
 736   else
 737     SOCAT_USE_ESCAPE=False
 738   fi
 739 fi
 740
 741 AC_SUBST(SOCAT_USE_ESCAPE)
 742
 743 SOCAT_USE_COMPRESS=
 744 AC_ARG_ENABLE([socat-compress],
 745   [AS_HELP_STRING([--enable-socat-compress],
 746     [use OpenSSL compression option available in patched socat builds
 747      (see INSTALL for details; default: detect automatically)])],
 748   [[if test "$enableval" = yes; then
 749       SOCAT_USE_COMPRESS=True
 750     else
 751       SOCAT_USE_COMPRESS=False
 752     fi
 753   ]])
 754
 755 if test -z "$SOCAT_USE_COMPRESS"
 756 then
 757   if $SOCAT -hhh | grep -w -q openssl-compress; then
 758     SOCAT_USE_COMPRESS=True
 759   else
 760     SOCAT_USE_COMPRESS=False
 761   fi
 762 fi
 763
 764 AC_SUBST(SOCAT_USE_COMPRESS)
 765
 766 if man --help | grep -q -e --warnings
 767 then
 768   MAN_HAS_WARNINGS=1
 769 else
 770   MAN_HAS_WARNINGS=
 771   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 772                             will not be possible]))
 773 fi
 774
 775 AC_SUBST(MAN_HAS_WARNINGS)
 776
 777 # Check for Python
 778 AM_PATH_PYTHON(2.6)
 779
 780 AC_PYTHON_MODULE(OpenSSL, t)
 781 AC_PYTHON_MODULE(simplejson, t)
 782 AC_PYTHON_MODULE(pyparsing, t)
 783 AC_PYTHON_MODULE(pyinotify, t)
 784 AC_PYTHON_MODULE(pycurl, t)
 785 AC_PYTHON_MODULE(bitarray, t)
 786 AC_PYTHON_MODULE(ipaddr, t)
 787 AC_PYTHON_MODULE(affinity)
 788 AC_PYTHON_MODULE(paramiko)
 789
 790 # Development-only Python modules
 791 PY_NODEV=
 792 AC_PYTHON_MODULE(yaml)
 793 if test $HAVE_PYMOD_YAML == "no"; then
 794   PY_NODEV="$PY_NODEV yaml"
 795 fi
 796
 797 if test -n "$PY_NODEV"; then
 798   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
 799                             found, you won't be able to run Python unittests]))
 800 else
 801   AC_MSG_NOTICE([Python development modules found, unittests enabled])
 802 fi
 803 AC_SUBST(PY_NODEV)
 804 AM_CONDITIONAL([PY_UNIT], [test -n $PY_NODEV])
 805
 806 AC_CONFIG_FILES([ Makefile ])
 807
 808 AC_OUTPUT