code.grnet.gr Git - ganeti-local/blob - htools/Ganeti/THH.hs

   1 {-# LANGUAGE TemplateHaskell, QuasiQuotes #-}
   2
   3 {-| TemplateHaskell helper for HTools.
   4
   5 As TemplateHaskell require that splices be defined in a separate
   6 module, we combine all the TemplateHaskell functionality that HTools
   7 needs in this module (except the one for unittests).
   8
   9 -}
  10
  11 {-
  12
  13 Copyright (C) 2011 Google Inc.
  14
  15 This program is free software; you can redistribute it and/or modify
  16 it under the terms of the GNU General Public License as published by
  17 the Free Software Foundation; either version 2 of the License, or
  18 (at your option) any later version.
  19
  20 This program is distributed in the hope that it will be useful, but
  21 WITHOUT ANY WARRANTY; without even the implied warranty of
  22 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  23 General Public License for more details.
  24
  25 You should have received a copy of the GNU General Public License
  26 along with this program; if not, write to the Free Software
  27 Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  28 02110-1301, USA.
  29
  30 -}
  31
  32 module Ganeti.THH ( declareSADT
  33                   , declareIADT
  34                   , makeJSONInstance
  35                   , genOpID
  36                   , genOpCode
  37                   , noDefault
  38                   , genStrOfOp
  39                   , genStrOfKey
  40                   , genLuxiOp
  41                   , Field
  42                   , simpleField
  43                   , defaultField
  44                   , optionalField
  45                   , renameField
  46                   , containerField
  47                   , customField
  48                   , timeStampFields
  49                   , uuidFields
  50                   , serialFields
  51                   , buildObject
  52                   , buildObjectSerialisation
  53                   , buildParam
  54                   , Container
  55                   ) where
  56
  57 import Control.Arrow
  58 import Control.Monad (liftM, liftM2)
  59 import Data.Char
  60 import Data.List
  61 import qualified Data.Map as M
  62 import Language.Haskell.TH
  63
  64 import qualified Text.JSON as JSON
  65
  66 -- * Exported types
  67
  68 type Container = M.Map String
  69
  70 -- | Serialised field data type.
  71 data Field = Field { fieldName        :: String
  72                    , fieldType        :: Q Type
  73                    , fieldRead        :: Maybe (Q Exp)
  74                    , fieldShow        :: Maybe (Q Exp)
  75                    , fieldDefault     :: Maybe (Q Exp)
  76                    , fieldConstr      :: Maybe String
  77                    , fieldIsContainer :: Bool
  78                    , fieldIsOptional  :: Bool
  79                    }
  80
  81 -- | Generates a simple field.
  82 simpleField :: String -> Q Type -> Field
  83 simpleField fname ftype =
  84   Field { fieldName        = fname
  85         , fieldType        = ftype
  86         , fieldRead        = Nothing
  87         , fieldShow        = Nothing
  88         , fieldDefault     = Nothing
  89         , fieldConstr      = Nothing
  90         , fieldIsContainer = False
  91         , fieldIsOptional  = False
  92         }
  93
  94 -- | Sets the renamed constructor field.
  95 renameField :: String -> Field -> Field
  96 renameField constrName field = field { fieldConstr = Just constrName }
  97
  98 -- | Sets the default value on a field (makes it optional with a
  99 -- default value).
 100 defaultField :: Q Exp -> Field -> Field
 101 defaultField defval field = field { fieldDefault = Just defval }
 102
 103 -- | Marks a field optional (turning its base type into a Maybe).
 104 optionalField :: Field -> Field
 105 optionalField field = field { fieldIsOptional = True }
 106
 107 -- | Marks a field as a container.
 108 containerField :: Field -> Field
 109 containerField field = field { fieldIsContainer = True }
 110
 111 -- | Sets custom functions on a field.
 112 customField :: Q Exp -> Q Exp -> Field -> Field
 113 customField readfn showfn field =
 114   field { fieldRead = Just readfn, fieldShow = Just showfn }
 115
 116 fieldRecordName :: Field -> String
 117 fieldRecordName (Field { fieldName = name, fieldConstr = alias }) =
 118   maybe (camelCase name) id alias
 119
 120 fieldVariable :: Field -> String
 121 fieldVariable = map toLower . fieldRecordName
 122
 123 actualFieldType :: Field -> Q Type
 124 actualFieldType f | fieldIsContainer f = [t| Container $t |]
 125                   | fieldIsOptional f  = [t| Maybe $t     |]
 126                   | otherwise = t
 127                   where t = fieldType f
 128
 129 checkNonOptDef :: (Monad m) => Field -> m ()
 130 checkNonOptDef (Field { fieldIsOptional = True, fieldName = name }) =
 131   fail $ "Optional field " ++ name ++ " used in parameter declaration"
 132 checkNonOptDef (Field { fieldDefault = (Just _), fieldName = name }) =
 133   fail $ "Default field " ++ name ++ " used in parameter declaration"
 134 checkNonOptDef _ = return ()
 135
 136 loadFn :: Field -> Q Exp -> Q Exp
 137 loadFn (Field { fieldIsContainer = True }) expr = [| $expr >>= readContainer |]
 138 loadFn (Field { fieldRead = Just readfn }) expr = [| $expr >>= $readfn |]
 139 loadFn _ expr = expr
 140
 141 saveFn :: Field -> Q Exp -> Q Exp
 142 saveFn (Field { fieldIsContainer = True }) expr = [| showContainer $expr |]
 143 saveFn (Field { fieldRead = Just readfn }) expr = [| $readfn $expr |]
 144 saveFn _ expr = expr
 145
 146 -- * Common field declarations
 147
 148 timeStampFields :: [Field]
 149 timeStampFields =
 150     [ defaultField [| 0::Double |] $ simpleField "ctime" [t| Double |]
 151     , defaultField [| 0::Double |] $ simpleField "mtime" [t| Double |]
 152     ]
 153
 154 serialFields :: [Field]
 155 serialFields =
 156     [ renameField  "Serial" $ simpleField "serial_no" [t| Int |] ]
 157
 158 uuidFields :: [Field]
 159 uuidFields = [ simpleField "uuid" [t| String |] ]
 160
 161 -- * Helper functions
 162
 163 -- | Ensure first letter is lowercase.
 164 --
 165 -- Used to convert type name to function prefix, e.g. in @data Aa ->
 166 -- aaToRaw@.
 167 ensureLower :: String -> String
 168 ensureLower [] = []
 169 ensureLower (x:xs) = toLower x:xs
 170
 171 -- | Ensure first letter is uppercase.
 172 --
 173 -- Used to convert constructor name to component
 174 ensureUpper :: String -> String
 175 ensureUpper [] = []
 176 ensureUpper (x:xs) = toUpper x:xs
 177
 178 -- | Helper for quoted expressions.
 179 varNameE :: String -> Q Exp
 180 varNameE = varE . mkName
 181
 182 -- | showJSON as an expression, for reuse.
 183 showJSONE :: Q Exp
 184 showJSONE = varNameE "showJSON"
 185
 186 -- | ToRaw function name.
 187 toRawName :: String -> Name
 188 toRawName = mkName . (++ "ToRaw") . ensureLower
 189
 190 -- | FromRaw function name.
 191 fromRawName :: String -> Name
 192 fromRawName = mkName . (++ "FromRaw") . ensureLower
 193
 194 -- | Converts a name to it's varE/litE representations.
 195 --
 196 reprE :: Either String Name -> Q Exp
 197 reprE = either stringE varE
 198
 199 -- | Smarter function application.
 200 --
 201 -- This does simply f x, except that if is 'id', it will skip it, in
 202 -- order to generate more readable code when using -ddump-splices.
 203 appFn :: Exp -> Exp -> Exp
 204 appFn f x | f == VarE 'id = x
 205           | otherwise = AppE f x
 206
 207 -- | Container loader
 208 readContainer :: (Monad m) => JSON.JSObject a -> m (Container a)
 209 readContainer = return . M.fromList . JSON.fromJSObject
 210
 211 -- | Container dumper
 212 showContainer :: (JSON.JSON a) => Container a -> JSON.JSValue
 213 showContainer = JSON.makeObj . map (second JSON.showJSON) . M.toList
 214
 215 -- * Template code for simple raw type-equivalent ADTs
 216
 217 -- | Generates a data type declaration.
 218 --
 219 -- The type will have a fixed list of instances.
 220 strADTDecl :: Name -> [String] -> Dec
 221 strADTDecl name constructors =
 222   DataD [] name []
 223           (map (flip NormalC [] . mkName) constructors)
 224           [''Show, ''Read, ''Eq, ''Enum, ''Bounded, ''Ord]
 225
 226 -- | Generates a toRaw function.
 227 --
 228 -- This generates a simple function of the form:
 229 --
 230 -- @
 231 -- nameToRaw :: Name -> /traw/
 232 -- nameToRaw Cons1 = var1
 233 -- nameToRaw Cons2 = \"value2\"
 234 -- @
 235 genToRaw :: Name -> Name -> Name -> [(String, Either String Name)] -> Q [Dec]
 236 genToRaw traw fname tname constructors = do
 237   sigt <- [t| $(conT tname) -> $(conT traw) |]
 238   -- the body clauses, matching on the constructor and returning the
 239   -- raw value
 240   clauses <- mapM  (\(c, v) -> clause [recP (mkName c) []]
 241                              (normalB (reprE v)) []) constructors
 242   return [SigD fname sigt, FunD fname clauses]
 243
 244 -- | Generates a fromRaw function.
 245 --
 246 -- The function generated is monadic and can fail parsing the
 247 -- raw value. It is of the form:
 248 --
 249 -- @
 250 -- nameFromRaw :: (Monad m) => /traw/ -> m Name
 251 -- nameFromRaw s | s == var1       = Cons1
 252 --               | s == \"value2\" = Cons2
 253 --               | otherwise = fail /.../
 254 -- @
 255 genFromRaw :: Name -> Name -> Name -> [(String, Name)] -> Q [Dec]
 256 genFromRaw traw fname tname constructors = do
 257   -- signature of form (Monad m) => String -> m $name
 258   sigt <- [t| (Monad m) => $(conT traw) -> m $(conT tname) |]
 259   -- clauses for a guarded pattern
 260   let varp = mkName "s"
 261       varpe = varE varp
 262   clauses <- mapM (\(c, v) -> do
 263                      -- the clause match condition
 264                      g <- normalG [| $varpe == $(varE v) |]
 265                      -- the clause result
 266                      r <- [| return $(conE (mkName c)) |]
 267                      return (g, r)) constructors
 268   -- the otherwise clause (fallback)
 269   oth_clause <- do
 270     g <- normalG [| otherwise |]
 271     r <- [|fail ("Invalid string value for type " ++
 272                  $(litE (stringL (nameBase tname))) ++ ": " ++ show $varpe) |]
 273     return (g, r)
 274   let fun = FunD fname [Clause [VarP varp]
 275                         (GuardedB (clauses++[oth_clause])) []]
 276   return [SigD fname sigt, fun]
 277
 278 -- | Generates a data type from a given raw format.
 279 --
 280 -- The format is expected to multiline. The first line contains the
 281 -- type name, and the rest of the lines must contain two words: the
 282 -- constructor name and then the string representation of the
 283 -- respective constructor.
 284 --
 285 -- The function will generate the data type declaration, and then two
 286 -- functions:
 287 --
 288 -- * /name/ToRaw, which converts the type to a raw type
 289 --
 290 -- * /name/FromRaw, which (monadically) converts from a raw type to the type
 291 --
 292 -- Note that this is basically just a custom show/read instance,
 293 -- nothing else.
 294 declareADT :: Name -> String -> [(String, Name)] -> Q [Dec]
 295 declareADT traw sname cons = do
 296   let name = mkName sname
 297       ddecl = strADTDecl name (map fst cons)
 298       -- process cons in the format expected by genToRaw
 299       cons' = map (\(a, b) -> (a, Right b)) cons
 300   toraw <- genToRaw traw (toRawName sname) name cons'
 301   fromraw <- genFromRaw traw (fromRawName sname) name cons
 302   return $ ddecl:toraw ++ fromraw
 303
 304 declareIADT :: String -> [(String, Name)] -> Q [Dec]
 305 declareIADT = declareADT ''Int
 306
 307 declareSADT :: String -> [(String, Name)] -> Q [Dec]
 308 declareSADT = declareADT ''String
 309
 310 -- | Creates the showJSON member of a JSON instance declaration.
 311 --
 312 -- This will create what is the equivalent of:
 313 --
 314 -- @
 315 -- showJSON = showJSON . /name/ToRaw
 316 -- @
 317 --
 318 -- in an instance JSON /name/ declaration
 319 genShowJSON :: String -> Q [Dec]
 320 genShowJSON name = [d| showJSON = JSON.showJSON . $(varE (toRawName name)) |]
 321
 322 -- | Creates the readJSON member of a JSON instance declaration.
 323 --
 324 -- This will create what is the equivalent of:
 325 --
 326 -- @
 327 -- readJSON s = case readJSON s of
 328 --                Ok s' -> /name/FromRaw s'
 329 --                Error e -> Error /description/
 330 -- @
 331 --
 332 -- in an instance JSON /name/ declaration
 333 genReadJSON :: String -> Q Dec
 334 genReadJSON name = do
 335   let s = mkName "s"
 336   body <- [| case JSON.readJSON $(varE s) of
 337                JSON.Ok s' -> $(varE (fromRawName name)) s'
 338                JSON.Error e ->
 339                    JSON.Error $ "Can't parse raw value for type " ++
 340                            $(stringE name) ++ ": " ++ e
 341            |]
 342   return $ FunD (mkName "readJSON") [Clause [VarP s] (NormalB body) []]
 343
 344 -- | Generates a JSON instance for a given type.
 345 --
 346 -- This assumes that the /name/ToRaw and /name/FromRaw functions
 347 -- have been defined as by the 'declareSADT' function.
 348 makeJSONInstance :: Name -> Q [Dec]
 349 makeJSONInstance name = do
 350   let base = nameBase name
 351   showJ <- genShowJSON base
 352   readJ <- genReadJSON base
 353   return [InstanceD [] (AppT (ConT ''JSON.JSON) (ConT name)) (readJ:showJ)]
 354
 355 -- * Template code for opcodes
 356
 357 -- | Transforms a CamelCase string into an_underscore_based_one.
 358 deCamelCase :: String -> String
 359 deCamelCase =
 360     intercalate "_" . map (map toUpper) . groupBy (\_ b -> not $ isUpper b)
 361
 362 -- | Transform an underscore_name into a CamelCase one.
 363 camelCase :: String -> String
 364 camelCase = concatMap (ensureUpper . drop 1) .
 365             groupBy (\_ b -> b /= '_') . ('_':)
 366
 367 -- | Computes the name of a given constructor.
 368 constructorName :: Con -> Q Name
 369 constructorName (NormalC name _) = return name
 370 constructorName (RecC name _)    = return name
 371 constructorName x                = fail $ "Unhandled constructor " ++ show x
 372
 373 -- | Builds the generic constructor-to-string function.
 374 --
 375 -- This generates a simple function of the following form:
 376 --
 377 -- @
 378 -- fname (ConStructorOne {}) = trans_fun("ConStructorOne")
 379 -- fname (ConStructorTwo {}) = trans_fun("ConStructorTwo")
 380 -- @
 381 --
 382 -- This builds a custom list of name/string pairs and then uses
 383 -- 'genToRaw' to actually generate the function
 384 genConstrToStr :: (String -> String) -> Name -> String -> Q [Dec]
 385 genConstrToStr trans_fun name fname = do
 386   TyConI (DataD _ _ _ cons _) <- reify name
 387   cnames <- mapM (liftM nameBase . constructorName) cons
 388   let svalues = map (Left . trans_fun) cnames
 389   genToRaw ''String (mkName fname) name $ zip cnames svalues
 390
 391 -- | Constructor-to-string for OpCode.
 392 genOpID :: Name -> String -> Q [Dec]
 393 genOpID = genConstrToStr deCamelCase
 394
 395 -- | OpCode parameter (field) type.
 396 type OpParam = (String, Q Type, Q Exp)
 397
 398 -- | Generates the OpCode data type.
 399 --
 400 -- This takes an opcode logical definition, and builds both the
 401 -- datatype and the JSON serialisation out of it. We can't use a
 402 -- generic serialisation since we need to be compatible with Ganeti's
 403 -- own, so we have a few quirks to work around.
 404 --
 405 -- There are three things to be defined for each parameter:
 406 --
 407 -- * name
 408 --
 409 -- * type; if this is 'Maybe', will only be serialised if it's a
 410 --   'Just' value
 411 --
 412 -- * default; if missing, won't raise an exception, but will instead
 413 --   use the default
 414 --
 415 genOpCode :: String                -- ^ Type name to use
 416           -> [(String, [OpParam])] -- ^ Constructor name and parameters
 417           -> Q [Dec]
 418 genOpCode name cons = do
 419   decl_d <- mapM (\(cname, fields) -> do
 420                     -- we only need the type of the field, without Q
 421                     fields' <- mapM (\(_, qt, _) ->
 422                                          qt >>= \t -> return (NotStrict, t))
 423                                fields
 424                     return $ NormalC (mkName cname) fields')
 425             cons
 426   let declD = DataD [] (mkName name) [] decl_d [''Show, ''Read, ''Eq]
 427
 428   (savesig, savefn) <- genSaveOpCode cons
 429   (loadsig, loadfn) <- genLoadOpCode cons
 430   return [declD, loadsig, loadfn, savesig, savefn]
 431
 432 -- | Checks whether a given parameter is options.
 433 --
 434 -- This requires that it's a 'Maybe'.
 435 isOptional :: Type -> Bool
 436 isOptional (AppT (ConT dt) _) | dt == ''Maybe = True
 437 isOptional _ = False
 438
 439 -- | Generates the \"save\" expression for a single opcode parameter.
 440 --
 441 -- There is only one special handling mode: if the parameter is of
 442 -- 'Maybe' type, then we only save it if it's a 'Just' value,
 443 -- otherwise we skip it.
 444 saveField :: Name    -- ^ The name of variable that contains the value
 445           -> OpParam -- ^ Parameter definition
 446           -> Q Exp
 447 saveField fvar (fname, qt, _) = do
 448   t <- qt
 449   let fnexp = stringE fname
 450       fvare = varE fvar
 451   (if isOptional t
 452    then [| case $fvare of
 453              Just v' -> [( $fnexp, $showJSONE v')]
 454              Nothing -> []
 455          |]
 456    else [| [( $fnexp, $showJSONE $fvare )] |])
 457
 458 -- | Generates the \"save\" clause for an entire opcode constructor.
 459 --
 460 -- This matches the opcode with variables named the same as the
 461 -- constructor fields (just so that the spliced in code looks nicer),
 462 -- and passes those name plus the parameter definition to 'saveField'.
 463 saveConstructor :: String    -- ^ The constructor name
 464                 -> [OpParam] -- ^ The parameter definitions for this
 465                              -- constructor
 466                 -> Q Clause  -- ^ Resulting clause
 467 saveConstructor sname fields = do
 468   let cname = mkName sname
 469   let fnames = map (\(n, _, _) -> mkName n) fields
 470   let pat = conP cname (map varP fnames)
 471   let felems = map (uncurry saveField) (zip fnames fields)
 472       -- now build the OP_ID serialisation
 473       opid = [| [( $(stringE "OP_ID"),
 474                    $showJSONE $(stringE . deCamelCase $ sname) )] |]
 475       flist = listE (opid:felems)
 476       -- and finally convert all this to a json object
 477       flist' = [| $(varNameE "makeObj") (concat $flist) |]
 478   clause [pat] (normalB flist') []
 479
 480 -- | Generates the main save opcode function.
 481 --
 482 -- This builds a per-constructor match clause that contains the
 483 -- respective constructor-serialisation code.
 484 genSaveOpCode :: [(String, [OpParam])] -> Q (Dec, Dec)
 485 genSaveOpCode opdefs = do
 486   cclauses <- mapM (uncurry saveConstructor) opdefs
 487   let fname = mkName "saveOpCode"
 488   sigt <- [t| $(conT (mkName "OpCode")) -> JSON.JSValue |]
 489   return $ (SigD fname sigt, FunD fname cclauses)
 490
 491 -- | Generates the \"load\" field for a single parameter.
 492 --
 493 -- There is custom handling, depending on how the parameter is
 494 -- specified. For a 'Maybe' type parameter, we allow that it is not
 495 -- present (via 'Utils.maybeFromObj'). Otherwise, if there is a
 496 -- default value, we allow the parameter to be abset, and finally if
 497 -- there is no default value, we require its presence.
 498 loadField :: OpParam -> Q (Name, Stmt)
 499 loadField (fname, qt, qdefa) = do
 500   let fvar = mkName fname
 501   t <- qt
 502   defa <- qdefa
 503   -- these are used in all patterns below
 504   let objvar = varNameE "o"
 505       objfield = stringE fname
 506   bexp <- if isOptional t
 507           then [| $((varNameE "maybeFromObj")) $objvar $objfield |]
 508           else case defa of
 509                  AppE (ConE dt) defval | dt == 'Just ->
 510                    -- but has a default value
 511                    [| $(varNameE "fromObjWithDefault")
 512                       $objvar $objfield $(return defval) |]
 513                  ConE dt | dt == 'Nothing ->
 514                      [| $(varNameE "fromObj") $objvar $objfield |]
 515                  s -> fail $ "Invalid default value " ++ show s ++
 516                       ", expecting either 'Nothing' or a 'Just defval'"
 517   return (fvar, BindS (VarP fvar) bexp)
 518
 519 loadConstructor :: String -> [OpParam] -> Q Exp
 520 loadConstructor sname fields = do
 521   let name = mkName sname
 522   fbinds <- mapM loadField fields
 523   let (fnames, fstmts) = unzip fbinds
 524   let cval = foldl (\accu fn -> AppE accu (VarE fn)) (ConE name) fnames
 525       fstmts' = fstmts ++ [NoBindS (AppE (VarE 'return) cval)]
 526   return $ DoE fstmts'
 527
 528 genLoadOpCode :: [(String, [OpParam])] -> Q (Dec, Dec)
 529 genLoadOpCode opdefs = do
 530   let fname = mkName "loadOpCode"
 531       arg1 = mkName "v"
 532       objname = mkName "o"
 533       opid = mkName "op_id"
 534   st1 <- bindS (varP objname) [| liftM JSON.fromJSObject
 535                                  (JSON.readJSON $(varE arg1)) |]
 536   st2 <- bindS (varP opid) [| $(varNameE "fromObj")
 537                               $(varE objname) $(stringE "OP_ID") |]
 538   -- the match results (per-constructor blocks)
 539   mexps <- mapM (uncurry loadConstructor) opdefs
 540   fails <- [| fail $ "Unknown opcode " ++ $(varE opid) |]
 541   let mpats = map (\(me, c) ->
 542                        let mp = LitP . StringL . deCamelCase . fst $ c
 543                        in Match mp (NormalB me) []
 544                   ) $ zip mexps opdefs
 545       defmatch = Match WildP (NormalB fails) []
 546       cst = NoBindS $ CaseE (VarE opid) $ mpats++[defmatch]
 547       body = DoE [st1, st2, cst]
 548   sigt <- [t| JSON.JSValue -> JSON.Result $(conT (mkName "OpCode")) |]
 549   return $ (SigD fname sigt, FunD fname [Clause [VarP arg1] (NormalB body) []])
 550
 551 -- | No default type.
 552 noDefault :: Q Exp
 553 noDefault = conE 'Nothing
 554
 555 -- * Template code for luxi
 556
 557 -- | Constructor-to-string for LuxiOp.
 558 genStrOfOp :: Name -> String -> Q [Dec]
 559 genStrOfOp = genConstrToStr id
 560
 561 -- | Constructor-to-string for MsgKeys.
 562 genStrOfKey :: Name -> String -> Q [Dec]
 563 genStrOfKey = genConstrToStr ensureLower
 564
 565 -- | LuxiOp parameter type.
 566 type LuxiParam = (String, Q Type, Q Exp)
 567
 568 -- | Generates the LuxiOp data type.
 569 --
 570 -- This takes a Luxi operation definition and builds both the
 571 -- datatype and the function trnasforming the arguments to JSON.
 572 -- We can't use anything less generic, because the way different
 573 -- operations are serialized differs on both parameter- and top-level.
 574 --
 575 -- There are three things to be defined for each parameter:
 576 --
 577 -- * name
 578 --
 579 -- * type
 580 --
 581 -- * operation; this is the operation performed on the parameter before
 582 --   serialization
 583 --
 584 genLuxiOp :: String -> [(String, [LuxiParam])] -> Q [Dec]
 585 genLuxiOp name cons = do
 586   decl_d <- mapM (\(cname, fields) -> do
 587                     fields' <- mapM (\(_, qt, _) ->
 588                                          qt >>= \t -> return (NotStrict, t))
 589                                fields
 590                     return $ NormalC (mkName cname) fields')
 591             cons
 592   let declD = DataD [] (mkName name) [] decl_d [''Show, ''Read]
 593   (savesig, savefn) <- genSaveLuxiOp cons
 594   return [declD, savesig, savefn]
 595
 596 -- | Generates the \"save\" expression for a single luxi parameter.
 597 saveLuxiField :: Name -> LuxiParam -> Q Exp
 598 saveLuxiField fvar (_, qt, fn) =
 599     [| JSON.showJSON ( $(liftM2 appFn fn $ varE fvar) ) |]
 600
 601 -- | Generates the \"save\" clause for entire LuxiOp constructor.
 602 saveLuxiConstructor :: (String, [LuxiParam]) -> Q Clause
 603 saveLuxiConstructor (sname, fields) = do
 604   let cname = mkName sname
 605       fnames = map (\(nm, _, _) -> mkName nm) fields
 606       pat = conP cname (map varP fnames)
 607       flist = map (uncurry saveLuxiField) (zip fnames fields)
 608       finval = if null flist
 609                then [| JSON.showJSON ()    |]
 610                else [| JSON.showJSON $(listE flist) |]
 611   clause [pat] (normalB finval) []
 612
 613 -- | Generates the main save LuxiOp function.
 614 genSaveLuxiOp :: [(String, [LuxiParam])]-> Q (Dec, Dec)
 615 genSaveLuxiOp opdefs = do
 616   sigt <- [t| $(conT (mkName "LuxiOp")) -> JSON.JSValue |]
 617   let fname = mkName "opToArgs"
 618   cclauses <- mapM saveLuxiConstructor opdefs
 619   return $ (SigD fname sigt, FunD fname cclauses)
 620
 621 -- * "Objects" functionality
 622
 623 -- | Extract the field's declaration from a Field structure.
 624 fieldTypeInfo :: String -> Field -> Q (Name, Strict, Type)
 625 fieldTypeInfo field_pfx fd = do
 626   t <- actualFieldType fd
 627   let n = mkName . (field_pfx ++) . fieldRecordName $ fd
 628   return (n, NotStrict, t)
 629
 630 -- | Build an object declaration.
 631 buildObject :: String -> String -> [Field] -> Q [Dec]
 632 buildObject sname field_pfx fields = do
 633   let name = mkName sname
 634   fields_d <- mapM (fieldTypeInfo field_pfx) fields
 635   let decl_d = RecC name fields_d
 636   let declD = DataD [] name [] [decl_d] [''Show, ''Read]
 637   ser_decls <- buildObjectSerialisation sname fields
 638   return $ declD:ser_decls
 639
 640 buildObjectSerialisation :: String -> [Field] -> Q [Dec]
 641 buildObjectSerialisation sname fields = do
 642   let name = mkName sname
 643   savedecls <- genSaveObject saveObjectField sname fields
 644   (loadsig, loadfn) <- genLoadObject loadObjectField sname fields
 645   shjson <- objectShowJSON sname
 646   rdjson <- objectReadJSON sname
 647   let instdecl = InstanceD [] (AppT (ConT ''JSON.JSON) (ConT name))
 648                  (rdjson:shjson)
 649   return $ savedecls ++ [loadsig, loadfn, instdecl]
 650
 651 genSaveObject :: (Name -> Field -> Q Exp)
 652               -> String -> [Field] -> Q [Dec]
 653 genSaveObject save_fn sname fields = do
 654   let name = mkName sname
 655   let fnames = map (mkName . fieldVariable) fields
 656   let pat = conP name (map varP fnames)
 657   let tdname = mkName ("toDict" ++ sname)
 658   tdsigt <- [t| $(conT name) -> [(String, JSON.JSValue)] |]
 659
 660   let felems = map (uncurry save_fn) (zip fnames fields)
 661       flist = listE felems
 662       -- and finally convert all this to a json object
 663       tdlist = [| concat $flist |]
 664       iname = mkName "i"
 665   tclause <- clause [pat] (normalB tdlist) []
 666   cclause <- [| $(varNameE "makeObj") . $(varE tdname) |]
 667   let fname = mkName ("save" ++ sname)
 668   sigt <- [t| $(conT name) -> JSON.JSValue |]
 669   return [SigD tdname tdsigt, FunD tdname [tclause],
 670           SigD fname sigt, ValD (VarP fname) (NormalB cclause) []]
 671
 672 saveObjectField :: Name -> Field -> Q Exp
 673 saveObjectField fvar field
 674   | isContainer = [| [( $nameE , $showJSONE . showContainer $ $fvarE)] |]
 675   | fisOptional = [| case $(varE fvar) of
 676                       Nothing -> []
 677                       Just v -> [( $nameE, $showJSONE v)]
 678                   |]
 679   | otherwise = case fieldShow field of
 680       Nothing -> [| [( $nameE, $showJSONE $fvarE)] |]
 681       Just fn -> [| [( $nameE, $showJSONE . $fn $ $fvarE)] |]
 682   where isContainer = fieldIsContainer field
 683         fisOptional  = fieldIsOptional field
 684         nameE = stringE (fieldName field)
 685         fvarE = varE fvar
 686
 687 objectShowJSON :: String -> Q [Dec]
 688 objectShowJSON name =
 689   [d| showJSON = JSON.showJSON . $(varE . mkName $ "save" ++ name) |]
 690
 691 genLoadObject :: (Field -> Q (Name, Stmt))
 692               -> String -> [Field] -> Q (Dec, Dec)
 693 genLoadObject load_fn sname fields = do
 694   let name = mkName sname
 695       funname = mkName $ "load" ++ sname
 696       arg1 = mkName "v"
 697       objname = mkName "o"
 698       opid = mkName "op_id"
 699   st1 <- bindS (varP objname) [| liftM JSON.fromJSObject
 700                                  (JSON.readJSON $(varE arg1)) |]
 701   fbinds <- mapM load_fn fields
 702   let (fnames, fstmts) = unzip fbinds
 703   let cval = foldl (\accu fn -> AppE accu (VarE fn)) (ConE name) fnames
 704       fstmts' = st1:fstmts ++ [NoBindS (AppE (VarE 'return) cval)]
 705   sigt <- [t| JSON.JSValue -> JSON.Result $(conT name) |]
 706   return $ (SigD funname sigt,
 707             FunD funname [Clause [VarP arg1] (NormalB (DoE fstmts')) []])
 708
 709 loadObjectField :: Field -> Q (Name, Stmt)
 710 loadObjectField field = do
 711   let name = fieldVariable field
 712       fvar = mkName name
 713   -- these are used in all patterns below
 714   let objvar = varNameE "o"
 715       objfield = stringE (fieldName field)
 716       loadexp =
 717         if fieldIsOptional field
 718           then [| $(varNameE "maybeFromObj") $objvar $objfield |]
 719           else case fieldDefault field of
 720                  Just defv ->
 721                    [| $(varNameE "fromObjWithDefault") $objvar
 722                       $objfield $defv |]
 723                  Nothing -> [| $(varNameE "fromObj") $objvar $objfield |]
 724   bexp <- loadFn field loadexp
 725
 726   return (fvar, BindS (VarP fvar) bexp)
 727
 728 objectReadJSON :: String -> Q Dec
 729 objectReadJSON name = do
 730   let s = mkName "s"
 731   body <- [| case JSON.readJSON $(varE s) of
 732                JSON.Ok s' -> $(varE .mkName $ "load" ++ name) s'
 733                JSON.Error e ->
 734                  JSON.Error $ "Can't parse value for type " ++
 735                        $(stringE name) ++ ": " ++ e
 736            |]
 737   return $ FunD (mkName "readJSON") [Clause [VarP s] (NormalB body) []]
 738
 739 -- * Inheritable parameter tables implementation
 740
 741 -- | Compute parameter type names.
 742 paramTypeNames :: String -> (String, String)
 743 paramTypeNames root = ("Filled"  ++ root ++ "Params",
 744                        "Partial" ++ root ++ "Params")
 745
 746 -- | Compute information about the type of a parameter field.
 747 paramFieldTypeInfo :: String -> Field -> Q (Name, Strict, Type)
 748 paramFieldTypeInfo field_pfx fd = do
 749   t <- actualFieldType fd
 750   let n = mkName . (++ "P") . (field_pfx ++) .
 751           fieldRecordName $ fd
 752   return (n, NotStrict, AppT (ConT ''Maybe) t)
 753
 754 -- | Build a parameter declaration.
 755 --
 756 -- This function builds two different data structures: a /filled/ one,
 757 -- in which all fields are required, and a /partial/ one, in which all
 758 -- fields are optional. Due to the current record syntax issues, the
 759 -- fields need to be named differrently for the two structures, so the
 760 -- partial ones get a /P/ suffix.
 761 buildParam :: String -> String -> [Field] -> Q [Dec]
 762 buildParam sname field_pfx fields = do
 763   let (sname_f, sname_p) = paramTypeNames sname
 764       name_f = mkName sname_f
 765       name_p = mkName sname_p
 766   fields_f <- mapM (fieldTypeInfo field_pfx) fields
 767   fields_p <- mapM (paramFieldTypeInfo field_pfx) fields
 768   let decl_f = RecC name_f fields_f
 769       decl_p = RecC name_p fields_p
 770   let declF = DataD [] name_f [] [decl_f] [''Show, ''Read]
 771       declP = DataD [] name_p [] [decl_p] [''Show, ''Read]
 772   ser_decls_f <- buildObjectSerialisation sname_f fields
 773   ser_decls_p <- buildPParamSerialisation sname_p fields
 774   fill_decls <- fillParam sname field_pfx fields
 775   return $ [declF, declP] ++ ser_decls_f ++ ser_decls_p ++ fill_decls
 776
 777 buildPParamSerialisation :: String -> [Field] -> Q [Dec]
 778 buildPParamSerialisation sname fields = do
 779   let name = mkName sname
 780   savedecls <- genSaveObject savePParamField sname fields
 781   (loadsig, loadfn) <- genLoadObject loadPParamField sname fields
 782   shjson <- objectShowJSON sname
 783   rdjson <- objectReadJSON sname
 784   let instdecl = InstanceD [] (AppT (ConT ''JSON.JSON) (ConT name))
 785                  (rdjson:shjson)
 786   return $ savedecls ++ [loadsig, loadfn, instdecl]
 787
 788 savePParamField :: Name -> Field -> Q Exp
 789 savePParamField fvar field = do
 790   checkNonOptDef field
 791   let actualVal = mkName "v"
 792   normalexpr <- saveObjectField actualVal field
 793   -- we have to construct the block here manually, because we can't
 794   -- splice-in-splice
 795   return $ CaseE (VarE fvar) [ Match (ConP 'Nothing [])
 796                                        (NormalB (ConE '[])) []
 797                              , Match (ConP 'Just [VarP actualVal])
 798                                        (NormalB normalexpr) []
 799                              ]
 800 loadPParamField :: Field -> Q (Name, Stmt)
 801 loadPParamField field = do
 802   checkNonOptDef field
 803   let name = fieldName field
 804       fvar = mkName name
 805   -- these are used in all patterns below
 806   let objvar = varNameE "o"
 807       objfield = stringE name
 808       loadexp = [| $(varNameE "maybeFromObj") $objvar $objfield |]
 809   bexp <- loadFn field loadexp
 810   return (fvar, BindS (VarP fvar) bexp)
 811
 812 -- | Builds a simple declaration of type @n_x = fromMaybe f_x p_x@.
 813 buildFromMaybe :: String -> Q Dec
 814 buildFromMaybe fname =
 815   valD (varP (mkName $ "n_" ++ fname))
 816          (normalB [| $(varNameE "fromMaybe")
 817                         $(varNameE $ "f_" ++ fname)
 818                         $(varNameE $ "p_" ++ fname) |]) []
 819
 820 fillParam :: String -> String -> [Field] -> Q [Dec]
 821 fillParam sname field_pfx fields = do
 822   let fnames = map (\fd -> field_pfx ++ fieldRecordName fd) fields
 823       (sname_f, sname_p) = paramTypeNames sname
 824       oname_f = "fobj"
 825       oname_p = "pobj"
 826       name_f = mkName sname_f
 827       name_p = mkName sname_p
 828       fun_name = mkName $ "fill" ++ sname ++ "Params"
 829       le_full = ValD (ConP name_f (map (VarP . mkName . ("f_" ++)) fnames))
 830                 (NormalB . VarE . mkName $ oname_f) []
 831       le_part = ValD (ConP name_p (map (VarP . mkName . ("p_" ++)) fnames))
 832                 (NormalB . VarE . mkName $ oname_p) []
 833       obj_new = foldl (\accu vname -> AppE accu (VarE vname)) (ConE name_f)
 834                 $ map (mkName . ("n_" ++)) fnames
 835   le_new <- mapM buildFromMaybe fnames
 836   funt <- [t| $(conT name_f) -> $(conT name_p) -> $(conT name_f) |]
 837   let sig = SigD fun_name funt
 838       fclause = Clause [VarP (mkName oname_f), VarP (mkName oname_p)]
 839                 (NormalB $ LetE (le_full:le_part:le_new) obj_new) []
 840       fun = FunD fun_name [fclause]
 841   return [sig, fun]