code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [9])
   4 m4_define([gnt_version_revision], [3])
   5 m4_define([gnt_version_suffix], [])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-xen-config-dir=...
  53 AC_ARG_WITH([xen-config-dir],
  54   [AS_HELP_STRING([--with-xen-config-dir=DIR],
  55                   m4_normalize([Xen configuration directory
  56                                 (default: /etc/xen)]))],
  57   [xen_config_dir="$withval"],
  58   [xen_config_dir=/etc/xen])
  59 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
  60
  61 # --with-os-search-path=...
  62 # do a bit of black sed magic to for quoting of the strings in the list
  63 AC_ARG_WITH([os-search-path],
  64   [AS_HELP_STRING([--with-os-search-path=LIST],
  65     [comma separated list of directories to]
  66     [ search for OS images (default is /srv/ganeti/os)]
  67   )],
  68   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  69   [os_search_path="'/srv/ganeti/os'"])
  70 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  71
  72 # --with-extstorage-search-path=...
  73 # same black sed magic for quoting of the strings in the list
  74 AC_ARG_WITH([extstorage-search-path],
  75   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  76     [comma separated list of directories to]
  77     [ search for External Storage Providers]
  78     [ (default is /srv/ganeti/extstorage)]
  79   )],
  80   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  81   [es_search_path="'/srv/ganeti/extstorage'"])
  82 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  83
  84 # --with-iallocator-search-path=...
  85 # do a bit of black sed magic to for quoting of the strings in the list
  86 AC_ARG_WITH([iallocator-search-path],
  87   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  88     [comma separated list of directories to]
  89     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  90   )],
  91   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  92   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  93 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  94
  95 # --with-xen-bootloader=...
  96 AC_ARG_WITH([xen-bootloader],
  97   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  98     [bootloader for Xen hypervisor (default is empty)]
  99   )],
 100   [xen_bootloader="$withval"],
 101   [xen_bootloader=])
 102 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
 103
 104 # --with-xen-kernel=...
 105 AC_ARG_WITH([xen-kernel],
 106   [AS_HELP_STRING([--with-xen-kernel=PATH],
 107     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
 108   )],
 109   [xen_kernel="$withval"],
 110   [xen_kernel="/boot/vmlinuz-3-xenU"])
 111 AC_SUBST(XEN_KERNEL, $xen_kernel)
 112
 113 # --with-xen-initrd=...
 114 AC_ARG_WITH([xen-initrd],
 115   [AS_HELP_STRING([--with-xen-initrd=PATH],
 116     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 117   )],
 118   [xen_initrd="$withval"],
 119   [xen_initrd="/boot/initrd-3-xenU"])
 120 AC_SUBST(XEN_INITRD, $xen_initrd)
 121
 122 # --with-kvm-kernel=...
 123 AC_ARG_WITH([kvm-kernel],
 124   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 125     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 126   )],
 127   [kvm_kernel="$withval"],
 128   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 129 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 130
 131 # --with-kvm-path=...
 132 AC_ARG_WITH([kvm-path],
 133   [AS_HELP_STRING([--with-kvm-path=PATH],
 134     [absolute path to the kvm binary]
 135     [ (default is /usr/bin/kvm)]
 136   )],
 137   [kvm_path="$withval"],
 138   [kvm_path="/usr/bin/kvm"])
 139 AC_SUBST(KVM_PATH, $kvm_path)
 140
 141 # --with-lvm-stripecount=...
 142 AC_ARG_WITH([lvm-stripecount],
 143   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 144     [the default number of stripes to use for LVM volumes]
 145     [ (default is 1)]
 146   )],
 147   [lvm_stripecount="$withval"],
 148   [lvm_stripecount=1])
 149 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 150
 151 # --with-ssh-login-user=...
 152 AC_ARG_WITH([ssh-login-user],
 153   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 154     [user to use for SSH logins within the cluster (default is root)]
 155   )],
 156   [ssh_login_user="$withval"],
 157   [ssh_login_user=root])
 158 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 159
 160 # --with-ssh-console-user=...
 161 AC_ARG_WITH([ssh-console-user],
 162   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 163     [user to use for SSH logins to access instance consoles (default is root)]
 164   )],
 165   [ssh_console_user="$withval"],
 166   [ssh_console_user=root])
 167 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 168
 169 # --with-default-user=...
 170 AC_ARG_WITH([default-user],
 171   [AS_HELP_STRING([--with-default-user=USERNAME],
 172     [default user for daemons]
 173     [ (default is to run all daemons as root)]
 174   )],
 175   [user_default="$withval"],
 176   [user_default=root])
 177
 178 # --with-default-group=...
 179 AC_ARG_WITH([default-group],
 180   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 181     [default group for daemons]
 182     [ (default is to run all daemons under group root)]
 183   )],
 184   [group_default="$withval"],
 185   [group_default=root])
 186
 187 # --with-user-prefix=...
 188 AC_ARG_WITH([user-prefix],
 189   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 190     [prefix for daemon users]
 191     [ (default is to run all daemons as root; use --with-default-user]
 192     [ to change the default)]
 193   )],
 194   [user_masterd="${withval}masterd";
 195    user_rapi="${withval}rapi";
 196    user_confd="${withval}confd";
 197    user_luxid="${withval}luxid";
 198    user_noded="$user_default";
 199    user_mond="$user_default"],
 200   [user_masterd="$user_default";
 201    user_rapi="$user_default";
 202    user_confd="$user_default";
 203    user_luxid="$user_default";
 204    user_noded="$user_default";
 205    user_mond="$user_default"])
 206 AC_SUBST(MASTERD_USER, $user_masterd)
 207 AC_SUBST(RAPI_USER, $user_rapi)
 208 AC_SUBST(CONFD_USER, $user_confd)
 209 AC_SUBST(LUXID_USER, $user_luxid)
 210 AC_SUBST(NODED_USER, $user_noded)
 211 AC_SUBST(MOND_USER, $user_mond)
 212
 213 # --with-group-prefix=...
 214 AC_ARG_WITH([group-prefix],
 215   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 216     [prefix for daemon POSIX groups]
 217     [ (default is to run all daemons under group root; use]
 218     [ --with-default-group to change the default)]
 219   )],
 220   [group_rapi="${withval}rapi";
 221    group_admin="${withval}admin";
 222    group_confd="${withval}confd";
 223    group_luxid="${withval}luxid";
 224    group_masterd="${withval}masterd";
 225    group_noded="$group_default";
 226    group_daemons="${withval}daemons";
 227    group_mond="$group_default"],
 228   [group_rapi="$group_default";
 229    group_admin="$group_default";
 230    group_confd="$group_default";
 231    group_luxid="$group_default";
 232    group_masterd="$group_default";
 233    group_noded="$group_default";
 234    group_daemons="$group_default";
 235    group_mond="$group_default"])
 236 AC_SUBST(RAPI_GROUP, $group_rapi)
 237 AC_SUBST(ADMIN_GROUP, $group_admin)
 238 AC_SUBST(CONFD_GROUP, $group_confd)
 239 AC_SUBST(LUXID_GROUP, $group_luxid)
 240 AC_SUBST(MASTERD_GROUP, $group_masterd)
 241 AC_SUBST(NODED_GROUP, $group_noded)
 242 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 243 AC_SUBST(MOND_GROUP, $group_mond)
 244
 245 # Print the config to the user
 246 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 247 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 248 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 249 AC_MSG_NOTICE([Running ganeti-luxid as $user_luxid:$group_luxid])
 250 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 251 AC_MSG_NOTICE([Group for clients is $group_admin])
 252
 253 # --enable-drbd-barriers
 254 AC_ARG_ENABLE([drbd-barriers],
 255   [AS_HELP_STRING([--enable-drbd-barriers],
 256                   m4_normalize([enable the DRBD barriers functionality by
 257                                 default (>= 8.0.12) (default: enabled)]))],
 258   [[if test "$enableval" != no; then
 259       DRBD_BARRIERS=n
 260       DRBD_NO_META_FLUSH=False
 261     else
 262       DRBD_BARRIERS=bf
 263       DRBD_NO_META_FLUSH=True
 264     fi
 265   ]],
 266   [DRBD_BARRIERS=n
 267    DRBD_NO_META_FLUSH=False
 268   ])
 269 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 270 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 271
 272 # --enable-syslog[=no/yes/only]
 273 AC_ARG_ENABLE([syslog],
 274   [AS_HELP_STRING([--enable-syslog],
 275     [enable use of syslog (default: disabled), one of no/yes/only])],
 276   [[case "$enableval" in
 277       no)
 278         SYSLOG=no
 279         ;;
 280       yes)
 281         SYSLOG=yes
 282         ;;
 283       only)
 284         SYSLOG=only
 285         ;;
 286       *)
 287         SYSLOG=
 288         ;;
 289     esac
 290   ]],
 291   [SYSLOG=no])
 292
 293 if test -z "$SYSLOG"
 294 then
 295   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 296 fi
 297 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 298
 299 AC_ARG_ENABLE([restricted-commands],
 300   [AS_HELP_STRING([--enable-restricted-commands],
 301                   m4_normalize([enable restricted commands in the node daemon
 302                                 (default: disabled)]))],
 303   [[if test "$enableval" = no; then
 304       enable_restricted_commands=False
 305     else
 306       enable_restricted_commands=True
 307     fi
 308   ]],
 309   [enable_restricted_commands=False])
 310 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 311
 312 # --with-disk-separator=...
 313 AC_ARG_WITH([disk-separator],
 314   [AS_HELP_STRING([--with-disk-separator=STRING],
 315     [Disk index separator, useful if the default of ':' is handled]
 316     [ specially by the hypervisor]
 317   )],
 318   [disk_separator="$withval"],
 319   [disk_separator=":"])
 320 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 321
 322 # Check common programs
 323 AC_PROG_INSTALL
 324 AC_PROG_LN_S
 325
 326 # Check for the ip command
 327 AC_ARG_VAR(IP_PATH, [ip path])
 328 AC_PATH_PROG(IP_PATH, [ip], [])
 329 if test -z "$IP_PATH"
 330 then
 331   AC_MSG_ERROR([ip command not found])
 332 fi
 333
 334 # Check for pandoc
 335 AC_ARG_VAR(PANDOC, [pandoc path])
 336 AC_PATH_PROG(PANDOC, [pandoc], [])
 337 if test -z "$PANDOC"
 338 then
 339   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 340 fi
 341
 342 # Check for python-sphinx
 343 AC_ARG_VAR(SPHINX, [sphinx-build path])
 344 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 345 if test -z "$SPHINX"
 346 then
 347   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 348                             not be possible]))
 349 else
 350   # Sphinx exits with code 1 when it prints its usage
 351   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
 352
 353   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
 354     AC_MSG_ERROR([Unable to determine Sphinx version])
 355
 356   # Note: Character classes ([...]) need to be double quoted due to autoconf
 357   # using m4
 358   elif ! echo "$sphinxver" | grep -q -E \
 359        '^Sphinx[[[:space:]]]+(\(sphinx-build\)[[[:space:]]]+|v)[[1-9]]\>'; then
 360     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
 361   fi
 362 fi
 363 AM_CONDITIONAL([HAS_SPHINX], [test -n "$SPHINX"])
 364
 365 AC_ARG_ENABLE([manpages-in-doc],
 366   [AS_HELP_STRING([--enable-manpages-in-doc],
 367                   m4_normalize([include man pages in HTML documentation
 368                                 (requires sphinx; default disabled)]))],
 369   [case "$enableval" in
 370       yes) manpages_in_doc=yes ;;
 371       no) manpages_in_doc= ;;
 372       *)
 373         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 374         ;;
 375     esac
 376   ],
 377   [manpages_in_doc=])
 378 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 379 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 380
 381 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 382   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 383 fi
 384
 385 # Check for graphviz (dot)
 386 AC_ARG_VAR(DOT, [dot path])
 387 AC_PATH_PROG(DOT, [dot], [])
 388 if test -z "$DOT"
 389 then
 390   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 391                             documentation rebuild not possible]))
 392 fi
 393
 394 # Check for pylint
 395 AC_ARG_VAR(PYLINT, [pylint path])
 396 AC_PATH_PROG(PYLINT, [pylint], [])
 397 if test -z "$PYLINT"
 398 then
 399   AC_MSG_WARN([pylint not found, checking code will not be possible])
 400 fi
 401
 402 # Check for pep8
 403 AC_ARG_VAR(PEP8, [pep8 path])
 404 AC_PATH_PROG(PEP8, [pep8], [])
 405 if test -z "$PEP8"
 406 then
 407   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 408 fi
 409 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 410
 411 # Check for python-coverage
 412 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 413 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 414 if test -z "$PYCOVERAGE"
 415 then
 416   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 417                             Python test coverage will not be possible]))
 418 fi
 419
 420 # Check for socat
 421 AC_ARG_VAR(SOCAT, [socat path])
 422 AC_PATH_PROG(SOCAT, [socat], [])
 423 if test -z "$SOCAT"
 424 then
 425   AC_MSG_ERROR([socat not found])
 426 fi
 427
 428 # Check for qemu-img
 429 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 430 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 431 if test -z "$QEMUIMG_PATH"
 432 then
 433   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 434 fi
 435
 436 # --enable-confd
 437 ENABLE_CONFD=
 438 AC_ARG_ENABLE([confd],
 439   [AS_HELP_STRING([--enable-confd],
 440   [enable the ganeti-confd daemon (default: check)])],
 441   [],
 442   [enable_confd=check])
 443
 444 ENABLE_MOND=
 445 AC_ARG_ENABLE([monitoring],
 446   [AS_HELP_STRING([--enable-monitoring],
 447   [enable the ganeti monitoring daemon (default: check)])],
 448   [],
 449   [enable_monitoring=check])
 450
 451 # Check for ghc
 452 AC_ARG_VAR(GHC, [ghc path])
 453 AC_PATH_PROG(GHC, [ghc], [])
 454 if test -z "$GHC"; then
 455   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 456 fi
 457
 458 AC_MSG_CHECKING([checking for extra GHC flags])
 459 GHC_BYVERSION_FLAGS=
 460 # check for GHC supported flags that vary accross versions
 461 for flag in -fwarn-incomplete-uni-patterns; do
 462   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 463    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 464   fi
 465 done
 466 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 467 AC_SUBST(GHC_BYVERSION_FLAGS)
 468
 469 # Check for ghc-pkg
 470 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 471 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 472 if test -z "$GHC_PKG"; then
 473   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 474 fi
 475
 476 # check for modules, first custom/special checks
 477 AC_MSG_NOTICE([checking for required haskell modules])
 478 HS_PARALLEL3=
 479 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 480                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 481 AC_SUBST(HS_PARALLEL3)
 482
 483 # and now standard modules
 484 AC_GHC_PKG_REQUIRE(curl)
 485 AC_GHC_PKG_REQUIRE(json)
 486 AC_GHC_PKG_REQUIRE(network)
 487 AC_GHC_PKG_REQUIRE(mtl)
 488 AC_GHC_PKG_REQUIRE(bytestring)
 489 AC_GHC_PKG_REQUIRE(utf8-string)
 490 AC_GHC_PKG_REQUIRE(hslogger)
 491
 492 # extra modules for confd functionality
 493 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 494 has_confd=False
 495 if test "$enable_confd" != no; then
 496   CONFD_PKG=
 497   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 498                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 499   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 500   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 501   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 502   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 503   if test -z "$CONFD_PKG"; then
 504     has_confd=True
 505   elif test "$enable_confd" = check; then
 506     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 507                               not found ($CONFD_PKG), confd disabled]))
 508   else
 509     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 510                                  required libraries were not found:
 511                                  $CONFD_PKG]))
 512   fi
 513 fi
 514 AC_SUBST(HS_REGEX_PCRE)
 515 if test "$has_confd" = True; then
 516   AC_MSG_NOTICE([Enabling confd usage])
 517 fi
 518 AC_SUBST(ENABLE_CONFD, $has_confd)
 519 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 520
 521 #extra modules for monitoring daemon functionality
 522 has_monitoring=False
 523 if test "$enable_monitoring" != no; then
 524   MONITORING_PKG=
 525   AC_GHC_PKG_CHECK([attoparsec], [],
 526                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 527   AC_GHC_PKG_CHECK([snap-server], [],
 528                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
 529   AC_GHC_PKG_CHECK([process], [],
 530                    [MONITORING_PKG="$MONITORING_PKG process"])
 531   MONITORING_DEP=
 532   if test "$has_confd" = False; then
 533     MONITORING_DEP="$MONITORING_DEP confd"
 534   fi
 535   has_monitoring_pkg=False
 536   if test -z "$MONITORING_PKG"; then
 537     has_monitoring_pkg=True
 538   elif test "$enable_monitoring" = check; then
 539     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 540                               daemon were not found ($MONITORING_PKG),
 541                               monitoring disabled]))
 542   else
 543     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 544                                  required libraries were not found:
 545                                  $MONITORING_PKG]))
 546   fi
 547   has_monitoring_dep=False
 548   if test -z "$MONITORING_DEP"; then
 549     has_monitoring_dep=True
 550   elif test "$enable_monitoring" = check; then
 551     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
 552                               monitoring agent were not enabled
 553                               ($MONITORING_DEP), monitoring disabled]))
 554   else
 555     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 556                                  required optional Ganeti components were not
 557                                  found: $MONITORING_DEP]))
 558   fi
 559
 560 fi
 561 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
 562   has_monitoring=True
 563   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 564 fi
 565 AC_SUBST(ENABLE_MOND, $has_monitoring)
 566 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
 567
 568 # development modules
 569 HS_NODEV=
 570 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 571 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 572 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 573 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 574 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 575 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 576 #        that are needed to execute the tests, avoiding the duplication
 577 #        of the checks.
 578 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 579 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 580 AC_GHC_PKG_CHECK([process], [], [HS_NODEV=1])
 581 AC_GHC_PKG_CHECK([snap-server], [], [HS_NODEV=1])
 582 AC_GHC_PKG_CHECK([regex-pcre], [], [HS_NODEV=1])
 583 AC_GHC_PKG_CHECK([Crypto], [], [HS_NODEV=1])
 584 AC_GHC_PKG_CHECK([text], [], [HS_NODEV=1])
 585 AC_GHC_PKG_CHECK([hinotify], [], [HS_NODEV=1])
 586 if test -n "$HS_NODEV"; then
 587    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 588                              you won't be able to run Haskell unittests]))
 589 else
 590    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 591 fi
 592 AC_SUBST(HS_NODEV)
 593
 594 HTOOLS=yes
 595 AC_SUBST(HTOOLS)
 596
 597 # --enable-split-query
 598 ENABLE_SPLIT_QUERY=
 599 AC_ARG_ENABLE([split-query],
 600   [AS_HELP_STRING([--enable-split-query],
 601   [enable use of custom query daemon via confd])],
 602   [[case "$enableval" in
 603       no)
 604         enable_split_query=False
 605         ;;
 606       yes)
 607         enable_split_query=True
 608         ;;
 609       *)
 610         echo "Invalid value for enable-confd '$enableval'"
 611         exit 1
 612         ;;
 613     esac
 614   ]],
 615   [[case "x${has_confd}x" in
 616      xTruex)
 617        enable_split_query=True
 618        ;;
 619      *)
 620        enable_split_query=False
 621        ;;
 622    esac]])
 623 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 624
 625 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 626   AC_MSG_ERROR([Split queries require the confd daemon])
 627 fi
 628
 629 if test x$enable_split_query = xTrue; then
 630   AC_MSG_NOTICE([Split query functionality enabled])
 631 fi
 632
 633 # Check for HsColour
 634 HS_APIDOC=no
 635 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 636 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 637 if test -z "$HSCOLOUR"; then
 638   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 639                             not be generated]))
 640 fi
 641
 642 # Check for haddock
 643 AC_ARG_VAR(HADDOCK, [haddock path])
 644 AC_PATH_PROG(HADDOCK, [haddock], [])
 645 if test -z "$HADDOCK"; then
 646   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 647                             not be generated]))
 648 fi
 649 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 650   HS_APIDOC=yes
 651 fi
 652 AC_SUBST(HS_APIDOC)
 653
 654 # Check for hlint
 655 AC_ARG_VAR(HLINT, [hlint path])
 656 AC_PATH_PROG(HLINT, [hlint], [])
 657 if test -z "$HLINT"; then
 658   AC_MSG_WARN([hlint not found, checking code will not be possible])
 659 fi
 660
 661 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 662   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 663                              htools support is not enabled]))
 664 fi
 665
 666 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 667 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 668 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 669 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 670
 671 # Check for fakeroot
 672 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 673 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 674 if test -z "$FAKEROOT_PATH"; then
 675   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 676                             will not be executed]))
 677 fi
 678 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 679
 680 SOCAT_USE_ESCAPE=
 681 AC_ARG_ENABLE([socat-escape],
 682   [AS_HELP_STRING([--enable-socat-escape],
 683     [use escape functionality available in socat >= 1.7 (default: detect
 684      automatically)])],
 685   [[if test "$enableval" = yes; then
 686       SOCAT_USE_ESCAPE=True
 687     else
 688       SOCAT_USE_ESCAPE=False
 689     fi
 690   ]])
 691
 692 if test -z "$SOCAT_USE_ESCAPE"
 693 then
 694   if $SOCAT -hh | grep -w -q escape; then
 695     SOCAT_USE_ESCAPE=True
 696   else
 697     SOCAT_USE_ESCAPE=False
 698   fi
 699 fi
 700
 701 AC_SUBST(SOCAT_USE_ESCAPE)
 702
 703 SOCAT_USE_COMPRESS=
 704 AC_ARG_ENABLE([socat-compress],
 705   [AS_HELP_STRING([--enable-socat-compress],
 706     [use OpenSSL compression option available in patched socat builds
 707      (see INSTALL for details; default: detect automatically)])],
 708   [[if test "$enableval" = yes; then
 709       SOCAT_USE_COMPRESS=True
 710     else
 711       SOCAT_USE_COMPRESS=False
 712     fi
 713   ]])
 714
 715 if test -z "$SOCAT_USE_COMPRESS"
 716 then
 717   if $SOCAT -hhh | grep -w -q openssl-compress; then
 718     SOCAT_USE_COMPRESS=True
 719   else
 720     SOCAT_USE_COMPRESS=False
 721   fi
 722 fi
 723
 724 AC_SUBST(SOCAT_USE_COMPRESS)
 725
 726 if man --help | grep -q -e --warnings
 727 then
 728   MAN_HAS_WARNINGS=1
 729 else
 730   MAN_HAS_WARNINGS=
 731   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 732                             will not be possible]))
 733 fi
 734
 735 AC_SUBST(MAN_HAS_WARNINGS)
 736
 737 # Check for Python
 738 AM_PATH_PYTHON(2.6)
 739
 740 AC_PYTHON_MODULE(OpenSSL, t)
 741 AC_PYTHON_MODULE(simplejson, t)
 742 AC_PYTHON_MODULE(pyparsing, t)
 743 AC_PYTHON_MODULE(pyinotify, t)
 744 AC_PYTHON_MODULE(pycurl, t)
 745 AC_PYTHON_MODULE(bitarray, t)
 746 AC_PYTHON_MODULE(ipaddr, t)
 747 AC_PYTHON_MODULE(mock)
 748 AC_PYTHON_MODULE(affinity)
 749 AC_PYTHON_MODULE(paramiko)
 750
 751 # Development-only Python modules
 752 PY_NODEV=
 753 AC_PYTHON_MODULE(yaml)
 754 if test $HAVE_PYMOD_YAML == "no"; then
 755   PY_NODEV="$PY_NODEV yaml"
 756 fi
 757
 758 if test -n "$PY_NODEV"; then
 759   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
 760                             found, you won't be able to run Python unittests]))
 761 else
 762   AC_MSG_NOTICE([Python development modules found, unittests enabled])
 763 fi
 764 AC_SUBST(PY_NODEV)
 765 AM_CONDITIONAL([PY_UNIT], [test -n $PY_NODEV])
 766
 767 AC_CONFIG_FILES([ Makefile ])
 768
 769 AC_OUTPUT