TestAsyncUDPSocket: remove dead code and add test
[ganeti-local] / configure.ac
1 # Configure script for Ganeti
2 m4_define([gnt_version_major], [2])
3 m4_define([gnt_version_minor], [1])
4 m4_define([gnt_version_revision], [2])
5 m4_define([gnt_version_suffix], [.1])
6 m4_define([gnt_version_full],
7           m4_format([%d.%d.%d%s],
8                     gnt_version_major, gnt_version_minor,
9                     gnt_version_revision, gnt_version_suffix))
10
11 AC_PREREQ(2.59)
12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
13 AC_CONFIG_AUX_DIR(autotools)
14 AC_CONFIG_SRCDIR(configure)
15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
16
17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
21 AC_SUBST([VERSION_FULL], gnt_version_full)
22
23 # --with-ssh-initscript=...
24 AC_ARG_WITH([ssh-initscript],
25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
26     [SSH init script to use (default is /etc/init.d/ssh)]
27   )],
28   [ssh_initd_script="$withval"],
29   [ssh_initd_script="/etc/init.d/ssh"])
30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
31
32 # --with-export-dir=...
33 AC_ARG_WITH([export-dir],
34   [AS_HELP_STRING([--with-export-dir=DIR],
35     [directory to use by default for instance image]
36     [ exports (default is /srv/ganeti/export)]
37   )],
38   [export_dir="$withval"],
39   [export_dir="/srv/ganeti/export"])
40 AC_SUBST(EXPORT_DIR, $export_dir)
41
42 # --with-ssh-config-dir=...
43 AC_ARG_WITH([ssh-config-dir],
44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
45     [ directory with ssh host keys ]
46     [ (default is /etc/ssh)]
47   )],
48   [ssh_config_dir="$withval"],
49   [ssh_config_dir="/etc/ssh"])
50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
51
52 # --with-os-search-path=...
53 # do a bit of black sed magic to for quoting of the strings in the list
54 AC_ARG_WITH([os-search-path],
55   [AS_HELP_STRING([--with-os-search-path=LIST],
56     [comma separated list of directories to]
57     [ search for OS images (default is /srv/ganeti/os)]
58   )],
59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
60   [os_search_path="'/srv/ganeti/os'"])
61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
62
63 # --with-iallocator-search-path=...
64 # do a bit of black sed magic to for quoting of the strings in the list
65 AC_ARG_WITH([iallocator-search-path],
66   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
67     [comma separated list of directories to]
68     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
69   )],
70   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
71   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
72 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
73
74 # --with-xen-bootloader=...
75 AC_ARG_WITH([xen-bootloader],
76   [AS_HELP_STRING([--with-xen-bootloader=PATH],
77     [bootloader for Xen hypervisor (default is empty)]
78   )],
79   [xen_bootloader="$withval"],
80   [xen_bootloader=])
81 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
82
83 # --with-xen-kernel=...
84 AC_ARG_WITH([xen-kernel],
85   [AS_HELP_STRING([--with-xen-kernel=PATH],
86     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-2.6-xenU)]
87   )],
88   [xen_kernel="$withval"],
89   [xen_kernel="/boot/vmlinuz-2.6-xenU"])
90 AC_SUBST(XEN_KERNEL, $xen_kernel)
91
92 # --with-xen-initrd=...
93 AC_ARG_WITH([xen-initrd],
94   [AS_HELP_STRING([--with-xen-initrd=PATH],
95     [DomU initrd image for Xen hypervisor (default is /boot/initrd-2.6-xenU)]
96   )],
97   [xen_initrd="$withval"],
98   [xen_initrd="/boot/initrd-2.6-xenU"])
99 AC_SUBST(XEN_INITRD, $xen_initrd)
100
101 # --with-file-storage-dir=...
102 AC_ARG_WITH([file-storage-dir],
103   [AS_HELP_STRING([--with-file-storage-dir=PATH],
104     [directory to store files for file-based backend]
105     [ (default is /srv/ganeti/file-storage)]
106   )],
107   [[file_storage_dir="$withval";
108     if test "$withval" != no; then
109       enable_file_storage=True
110     else
111       enable_file_storage=False
112     fi
113   ]],
114   [[file_storage_dir="/srv/ganeti/file-storage"; enable_file_storage="True"]])
115 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
116 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
117
118 # --with-kvm-path=...
119 AC_ARG_WITH([kvm-path],
120   [AS_HELP_STRING([--with-kvm-path=PATH],
121     [absolute path to the kvm binary]
122     [ (default is /usr/bin/kvm)]
123   )],
124   [kvm_path="$withval"],
125   [kvm_path="/usr/bin/kvm"])
126 AC_SUBST(KVM_PATH, $kvm_path)
127
128 # --with-lvm-stripecount=...
129 AC_ARG_WITH([lvm-stripecount],
130   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
131     [the number of stripes to use for LVM volumes]
132     [ (default is 1)]
133   )],
134   [lvm_stripecount="$withval"],
135   [lvm_stripecount="1"])
136 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
137
138 # --enable-drbd-barriers
139 AC_ARG_ENABLE([drbd-barriers],
140   [AS_HELP_STRING([--enable-drbd-barriers],
141     [enable the DRBD barrier functionality (>= 8.0.12) (default: enabled)])],
142   [[if test "$enableval" != no; then
143       DRBD_BARRIERS=True
144     else
145       DRBD_BARRIERS=False
146     fi
147   ]],
148   [DRBD_BARRIERS=True])
149 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
150
151 # --enable-syslog[=no/yes/only]
152 AC_ARG_ENABLE([syslog],
153   [AS_HELP_STRING([--enable-syslog],
154     [enable use of syslog (default: disabled), one of no/yes/only])],
155   [[case "$enableval" in
156       no)
157         SYSLOG=no
158         ;;
159       yes)
160         SYSLOG=yes
161         ;;
162       only)
163         SYSLOG=only
164         ;;
165       *)
166         SYSLOG=
167         ;;
168     esac
169   ]],
170   [SYSLOG=no])
171
172 if test -z "$SYSLOG"
173 then
174   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
175 fi
176 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
177
178 # Check common programs
179 AC_PROG_INSTALL
180 AC_PROG_LN_S
181
182 # Check for docbook programs
183 AC_ARG_VAR(DOCBOOK2MAN, [docbook2man path])
184 AC_PATH_PROG(DOCBOOK2MAN, [docbook2man], [])
185 if test -z "$DOCBOOK2MAN"
186 then
187   AC_MSG_WARN([docbook2man not found, man pages rebuild will not be possible])
188 fi
189
190 AC_ARG_VAR(DOCBOOK2HTML, [docbook2html path])
191 AC_PATH_PROG(DOCBOOK2HTML, [docbook2html], [])
192 if test -z "$DOCBOOK2HTML"
193 then
194   AC_MSG_WARN([docbook2html not found, man pages rebuild will not be possible])
195 fi
196
197 # Check for python-sphinx
198 AC_ARG_VAR(SPHINX, [sphinx-build path])
199 AC_PATH_PROG(SPHINX, [sphinx-build], [])
200 if test -z "$SPHINX"
201 then
202   AC_MSG_WARN([sphinx-build not found, documentation rebuild will not be possible])
203 fi
204
205 # Check for graphviz (dot)
206 AC_ARG_VAR(DOT, [dot path])
207 AC_PATH_PROG(DOT, [dot], [])
208 if test -z "$DOT"
209 then
210   AC_MSG_WARN([dot (from the graphviz suite) not found, documentation rebuild not possible])
211 fi
212
213 # Check for pylint
214 AC_ARG_VAR(PYLINT, [pylint path])
215 AC_PATH_PROG(PYLINT, [pylint], [])
216 if test -z "$PYLINT"
217 then
218   AC_MSG_WARN([pylint not found, checking code will not be possible])
219 fi
220
221 # Check for socat
222 AC_ARG_VAR(SOCAT, [socat path])
223 AC_PATH_PROG(SOCAT, [socat], [])
224 if test -z "$SOCAT"
225 then
226   AC_MSG_ERROR([socat not found])
227 fi
228
229 SOCAT_USE_ESCAPE=
230 AC_ARG_ENABLE([socat-escape],
231   [AS_HELP_STRING([--enable-socat-escape],
232     [use escape functionality available in socat >= 1.7 (default: detect
233      automatically)])],
234   [[if test "$enableval" = yes; then
235       SOCAT_USE_ESCAPE=True
236     else
237       SOCAT_USE_ESCAPE=False
238     fi
239   ]])
240
241 if test -z "$SOCAT_USE_ESCAPE"
242 then
243   if $SOCAT -hh | grep -w -q escape; then
244     SOCAT_USE_ESCAPE=True
245   else
246     SOCAT_USE_ESCAPE=False
247   fi
248 fi
249
250 AC_SUBST(SOCAT_USE_ESCAPE)
251
252 # Check for Python
253 AM_PATH_PYTHON(2.4)
254
255 AC_PYTHON_MODULE(OpenSSL, t)
256 AC_PYTHON_MODULE(simplejson, t)
257 AC_PYTHON_MODULE(pyparsing, t)
258 AC_PYTHON_MODULE(pyinotify, t)
259
260 AC_CONFIG_FILES([ Makefile ])
261
262 AC_OUTPUT