code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [10])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~alpha1])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --enable-versionfull
  24 AC_ARG_ENABLE([versionfull],
  25   [AS_HELP_STRING([--enable-versionfull],
  26                   m4_normalize([use the full version string rather
  27                   than major.minor for version directories]))],
  28   [[if test "$enableval" != no; then
  29       USE_VERSION_FULL=yes
  30     else
  31       USER_VERSION_FULL=no
  32     fi
  33   ]],
  34   [USE_VERSION_FULL=no
  35   ])
  36 AC_SUBST(USE_VERSION_FULL, $USE_VERSION_FULL)
  37 AM_CONDITIONAL([USE_VERSION_FULL], [test "$USE_VERSION_FULL" = yes])
  38
  39 # --enable-symlinks
  40 AC_ARG_ENABLE([symlinks],
  41   [AS_HELP_STRING([--enable-symlinks],
  42                   m4_normalize([also install version-dependent symlinks under
  43                   $sysconfdir (default: enabled)]))],
  44   [[if test "$enableval" != no; then
  45       INSTALL_SYMLINKS=yes
  46     else
  47       INSTALL_SYMLINKS=no
  48     fi
  49   ]],
  50   [INSTALL_SYMLINKS=yes
  51   ])
  52 AC_SUBST(INSTALL_SYMLINKS, $INSTALL_SYMLINKS)
  53 AM_CONDITIONAL([INSTALL_SYMLINKS], [test "$INSTALL_SYMLINKS" = yes])
  54
  55 # --with-ssh-initscript=...
  56 AC_ARG_WITH([ssh-initscript],
  57   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  58     [SSH init script to use (default is /etc/init.d/ssh)]
  59   )],
  60   [ssh_initd_script="$withval"],
  61   [ssh_initd_script="/etc/init.d/ssh"])
  62 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  63
  64 # --with-export-dir=...
  65 AC_ARG_WITH([export-dir],
  66   [AS_HELP_STRING([--with-export-dir=DIR],
  67     [directory to use by default for instance image]
  68     [ exports (default is /srv/ganeti/export)]
  69   )],
  70   [export_dir="$withval"],
  71   [export_dir="/srv/ganeti/export"])
  72 AC_SUBST(EXPORT_DIR, $export_dir)
  73
  74 # --with-ssh-config-dir=...
  75 AC_ARG_WITH([ssh-config-dir],
  76   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  77     [ directory with ssh host keys ]
  78     [ (default is /etc/ssh)]
  79   )],
  80   [ssh_config_dir="$withval"],
  81   [ssh_config_dir="/etc/ssh"])
  82 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  83
  84 # --with-xen-config-dir=...
  85 AC_ARG_WITH([xen-config-dir],
  86   [AS_HELP_STRING([--with-xen-config-dir=DIR],
  87                   m4_normalize([Xen configuration directory
  88                                 (default: /etc/xen)]))],
  89   [xen_config_dir="$withval"],
  90   [xen_config_dir=/etc/xen])
  91 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
  92
  93 # --with-os-search-path=...
  94 # do a bit of black sed magic to for quoting of the strings in the list
  95 AC_ARG_WITH([os-search-path],
  96   [AS_HELP_STRING([--with-os-search-path=LIST],
  97     [comma separated list of directories to]
  98     [ search for OS images (default is /srv/ganeti/os)]
  99   )],
 100   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/\1/g"`],
 101   [os_search_path="/srv/ganeti/os"])
 102 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
 103
 104 # --with-extstorage-search-path=...
 105 # same black sed magic for quoting of the strings in the list
 106 AC_ARG_WITH([extstorage-search-path],
 107   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
 108     [comma separated list of directories to]
 109     [ search for External Storage Providers]
 110     [ (default is /srv/ganeti/extstorage)]
 111   )],
 112   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/\1/g"`],
 113   [es_search_path="/srv/ganeti/extstorage"])
 114 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
 115
 116 # --with-iallocator-search-path=...
 117 # do a bit of black sed magic to for quoting of the strings in the list
 118 AC_ARG_WITH([iallocator-search-path],
 119   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
 120     [comma separated list of directories to]
 121     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
 122   )],
 123   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/\1/g"`],
 124   [iallocator_search_path="$libdir/$PACKAGE_NAME/iallocators"])
 125 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
 126
 127 # --with-xen-bootloader=...
 128 AC_ARG_WITH([xen-bootloader],
 129   [AS_HELP_STRING([--with-xen-bootloader=PATH],
 130     [bootloader for Xen hypervisor (default is empty)]
 131   )],
 132   [xen_bootloader="$withval"],
 133   [xen_bootloader=])
 134 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
 135
 136 # --with-xen-kernel=...
 137 AC_ARG_WITH([xen-kernel],
 138   [AS_HELP_STRING([--with-xen-kernel=PATH],
 139     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
 140   )],
 141   [xen_kernel="$withval"],
 142   [xen_kernel="/boot/vmlinuz-3-xenU"])
 143 AC_SUBST(XEN_KERNEL, $xen_kernel)
 144
 145 # --with-xen-initrd=...
 146 AC_ARG_WITH([xen-initrd],
 147   [AS_HELP_STRING([--with-xen-initrd=PATH],
 148     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 149   )],
 150   [xen_initrd="$withval"],
 151   [xen_initrd="/boot/initrd-3-xenU"])
 152 AC_SUBST(XEN_INITRD, $xen_initrd)
 153
 154 # --with-kvm-kernel=...
 155 AC_ARG_WITH([kvm-kernel],
 156   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 157     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 158   )],
 159   [kvm_kernel="$withval"],
 160   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 161 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 162
 163 # --with-shared-file-storage-dir=...
 164 AC_ARG_WITH([shared-file-storage-dir],
 165   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 166     [directory to store files for shared file-based backend]
 167     [ (default is /srv/ganeti/shared-file-storage)]
 168   )],
 169   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage"]])
 170 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 171
 172 # --with-kvm-path=...
 173 AC_ARG_WITH([kvm-path],
 174   [AS_HELP_STRING([--with-kvm-path=PATH],
 175     [absolute path to the kvm binary]
 176     [ (default is /usr/bin/kvm)]
 177   )],
 178   [kvm_path="$withval"],
 179   [kvm_path="/usr/bin/kvm"])
 180 AC_SUBST(KVM_PATH, $kvm_path)
 181
 182 # --with-lvm-stripecount=...
 183 AC_ARG_WITH([lvm-stripecount],
 184   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 185     [the default number of stripes to use for LVM volumes]
 186     [ (default is 1)]
 187   )],
 188   [lvm_stripecount="$withval"],
 189   [lvm_stripecount=1])
 190 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 191
 192 # --with-ssh-login-user=...
 193 AC_ARG_WITH([ssh-login-user],
 194   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 195     [user to use for SSH logins within the cluster (default is root)]
 196   )],
 197   [ssh_login_user="$withval"],
 198   [ssh_login_user=root])
 199 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 200
 201 # --with-ssh-console-user=...
 202 AC_ARG_WITH([ssh-console-user],
 203   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 204     [user to use for SSH logins to access instance consoles (default is root)]
 205   )],
 206   [ssh_console_user="$withval"],
 207   [ssh_console_user=root])
 208 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 209
 210 # --with-default-user=...
 211 AC_ARG_WITH([default-user],
 212   [AS_HELP_STRING([--with-default-user=USERNAME],
 213     [default user for daemons]
 214     [ (default is to run all daemons as root)]
 215   )],
 216   [user_default="$withval"],
 217   [user_default=root])
 218
 219 # --with-default-group=...
 220 AC_ARG_WITH([default-group],
 221   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 222     [default group for daemons]
 223     [ (default is to run all daemons under group root)]
 224   )],
 225   [group_default="$withval"],
 226   [group_default=root])
 227
 228 # --with-user-prefix=...
 229 AC_ARG_WITH([user-prefix],
 230   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 231     [prefix for daemon users]
 232     [ (default is to run all daemons as root; use --with-default-user]
 233     [ to change the default)]
 234   )],
 235   [user_masterd="${withval}masterd";
 236    user_rapi="${withval}rapi";
 237    user_confd="${withval}confd";
 238    user_luxid="${withval}luxid";
 239    user_noded="$user_default";
 240    user_mond="$user_default"],
 241   [user_masterd="$user_default";
 242    user_rapi="$user_default";
 243    user_confd="$user_default";
 244    user_luxid="$user_default";
 245    user_noded="$user_default";
 246    user_mond="$user_default"])
 247 AC_SUBST(MASTERD_USER, $user_masterd)
 248 AC_SUBST(RAPI_USER, $user_rapi)
 249 AC_SUBST(CONFD_USER, $user_confd)
 250 AC_SUBST(LUXID_USER, $user_luxid)
 251 AC_SUBST(NODED_USER, $user_noded)
 252 AC_SUBST(MOND_USER, $user_mond)
 253
 254 # --with-group-prefix=...
 255 AC_ARG_WITH([group-prefix],
 256   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 257     [prefix for daemon POSIX groups]
 258     [ (default is to run all daemons under group root; use]
 259     [ --with-default-group to change the default)]
 260   )],
 261   [group_rapi="${withval}rapi";
 262    group_admin="${withval}admin";
 263    group_confd="${withval}confd";
 264    group_luxid="${withval}luxid";
 265    group_masterd="${withval}masterd";
 266    group_noded="$group_default";
 267    group_daemons="${withval}daemons";
 268    group_mond="$group_default"],
 269   [group_rapi="$group_default";
 270    group_admin="$group_default";
 271    group_confd="$group_default";
 272    group_luxid="$group_default";
 273    group_masterd="$group_default";
 274    group_noded="$group_default";
 275    group_daemons="$group_default";
 276    group_mond="$group_default"])
 277 AC_SUBST(RAPI_GROUP, $group_rapi)
 278 AC_SUBST(ADMIN_GROUP, $group_admin)
 279 AC_SUBST(CONFD_GROUP, $group_confd)
 280 AC_SUBST(LUXID_GROUP, $group_luxid)
 281 AC_SUBST(MASTERD_GROUP, $group_masterd)
 282 AC_SUBST(NODED_GROUP, $group_noded)
 283 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 284 AC_SUBST(MOND_GROUP, $group_mond)
 285
 286 # Print the config to the user
 287 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 288 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 289 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 290 AC_MSG_NOTICE([Running ganeti-luxid as $user_luxid:$group_luxid])
 291 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 292 AC_MSG_NOTICE([Group for clients is $group_admin])
 293
 294 # --enable-drbd-barriers
 295 AC_ARG_ENABLE([drbd-barriers],
 296   [AS_HELP_STRING([--enable-drbd-barriers],
 297                   m4_normalize([enable the DRBD barriers functionality by
 298                                 default (>= 8.0.12) (default: enabled)]))],
 299   [[if test "$enableval" != no; then
 300       DRBD_BARRIERS=n
 301       DRBD_NO_META_FLUSH=False
 302     else
 303       DRBD_BARRIERS=bf
 304       DRBD_NO_META_FLUSH=True
 305     fi
 306   ]],
 307   [DRBD_BARRIERS=n
 308    DRBD_NO_META_FLUSH=False
 309   ])
 310 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 311 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 312
 313 # --enable-syslog[=no/yes/only]
 314 AC_ARG_ENABLE([syslog],
 315   [AS_HELP_STRING([--enable-syslog],
 316     [enable use of syslog (default: disabled), one of no/yes/only])],
 317   [[case "$enableval" in
 318       no)
 319         SYSLOG=no
 320         ;;
 321       yes)
 322         SYSLOG=yes
 323         ;;
 324       only)
 325         SYSLOG=only
 326         ;;
 327       *)
 328         SYSLOG=
 329         ;;
 330     esac
 331   ]],
 332   [SYSLOG=no])
 333
 334 if test -z "$SYSLOG"
 335 then
 336   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 337 fi
 338 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 339
 340 # --enable-restricted-commands[=no/yes]
 341 AC_ARG_ENABLE([restricted-commands],
 342   [AS_HELP_STRING([--enable-restricted-commands],
 343                   m4_normalize([enable restricted commands in the node daemon
 344                                 (default: disabled)]))],
 345   [[if test "$enableval" = no; then
 346       enable_restricted_commands=False
 347     else
 348       enable_restricted_commands=True
 349     fi
 350   ]],
 351   [enable_restricted_commands=False])
 352 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 353
 354 # --with-disk-separator=...
 355 AC_ARG_WITH([disk-separator],
 356   [AS_HELP_STRING([--with-disk-separator=STRING],
 357     [Disk index separator, useful if the default of ':' is handled]
 358     [ specially by the hypervisor]
 359   )],
 360   [disk_separator="$withval"],
 361   [disk_separator=":"])
 362 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 363
 364 # Check common programs
 365 AC_PROG_INSTALL
 366 AC_PROG_LN_S
 367
 368 # Check for the ip command
 369 AC_ARG_VAR(IP_PATH, [ip path])
 370 AC_PATH_PROG(IP_PATH, [ip], [])
 371 if test -z "$IP_PATH"
 372 then
 373   AC_MSG_ERROR([ip command not found])
 374 fi
 375
 376 # Check for pandoc
 377 AC_ARG_VAR(PANDOC, [pandoc path])
 378 AC_PATH_PROG(PANDOC, [pandoc], [])
 379 if test -z "$PANDOC"
 380 then
 381   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 382 fi
 383
 384 # Check for python-sphinx
 385 AC_ARG_VAR(SPHINX, [sphinx-build path])
 386 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 387 if test -z "$SPHINX"
 388 then
 389   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 390                             not be possible]))
 391 else
 392   # Sphinx exits with code 1 when it prints its usage
 393   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
 394
 395   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
 396     AC_MSG_ERROR([Unable to determine Sphinx version])
 397
 398   # Note: Character classes ([...]) need to be double quoted due to autoconf
 399   # using m4
 400   elif ! echo "$sphinxver" | grep -q -E '^Sphinx[[[:space:]]]+v[[1-9]]\>'; then
 401     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
 402   fi
 403 fi
 404 AM_CONDITIONAL([HAS_SPHINX], [test -n "$SPHINX"])
 405
 406 AC_ARG_ENABLE([manpages-in-doc],
 407   [AS_HELP_STRING([--enable-manpages-in-doc],
 408                   m4_normalize([include man pages in HTML documentation
 409                                 (requires sphinx; default disabled)]))],
 410   [case "$enableval" in
 411       yes) manpages_in_doc=yes ;;
 412       no) manpages_in_doc= ;;
 413       *)
 414         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 415         ;;
 416     esac
 417   ],
 418   [manpages_in_doc=])
 419 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 420 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 421
 422 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 423   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 424 fi
 425
 426 # Check for graphviz (dot)
 427 AC_ARG_VAR(DOT, [dot path])
 428 AC_PATH_PROG(DOT, [dot], [])
 429 if test -z "$DOT"
 430 then
 431   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 432                             documentation rebuild not possible]))
 433 fi
 434
 435 # Check for pylint
 436 AC_ARG_VAR(PYLINT, [pylint path])
 437 AC_PATH_PROG(PYLINT, [pylint], [])
 438 if test -z "$PYLINT"
 439 then
 440   AC_MSG_WARN([pylint not found, checking code will not be possible])
 441 fi
 442
 443 # Check for pep8
 444 AC_ARG_VAR(PEP8, [pep8 path])
 445 AC_PATH_PROG(PEP8, [pep8], [])
 446 if test -z "$PEP8"
 447 then
 448   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 449 fi
 450 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 451
 452 # Check for python-coverage
 453 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 454 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 455 if test -z "$PYCOVERAGE"
 456 then
 457   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 458                             Python test coverage will not be possible]))
 459 fi
 460
 461 # Check for socat
 462 AC_ARG_VAR(SOCAT, [socat path])
 463 AC_PATH_PROG(SOCAT, [socat], [])
 464 if test -z "$SOCAT"
 465 then
 466   AC_MSG_ERROR([socat not found])
 467 fi
 468
 469 # Check for qemu-img
 470 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 471 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 472 if test -z "$QEMUIMG_PATH"
 473 then
 474   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 475 fi
 476
 477 # --enable-confd
 478 ENABLE_CONFD=
 479 AC_ARG_ENABLE([confd],
 480   [AS_HELP_STRING([--enable-confd],
 481   [enable the ganeti-confd daemon (default: check)])],
 482   [],
 483   [enable_confd=check])
 484
 485 ENABLE_MOND=
 486 AC_ARG_ENABLE([monitoring],
 487   [AS_HELP_STRING([--enable-monitoring],
 488   [enable the ganeti monitoring daemon (default: check)])],
 489   [],
 490   [enable_monitoring=check])
 491
 492 # Check for ghc
 493 AC_ARG_VAR(GHC, [ghc path])
 494 AC_PATH_PROG(GHC, [ghc], [])
 495 if test -z "$GHC"; then
 496   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 497 fi
 498
 499 AC_MSG_CHECKING([checking for extra GHC flags])
 500 GHC_BYVERSION_FLAGS=
 501 # check for GHC supported flags that vary accross versions
 502 for flag in -fwarn-incomplete-uni-patterns; do
 503   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 504    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 505   fi
 506 done
 507 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 508 AC_SUBST(GHC_BYVERSION_FLAGS)
 509
 510 # Check for ghc-pkg
 511 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 512 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 513 if test -z "$GHC_PKG"; then
 514   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 515 fi
 516
 517 # check for modules, first custom/special checks
 518 AC_MSG_NOTICE([checking for required haskell modules])
 519 HS_PARALLEL3=
 520 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 521                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 522 AC_SUBST(HS_PARALLEL3)
 523
 524 # and now standard modules
 525 AC_GHC_PKG_REQUIRE(curl)
 526 AC_GHC_PKG_REQUIRE(json)
 527 AC_GHC_PKG_REQUIRE(network)
 528 AC_GHC_PKG_REQUIRE(mtl)
 529 AC_GHC_PKG_REQUIRE(bytestring)
 530 AC_GHC_PKG_REQUIRE(utf8-string)
 531 AC_GHC_PKG_REQUIRE(hslogger)
 532
 533 # extra modules for confd functionality
 534 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 535 has_confd=False
 536 if test "$enable_confd" != no; then
 537   CONFD_PKG=
 538   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 539                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 540   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 541   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 542   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 543   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 544   if test -z "$CONFD_PKG"; then
 545     has_confd=True
 546   elif test "$enable_confd" = check; then
 547     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 548                               not found ($CONFD_PKG), confd disabled]))
 549   else
 550     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 551                                  required libraries were not found:
 552                                  $CONFD_PKG]))
 553   fi
 554 fi
 555 AC_SUBST(HS_REGEX_PCRE)
 556 if test "$has_confd" = True; then
 557   AC_MSG_NOTICE([Enabling confd usage])
 558 fi
 559 AC_SUBST(ENABLE_CONFD, $has_confd)
 560 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 561
 562 #extra modules for monitoring daemon functionality
 563 has_monitoring=False
 564 if test "$enable_monitoring" != no; then
 565   MONITORING_PKG=
 566   AC_GHC_PKG_CHECK([attoparsec], [],
 567                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 568   AC_GHC_PKG_CHECK([snap-server], [],
 569                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
 570   AC_GHC_PKG_CHECK([process], [],
 571                    [MONITORING_PKG="$MONITORING_PKG process"])
 572   MONITORING_DEP=
 573   if test "$has_confd" = False; then
 574     MONITORING_DEP="$MONITORING_DEP confd"
 575   fi
 576   has_monitoring_pkg=False
 577   if test -z "$MONITORING_PKG"; then
 578     has_monitoring_pkg=True
 579   elif test "$enable_monitoring" = check; then
 580     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 581                               daemon were not found ($MONITORING_PKG),
 582                               monitoring disabled]))
 583   else
 584     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 585                                  required libraries were not found:
 586                                  $MONITORING_PKG]))
 587   fi
 588   has_monitoring_dep=False
 589   if test -z "$MONITORING_DEP"; then
 590     has_monitoring_dep=True
 591   elif test "$enable_monitoring" = check; then
 592     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
 593                               monitoring agent were not enabled
 594                               ($MONITORING_DEP), monitoring disabled]))
 595   else
 596     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 597                                  required optional Ganeti components were not
 598                                  found: $MONITORING_DEP]))
 599   fi
 600
 601 fi
 602 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
 603   has_monitoring=True
 604   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 605 fi
 606 AC_SUBST(ENABLE_MOND, $has_monitoring)
 607 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
 608
 609 # development modules
 610 HS_NODEV=
 611 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 612 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 613 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 614 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 615 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 616 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 617 #        that are needed to execute the tests, avoiding the duplication
 618 #        of the checks.
 619 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 620 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 621 AC_GHC_PKG_CHECK([process], [],
 622                  [MONITORING_PKG="$MONITORING_PKG process"])
 623 if test -n "$HS_NODEV"; then
 624    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 625                              you won't be able to run Haskell unittests]))
 626 else
 627    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 628 fi
 629 AC_SUBST(HS_NODEV)
 630
 631 HTOOLS=yes
 632 AC_SUBST(HTOOLS)
 633
 634 # --enable-split-query
 635 ENABLE_SPLIT_QUERY=
 636 AC_ARG_ENABLE([split-query],
 637   [AS_HELP_STRING([--enable-split-query],
 638   [enable use of custom query daemon via confd])],
 639   [[case "$enableval" in
 640       no)
 641         enable_split_query=False
 642         ;;
 643       yes)
 644         enable_split_query=True
 645         ;;
 646       *)
 647         echo "Invalid value for enable-confd '$enableval'"
 648         exit 1
 649         ;;
 650     esac
 651   ]],
 652   [[case "x${has_confd}x" in
 653      xTruex)
 654        enable_split_query=True
 655        ;;
 656      *)
 657        enable_split_query=False
 658        ;;
 659    esac]])
 660 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 661
 662 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 663   AC_MSG_ERROR([Split queries require the confd daemon])
 664 fi
 665
 666 if test x$enable_split_query = xTrue; then
 667   AC_MSG_NOTICE([Split query functionality enabled])
 668 fi
 669
 670 # Check for HsColour
 671 HS_APIDOC=no
 672 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 673 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 674 if test -z "$HSCOLOUR"; then
 675   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 676                             not be generated]))
 677 fi
 678
 679 # Check for haddock
 680 AC_ARG_VAR(HADDOCK, [haddock path])
 681 AC_PATH_PROG(HADDOCK, [haddock], [])
 682 if test -z "$HADDOCK"; then
 683   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 684                             not be generated]))
 685 fi
 686 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 687   HS_APIDOC=yes
 688 fi
 689 AC_SUBST(HS_APIDOC)
 690
 691 # Check for hlint
 692 AC_ARG_VAR(HLINT, [hlint path])
 693 AC_PATH_PROG(HLINT, [hlint], [])
 694 if test -z "$HLINT"; then
 695   AC_MSG_WARN([hlint not found, checking code will not be possible])
 696 fi
 697
 698 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 699   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 700                              htools support is not enabled]))
 701 fi
 702
 703 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 704 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 705 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 706 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 707
 708 # Check for fakeroot
 709 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 710 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 711 if test -z "$FAKEROOT_PATH"; then
 712   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 713                             will not be executed]))
 714 fi
 715 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 716
 717 SOCAT_USE_ESCAPE=
 718 AC_ARG_ENABLE([socat-escape],
 719   [AS_HELP_STRING([--enable-socat-escape],
 720     [use escape functionality available in socat >= 1.7 (default: detect
 721      automatically)])],
 722   [[if test "$enableval" = yes; then
 723       SOCAT_USE_ESCAPE=True
 724     else
 725       SOCAT_USE_ESCAPE=False
 726     fi
 727   ]])
 728
 729 if test -z "$SOCAT_USE_ESCAPE"
 730 then
 731   if $SOCAT -hh | grep -w -q escape; then
 732     SOCAT_USE_ESCAPE=True
 733   else
 734     SOCAT_USE_ESCAPE=False
 735   fi
 736 fi
 737
 738 AC_SUBST(SOCAT_USE_ESCAPE)
 739
 740 SOCAT_USE_COMPRESS=
 741 AC_ARG_ENABLE([socat-compress],
 742   [AS_HELP_STRING([--enable-socat-compress],
 743     [use OpenSSL compression option available in patched socat builds
 744      (see INSTALL for details; default: detect automatically)])],
 745   [[if test "$enableval" = yes; then
 746       SOCAT_USE_COMPRESS=True
 747     else
 748       SOCAT_USE_COMPRESS=False
 749     fi
 750   ]])
 751
 752 if test -z "$SOCAT_USE_COMPRESS"
 753 then
 754   if $SOCAT -hhh | grep -w -q openssl-compress; then
 755     SOCAT_USE_COMPRESS=True
 756   else
 757     SOCAT_USE_COMPRESS=False
 758   fi
 759 fi
 760
 761 AC_SUBST(SOCAT_USE_COMPRESS)
 762
 763 if man --help | grep -q -e --warnings
 764 then
 765   MAN_HAS_WARNINGS=1
 766 else
 767   MAN_HAS_WARNINGS=
 768   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 769                             will not be possible]))
 770 fi
 771
 772 AC_SUBST(MAN_HAS_WARNINGS)
 773
 774 # Check for Python
 775 AM_PATH_PYTHON(2.6)
 776
 777 AC_PYTHON_MODULE(OpenSSL, t)
 778 AC_PYTHON_MODULE(simplejson, t)
 779 AC_PYTHON_MODULE(pyparsing, t)
 780 AC_PYTHON_MODULE(pyinotify, t)
 781 AC_PYTHON_MODULE(pycurl, t)
 782 AC_PYTHON_MODULE(bitarray, t)
 783 AC_PYTHON_MODULE(ipaddr, t)
 784 AC_PYTHON_MODULE(mock)
 785 AC_PYTHON_MODULE(affinity)
 786 AC_PYTHON_MODULE(paramiko)
 787
 788 # Development-only Python modules
 789 PY_NODEV=
 790 AC_PYTHON_MODULE(yaml)
 791 if test $HAVE_PYMOD_YAML == "no"; then
 792   PY_NODEV="$PY_NODEV yaml"
 793 fi
 794
 795 if test -n "$PY_NODEV"; then
 796   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
 797                             found, you won't be able to run Python unittests]))
 798 else
 799   AC_MSG_NOTICE([Python development modules found, unittests enabled])
 800 fi
 801 AC_SUBST(PY_NODEV)
 802 AM_CONDITIONAL([PY_UNIT], [test -n $PY_NODEV])
 803
 804 AC_CONFIG_FILES([ Makefile ])
 805
 806 AC_OUTPUT