code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [9])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~alpha1])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-xen-config-dir=...
  53 AC_ARG_WITH([xen-config-dir],
  54   [AS_HELP_STRING([--with-xen-config-dir=DIR],
  55                   m4_normalize([Xen configuration directory
  56                                 (default: /etc/xen)]))],
  57   [xen_config_dir="$withval"],
  58   [xen_config_dir=/etc/xen])
  59 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
  60
  61 # --with-os-search-path=...
  62 # do a bit of black sed magic to for quoting of the strings in the list
  63 AC_ARG_WITH([os-search-path],
  64   [AS_HELP_STRING([--with-os-search-path=LIST],
  65     [comma separated list of directories to]
  66     [ search for OS images (default is /srv/ganeti/os)]
  67   )],
  68   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  69   [os_search_path="'/srv/ganeti/os'"])
  70 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  71
  72 # --with-extstorage-search-path=...
  73 # same black sed magic for quoting of the strings in the list
  74 AC_ARG_WITH([extstorage-search-path],
  75   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  76     [comma separated list of directories to]
  77     [ search for External Storage Providers]
  78     [ (default is /srv/ganeti/extstorage)]
  79   )],
  80   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  81   [es_search_path="'/srv/ganeti/extstorage'"])
  82 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  83
  84 # --with-iallocator-search-path=...
  85 # do a bit of black sed magic to for quoting of the strings in the list
  86 AC_ARG_WITH([iallocator-search-path],
  87   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  88     [comma separated list of directories to]
  89     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  90   )],
  91   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  92   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  93 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  94
  95 # --with-xen-bootloader=...
  96 AC_ARG_WITH([xen-bootloader],
  97   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  98     [bootloader for Xen hypervisor (default is empty)]
  99   )],
 100   [xen_bootloader="$withval"],
 101   [xen_bootloader=])
 102 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
 103
 104 # --with-xen-kernel=...
 105 AC_ARG_WITH([xen-kernel],
 106   [AS_HELP_STRING([--with-xen-kernel=PATH],
 107     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
 108   )],
 109   [xen_kernel="$withval"],
 110   [xen_kernel="/boot/vmlinuz-3-xenU"])
 111 AC_SUBST(XEN_KERNEL, $xen_kernel)
 112
 113 # --with-xen-initrd=...
 114 AC_ARG_WITH([xen-initrd],
 115   [AS_HELP_STRING([--with-xen-initrd=PATH],
 116     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 117   )],
 118   [xen_initrd="$withval"],
 119   [xen_initrd="/boot/initrd-3-xenU"])
 120 AC_SUBST(XEN_INITRD, $xen_initrd)
 121
 122 # --with-kvm-kernel=...
 123 AC_ARG_WITH([kvm-kernel],
 124   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 125     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 126   )],
 127   [kvm_kernel="$withval"],
 128   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 129 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 130
 131 # --with-shared-file-storage-dir=...
 132 AC_ARG_WITH([shared-file-storage-dir],
 133   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 134     [directory to store files for shared file-based backend]
 135     [ (default is /srv/ganeti/shared-file-storage)]
 136   )],
 137   [[shared_file_storage_dir="$withval";
 138     if test "$withval" != no; then
 139       enable_shared_file_storage=True
 140     else
 141       enable_shared_file_storage=False
 142     fi
 143   ]],
 144   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 145     enable_shared_file_storage=True]])
 146 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 147 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 148
 149 # --with-kvm-path=...
 150 AC_ARG_WITH([kvm-path],
 151   [AS_HELP_STRING([--with-kvm-path=PATH],
 152     [absolute path to the kvm binary]
 153     [ (default is /usr/bin/kvm)]
 154   )],
 155   [kvm_path="$withval"],
 156   [kvm_path="/usr/bin/kvm"])
 157 AC_SUBST(KVM_PATH, $kvm_path)
 158
 159 # --with-lvm-stripecount=...
 160 AC_ARG_WITH([lvm-stripecount],
 161   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 162     [the default number of stripes to use for LVM volumes]
 163     [ (default is 1)]
 164   )],
 165   [lvm_stripecount="$withval"],
 166   [lvm_stripecount=1])
 167 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 168
 169 # --with-ssh-login-user=...
 170 AC_ARG_WITH([ssh-login-user],
 171   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 172     [user to use for SSH logins within the cluster (default is root)]
 173   )],
 174   [ssh_login_user="$withval"],
 175   [ssh_login_user=root])
 176 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 177
 178 # --with-ssh-console-user=...
 179 AC_ARG_WITH([ssh-console-user],
 180   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 181     [user to use for SSH logins to access instance consoles (default is root)]
 182   )],
 183   [ssh_console_user="$withval"],
 184   [ssh_console_user=root])
 185 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 186
 187 # --with-default-user=...
 188 AC_ARG_WITH([default-user],
 189   [AS_HELP_STRING([--with-default-user=USERNAME],
 190     [default user for daemons]
 191     [ (default is to run all daemons as root)]
 192   )],
 193   [user_default="$withval"],
 194   [user_default=root])
 195
 196 # --with-default-group=...
 197 AC_ARG_WITH([default-group],
 198   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 199     [default group for daemons]
 200     [ (default is to run all daemons under group root)]
 201   )],
 202   [group_default="$withval"],
 203   [group_default=root])
 204
 205 # --with-user-prefix=...
 206 AC_ARG_WITH([user-prefix],
 207   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 208     [prefix for daemon users]
 209     [ (default is to run all daemons as root; use --with-default-user]
 210     [ to change the default)]
 211   )],
 212   [user_masterd="${withval}masterd";
 213    user_rapi="${withval}rapi";
 214    user_confd="${withval}confd";
 215    user_luxid="${withval}luxid";
 216    user_noded="$user_default";
 217    user_mond="$user_default"],
 218   [user_masterd="$user_default";
 219    user_rapi="$user_default";
 220    user_confd="$user_default";
 221    user_luxid="$user_default";
 222    user_noded="$user_default";
 223    user_mond="$user_default"])
 224 AC_SUBST(MASTERD_USER, $user_masterd)
 225 AC_SUBST(RAPI_USER, $user_rapi)
 226 AC_SUBST(CONFD_USER, $user_confd)
 227 AC_SUBST(LUXID_USER, $user_luxid)
 228 AC_SUBST(NODED_USER, $user_noded)
 229 AC_SUBST(MOND_USER, $user_mond)
 230
 231 # --with-group-prefix=...
 232 AC_ARG_WITH([group-prefix],
 233   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 234     [prefix for daemon POSIX groups]
 235     [ (default is to run all daemons under group root; use]
 236     [ --with-default-group to change the default)]
 237   )],
 238   [group_rapi="${withval}rapi";
 239    group_admin="${withval}admin";
 240    group_confd="${withval}confd";
 241    group_luxid="${withval}luxid";
 242    group_masterd="${withval}masterd";
 243    group_noded="$group_default";
 244    group_daemons="${withval}daemons";
 245    group_mond="$group_default"],
 246   [group_rapi="$group_default";
 247    group_admin="$group_default";
 248    group_confd="$group_default";
 249    group_luxid="$group_default";
 250    group_masterd="$group_default";
 251    group_noded="$group_default";
 252    group_daemons="$group_default";
 253    group_mond="$group_default"])
 254 AC_SUBST(RAPI_GROUP, $group_rapi)
 255 AC_SUBST(ADMIN_GROUP, $group_admin)
 256 AC_SUBST(CONFD_GROUP, $group_confd)
 257 AC_SUBST(LUXID_GROUP, $group_luxid)
 258 AC_SUBST(MASTERD_GROUP, $group_masterd)
 259 AC_SUBST(NODED_GROUP, $group_noded)
 260 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 261 AC_SUBST(MOND_GROUP, $group_mond)
 262
 263 # Print the config to the user
 264 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 265 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 266 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 267 AC_MSG_NOTICE([Running ganeti-luxid as $user_luxid:$group_luxid])
 268 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 269 AC_MSG_NOTICE([Group for clients is $group_admin])
 270
 271 # --enable-drbd-barriers
 272 AC_ARG_ENABLE([drbd-barriers],
 273   [AS_HELP_STRING([--enable-drbd-barriers],
 274                   m4_normalize([enable the DRBD barriers functionality by
 275                                 default (>= 8.0.12) (default: enabled)]))],
 276   [[if test "$enableval" != no; then
 277       DRBD_BARRIERS=n
 278       DRBD_NO_META_FLUSH=False
 279     else
 280       DRBD_BARRIERS=bf
 281       DRBD_NO_META_FLUSH=True
 282     fi
 283   ]],
 284   [DRBD_BARRIERS=n
 285    DRBD_NO_META_FLUSH=False
 286   ])
 287 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 288 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 289
 290 # --enable-syslog[=no/yes/only]
 291 AC_ARG_ENABLE([syslog],
 292   [AS_HELP_STRING([--enable-syslog],
 293     [enable use of syslog (default: disabled), one of no/yes/only])],
 294   [[case "$enableval" in
 295       no)
 296         SYSLOG=no
 297         ;;
 298       yes)
 299         SYSLOG=yes
 300         ;;
 301       only)
 302         SYSLOG=only
 303         ;;
 304       *)
 305         SYSLOG=
 306         ;;
 307     esac
 308   ]],
 309   [SYSLOG=no])
 310
 311 if test -z "$SYSLOG"
 312 then
 313   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 314 fi
 315 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 316
 317 AC_ARG_ENABLE([restricted-commands],
 318   [AS_HELP_STRING([--enable-restricted-commands],
 319                   m4_normalize([enable restricted commands in the node daemon
 320                                 (default: disabled)]))],
 321   [[if test "$enableval" = no; then
 322       enable_restricted_commands=False
 323     else
 324       enable_restricted_commands=True
 325     fi
 326   ]],
 327   [enable_restricted_commands=False])
 328 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 329
 330 # --with-disk-separator=...
 331 AC_ARG_WITH([disk-separator],
 332   [AS_HELP_STRING([--with-disk-separator=STRING],
 333     [Disk index separator, useful if the default of ':' is handled]
 334     [ specially by the hypervisor]
 335   )],
 336   [disk_separator="$withval"],
 337   [disk_separator=":"])
 338 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 339
 340 # Check common programs
 341 AC_PROG_INSTALL
 342 AC_PROG_LN_S
 343
 344 # Check for the ip command
 345 AC_ARG_VAR(IP_PATH, [ip path])
 346 AC_PATH_PROG(IP_PATH, [ip], [])
 347 if test -z "$IP_PATH"
 348 then
 349   AC_MSG_ERROR([ip command not found])
 350 fi
 351
 352 # Check for pandoc
 353 AC_ARG_VAR(PANDOC, [pandoc path])
 354 AC_PATH_PROG(PANDOC, [pandoc], [])
 355 if test -z "$PANDOC"
 356 then
 357   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 358 fi
 359
 360 # Check for python-sphinx
 361 AC_ARG_VAR(SPHINX, [sphinx-build path])
 362 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 363 if test -z "$SPHINX"
 364 then
 365   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 366                             not be possible]))
 367 else
 368   # Sphinx exits with code 1 when it prints its usage
 369   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
 370
 371   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
 372     AC_MSG_ERROR([Unable to determine Sphinx version])
 373
 374   # Note: Character classes ([...]) need to be double quoted due to autoconf
 375   # using m4
 376   elif ! echo "$sphinxver" | grep -q -E '^Sphinx[[[:space:]]]+v[[1-9]]\>'; then
 377     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
 378   fi
 379 fi
 380
 381 AC_ARG_ENABLE([manpages-in-doc],
 382   [AS_HELP_STRING([--enable-manpages-in-doc],
 383                   m4_normalize([include man pages in HTML documentation
 384                                 (requires sphinx; default disabled)]))],
 385   [case "$enableval" in
 386       yes) manpages_in_doc=yes ;;
 387       no) manpages_in_doc= ;;
 388       *)
 389         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 390         ;;
 391     esac
 392   ],
 393   [manpages_in_doc=])
 394 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 395 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 396
 397 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 398   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 399 fi
 400
 401 # Check for graphviz (dot)
 402 AC_ARG_VAR(DOT, [dot path])
 403 AC_PATH_PROG(DOT, [dot], [])
 404 if test -z "$DOT"
 405 then
 406   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 407                             documentation rebuild not possible]))
 408 fi
 409
 410 # Check for pylint
 411 AC_ARG_VAR(PYLINT, [pylint path])
 412 AC_PATH_PROG(PYLINT, [pylint], [])
 413 if test -z "$PYLINT"
 414 then
 415   AC_MSG_WARN([pylint not found, checking code will not be possible])
 416 fi
 417
 418 # Check for pep8
 419 AC_ARG_VAR(PEP8, [pep8 path])
 420 AC_PATH_PROG(PEP8, [pep8], [])
 421 if test -z "$PEP8"
 422 then
 423   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 424 fi
 425 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 426
 427 # Check for python-coverage
 428 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 429 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 430 if test -z "$PYCOVERAGE"
 431 then
 432   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 433                             Python test coverage will not be possible]))
 434 fi
 435
 436 # Check for socat
 437 AC_ARG_VAR(SOCAT, [socat path])
 438 AC_PATH_PROG(SOCAT, [socat], [])
 439 if test -z "$SOCAT"
 440 then
 441   AC_MSG_ERROR([socat not found])
 442 fi
 443
 444 # Check for qemu-img
 445 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 446 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 447 if test -z "$QEMUIMG_PATH"
 448 then
 449   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 450 fi
 451
 452 # --enable-confd
 453 ENABLE_CONFD=
 454 AC_ARG_ENABLE([confd],
 455   [AS_HELP_STRING([--enable-confd],
 456   [enable the ganeti-confd daemon (default: check)])],
 457   [],
 458   [enable_confd=check])
 459
 460 ENABLE_MOND=
 461 AC_ARG_ENABLE([monitoring],
 462   [AS_HELP_STRING([--enable-monitoring],
 463   [enable the ganeti monitoring daemon (default: check)])],
 464   [],
 465   [enable_monitoring=check])
 466
 467 # Check for ghc
 468 AC_ARG_VAR(GHC, [ghc path])
 469 AC_PATH_PROG(GHC, [ghc], [])
 470 if test -z "$GHC"; then
 471   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 472 fi
 473
 474 AC_MSG_CHECKING([checking for extra GHC flags])
 475 GHC_BYVERSION_FLAGS=
 476 # check for GHC supported flags that vary accross versions
 477 for flag in -fwarn-incomplete-uni-patterns; do
 478   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 479    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 480   fi
 481 done
 482 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 483 AC_SUBST(GHC_BYVERSION_FLAGS)
 484
 485 # Check for ghc-pkg
 486 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 487 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 488 if test -z "$GHC_PKG"; then
 489   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 490 fi
 491
 492 # check for modules, first custom/special checks
 493 AC_MSG_NOTICE([checking for required haskell modules])
 494 HS_PARALLEL3=
 495 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 496                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 497 AC_SUBST(HS_PARALLEL3)
 498
 499 # and now standard modules
 500 AC_GHC_PKG_REQUIRE(curl)
 501 AC_GHC_PKG_REQUIRE(json)
 502 AC_GHC_PKG_REQUIRE(network)
 503 AC_GHC_PKG_REQUIRE(mtl)
 504 AC_GHC_PKG_REQUIRE(bytestring)
 505 AC_GHC_PKG_REQUIRE(utf8-string)
 506
 507 # extra modules for confd functionality
 508 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 509 has_confd=False
 510 if test "$enable_confd" != no; then
 511   CONFD_PKG=
 512   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 513                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 514   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 515   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 516   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 517   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 518   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 519   if test -z "$CONFD_PKG"; then
 520     has_confd=True
 521   elif test "$enable_confd" = check; then
 522     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 523                               not found ($CONFD_PKG), confd disabled]))
 524   else
 525     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 526                                  required libraries were not found:
 527                                  $CONFD_PKG]))
 528   fi
 529 fi
 530 AC_SUBST(HS_REGEX_PCRE)
 531 if test "$has_confd" = True; then
 532   AC_MSG_NOTICE([Enabling confd usage])
 533 fi
 534 AC_SUBST(ENABLE_CONFD, $has_confd)
 535 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 536
 537 #extra modules for monitoring daemon functionality
 538 has_monitoring=False
 539 if test "$enable_monitoring" != no; then
 540   MONITORING_PKG=
 541   AC_GHC_PKG_CHECK([attoparsec], [],
 542                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 543   AC_GHC_PKG_CHECK([snap-server], [],
 544                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
 545   AC_GHC_PKG_CHECK([process], [],
 546                    [MONITORING_PKG="$MONITORING_PKG process"])
 547   MONITORING_DEP=
 548   if test "$has_confd" = False; then
 549     MONITORING_DEP="$MONITORING_DEP confd"
 550   fi
 551   has_monitoring_pkg=False
 552   if test -z "$MONITORING_PKG"; then
 553     has_monitoring_pkg=True
 554   elif test "$enable_monitoring" = check; then
 555     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 556                               daemon were not found ($MONITORING_PKG),
 557                               monitoring disabled]))
 558   else
 559     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 560                                  required libraries were not found:
 561                                  $MONITORING_PKG]))
 562   fi
 563   has_monitoring_dep=False
 564   if test -z "$MONITORING_DEP"; then
 565     has_monitoring_dep=True
 566   elif test "$enable_monitoring" = check; then
 567     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
 568                               monitoring agent were not enabled
 569                               ($MONITORING_DEP), monitoring disabled]))
 570   else
 571     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 572                                  required optional Ganeti components were not
 573                                  found: $MONITORING_DEP]))
 574   fi
 575
 576 fi
 577 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
 578   has_monitoring=True
 579   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 580 fi
 581 AC_SUBST(ENABLE_MOND, $has_monitoring)
 582 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
 583
 584 # development modules
 585 HS_NODEV=
 586 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 587 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 588 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 589 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 590 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 591 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 592 #        that are needed to execute the tests, avoiding the duplication
 593 #        of the checks.
 594 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 595 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 596 AC_GHC_PKG_CHECK([process], [],
 597                  [MONITORING_PKG="$MONITORING_PKG process"])
 598 if test -n "$HS_NODEV"; then
 599    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 600                              you won't be able to run Haskell unittests]))
 601 else
 602    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 603 fi
 604 AC_SUBST(HS_NODEV)
 605
 606 HTOOLS=yes
 607 AC_SUBST(HTOOLS)
 608
 609 # --enable-split-query
 610 ENABLE_SPLIT_QUERY=
 611 AC_ARG_ENABLE([split-query],
 612   [AS_HELP_STRING([--enable-split-query],
 613   [enable use of custom query daemon via confd])],
 614   [[case "$enableval" in
 615       no)
 616         enable_split_query=False
 617         ;;
 618       yes)
 619         enable_split_query=True
 620         ;;
 621       *)
 622         echo "Invalid value for enable-confd '$enableval'"
 623         exit 1
 624         ;;
 625     esac
 626   ]],
 627   [[case "x${has_confd}x" in
 628      xTruex)
 629        enable_split_query=True
 630        ;;
 631      *)
 632        enable_split_query=False
 633        ;;
 634    esac]])
 635 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 636
 637 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 638   AC_MSG_ERROR([Split queries require the confd daemon])
 639 fi
 640
 641 if test x$enable_split_query = xTrue; then
 642   AC_MSG_NOTICE([Split query functionality enabled])
 643 fi
 644
 645 # Check for HsColour
 646 HS_APIDOC=no
 647 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 648 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 649 if test -z "$HSCOLOUR"; then
 650   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 651                             not be generated]))
 652 fi
 653
 654 # Check for haddock
 655 AC_ARG_VAR(HADDOCK, [haddock path])
 656 AC_PATH_PROG(HADDOCK, [haddock], [])
 657 if test -z "$HADDOCK"; then
 658   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 659                             not be generated]))
 660 fi
 661 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 662   HS_APIDOC=yes
 663 fi
 664 AC_SUBST(HS_APIDOC)
 665
 666 # Check for hlint
 667 AC_ARG_VAR(HLINT, [hlint path])
 668 AC_PATH_PROG(HLINT, [hlint], [])
 669 if test -z "$HLINT"; then
 670   AC_MSG_WARN([hlint not found, checking code will not be possible])
 671 fi
 672
 673 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 674   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 675                              htools support is not enabled]))
 676 fi
 677
 678 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 679 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 680 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 681 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 682
 683 # Check for fakeroot
 684 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 685 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 686 if test -z "$FAKEROOT_PATH"; then
 687   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 688                             will not be executed]))
 689 fi
 690 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 691
 692 SOCAT_USE_ESCAPE=
 693 AC_ARG_ENABLE([socat-escape],
 694   [AS_HELP_STRING([--enable-socat-escape],
 695     [use escape functionality available in socat >= 1.7 (default: detect
 696      automatically)])],
 697   [[if test "$enableval" = yes; then
 698       SOCAT_USE_ESCAPE=True
 699     else
 700       SOCAT_USE_ESCAPE=False
 701     fi
 702   ]])
 703
 704 if test -z "$SOCAT_USE_ESCAPE"
 705 then
 706   if $SOCAT -hh | grep -w -q escape; then
 707     SOCAT_USE_ESCAPE=True
 708   else
 709     SOCAT_USE_ESCAPE=False
 710   fi
 711 fi
 712
 713 AC_SUBST(SOCAT_USE_ESCAPE)
 714
 715 SOCAT_USE_COMPRESS=
 716 AC_ARG_ENABLE([socat-compress],
 717   [AS_HELP_STRING([--enable-socat-compress],
 718     [use OpenSSL compression option available in patched socat builds
 719      (see INSTALL for details; default: detect automatically)])],
 720   [[if test "$enableval" = yes; then
 721       SOCAT_USE_COMPRESS=True
 722     else
 723       SOCAT_USE_COMPRESS=False
 724     fi
 725   ]])
 726
 727 if test -z "$SOCAT_USE_COMPRESS"
 728 then
 729   if $SOCAT -hhh | grep -w -q openssl-compress; then
 730     SOCAT_USE_COMPRESS=True
 731   else
 732     SOCAT_USE_COMPRESS=False
 733   fi
 734 fi
 735
 736 AC_SUBST(SOCAT_USE_COMPRESS)
 737
 738 if man --help | grep -q -e --warnings
 739 then
 740   MAN_HAS_WARNINGS=1
 741 else
 742   MAN_HAS_WARNINGS=
 743   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 744                             will not be possible]))
 745 fi
 746
 747 AC_SUBST(MAN_HAS_WARNINGS)
 748
 749 # Check for Python
 750 AM_PATH_PYTHON(2.6)
 751
 752 AC_PYTHON_MODULE(OpenSSL, t)
 753 AC_PYTHON_MODULE(simplejson, t)
 754 AC_PYTHON_MODULE(pyparsing, t)
 755 AC_PYTHON_MODULE(pyinotify, t)
 756 AC_PYTHON_MODULE(pycurl, t)
 757 AC_PYTHON_MODULE(bitarray, t)
 758 AC_PYTHON_MODULE(ipaddr, t)
 759 AC_PYTHON_MODULE(mock)
 760 AC_PYTHON_MODULE(affinity)
 761 AC_PYTHON_MODULE(paramiko)
 762
 763 # Development-only Python modules
 764 PY_NODEV=
 765 AC_PYTHON_MODULE(yaml)
 766 if test $HAVE_PYMOD_YAML == "no"; then
 767   PY_NODEV="$PY_NODEV yaml"
 768 fi
 769
 770 if test -n "$PY_NODEV"; then
 771   AC_MSG_WARN(m4_normalize([Required development modules ($PY_NODEV) were not
 772                             found, you won't be able to run Python unittests]))
 773 else
 774   AC_MSG_NOTICE([Python development modules found, unittests enabled])
 775 fi
 776 AC_SUBST(PY_NODEV)
 777 AM_CONDITIONAL([PY_UNIT], [test -n $PY_NODEV])
 778
 779 AC_CONFIG_FILES([ Makefile ])
 780
 781 AC_OUTPUT