code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [6])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-os-search-path=...
  53 # do a bit of black sed magic to for quoting of the strings in the list
  54 AC_ARG_WITH([os-search-path],
  55   [AS_HELP_STRING([--with-os-search-path=LIST],
  56     [comma separated list of directories to]
  57     [ search for OS images (default is /srv/ganeti/os)]
  58   )],
  59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  60   [os_search_path="'/srv/ganeti/os'"])
  61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  62
  63 # --with-iallocator-search-path=...
  64 # do a bit of black sed magic to for quoting of the strings in the list
  65 AC_ARG_WITH([iallocator-search-path],
  66   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  67     [comma separated list of directories to]
  68     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  69   )],
  70   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  71   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  72 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  73
  74 # --with-xen-bootloader=...
  75 AC_ARG_WITH([xen-bootloader],
  76   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  77     [bootloader for Xen hypervisor (default is empty)]
  78   )],
  79   [xen_bootloader="$withval"],
  80   [xen_bootloader=])
  81 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  82
  83 # --with-xen-kernel=...
  84 AC_ARG_WITH([xen-kernel],
  85   [AS_HELP_STRING([--with-xen-kernel=PATH],
  86     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
  87   )],
  88   [xen_kernel="$withval"],
  89   [xen_kernel="/boot/vmlinuz-3-xenU"])
  90 AC_SUBST(XEN_KERNEL, $xen_kernel)
  91
  92 # --with-xen-initrd=...
  93 AC_ARG_WITH([xen-initrd],
  94   [AS_HELP_STRING([--with-xen-initrd=PATH],
  95     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
  96   )],
  97   [xen_initrd="$withval"],
  98   [xen_initrd="/boot/initrd-3-xenU"])
  99 AC_SUBST(XEN_INITRD, $xen_initrd)
 100
 101 # --with-xen-cmd=...
 102 AC_ARG_WITH([xen-cmd],
 103   [AS_HELP_STRING([--with-xen-cmd=CMD],
 104     [Sets the xen cli interface command (default is xm)]
 105   )],
 106   [xen_cmd="$withval"],
 107   [xen_cmd="xm"])
 108 AC_SUBST(XEN_CMD, $xen_cmd)
 109
 110 if ! test "$XEN_CMD" = xl -o "$XEN_CMD" = xm; then
 111   AC_MSG_ERROR([Unsupported xen command specified])
 112 fi
 113
 114 # --with-kvm-kernel=...
 115 AC_ARG_WITH([kvm-kernel],
 116   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 117     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 118   )],
 119   [kvm_kernel="$withval"],
 120   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 121 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 122
 123 # --with-file-storage-dir=...
 124 AC_ARG_WITH([file-storage-dir],
 125   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 126     [directory to store files for file-based backend]
 127     [ (default is /srv/ganeti/file-storage)]
 128   )],
 129   [[file_storage_dir="$withval";
 130     if test "$withval" != no; then
 131       enable_file_storage=True
 132     else
 133       enable_file_storage=False
 134     fi
 135   ]],
 136   [[file_storage_dir="/srv/ganeti/file-storage";
 137     enable_file_storage="True"]])
 138 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 139 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 140
 141 # --with-shared-file-storage-dir=...
 142 AC_ARG_WITH([shared-file-storage-dir],
 143   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 144     [directory to store files for shared file-based backend]
 145     [ (default is /srv/ganeti/shared-file-storage)]
 146   )],
 147   [[shared_file_storage_dir="$withval";
 148     if test "$withval" != no; then
 149       enable_shared_file_storage=True
 150     else
 151       enable_shared_file_storage=False
 152     fi
 153   ]],
 154   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 155     enable_shared_file_storage="True"]])
 156 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 157 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 158
 159 # --with-kvm-path=...
 160 AC_ARG_WITH([kvm-path],
 161   [AS_HELP_STRING([--with-kvm-path=PATH],
 162     [absolute path to the kvm binary]
 163     [ (default is /usr/bin/kvm)]
 164   )],
 165   [kvm_path="$withval"],
 166   [kvm_path="/usr/bin/kvm"])
 167 AC_SUBST(KVM_PATH, $kvm_path)
 168
 169 # --with-lvm-stripecount=...
 170 AC_ARG_WITH([lvm-stripecount],
 171   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 172     [the default number of stripes to use for LVM volumes]
 173     [ (default is 1)]
 174   )],
 175   [lvm_stripecount="$withval"],
 176   [lvm_stripecount="1"])
 177 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 178
 179 # --with-default-user=...
 180 AC_ARG_WITH([default-user],
 181   [AS_HELP_STRING([--with-default-user=USERNAME],
 182     [default user for daemons]
 183     [ (default is to run all daemons as root)]
 184   )],
 185   [user_default="$withval"],
 186   [user_default=root])
 187
 188 # --with-default-group=...
 189 AC_ARG_WITH([default-group],
 190   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 191     [default group for daemons]
 192     [ (default is to run all daemons under group root)]
 193   )],
 194   [group_default="$withval"],
 195   [group_default=root])
 196
 197 # --with-user-prefix=...
 198 AC_ARG_WITH([user-prefix],
 199   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 200     [prefix for daemon users]
 201     [ (default is to run all daemons as root; use --with-default-user]
 202     [ to change the default)]
 203   )],
 204   [user_masterd="${withval}masterd";
 205    user_rapi="${withval}rapi";
 206    user_confd="${withval}confd";
 207    user_noded="$user_default"],
 208   [user_masterd="$user_default";
 209    user_rapi="$user_default";
 210    user_confd="$user_default";
 211    user_noded="$user_default"])
 212 AC_SUBST(MASTERD_USER, $user_masterd)
 213 AC_SUBST(RAPI_USER, $user_rapi)
 214 AC_SUBST(CONFD_USER, $user_confd)
 215 AC_SUBST(NODED_USER, $user_noded)
 216
 217 # --with-group-prefix=...
 218 AC_ARG_WITH([group-prefix],
 219   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 220     [prefix for daemon POSIX groups]
 221     [ (default is to run all daemons under group root; use]
 222     [ --with-default-group to change the default)]
 223   )],
 224   [group_rapi="${withval}rapi";
 225    group_admin="${withval}admin";
 226    group_confd="${withval}confd";
 227    group_masterd="${withval}masterd";
 228    group_noded="$group_default";
 229    group_daemons="${withval}daemons";],
 230   [group_rapi="$group_default";
 231    group_admin="$group_default";
 232    group_confd="$group_default";
 233    group_masterd="$group_default";
 234    group_noded="$group_default";
 235    group_daemons="$group_default"])
 236 AC_SUBST(RAPI_GROUP, $group_rapi)
 237 AC_SUBST(ADMIN_GROUP, $group_admin)
 238 AC_SUBST(CONFD_GROUP, $group_confd)
 239 AC_SUBST(MASTERD_GROUP, $group_masterd)
 240 AC_SUBST(NODED_GROUP, $group_noded)
 241 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 242
 243 # Print the config to the user
 244 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 245 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 246 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 247 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 248 AC_MSG_NOTICE([Group for clients is $group_admin])
 249
 250 # --enable-drbd-barriers
 251 AC_ARG_ENABLE([drbd-barriers],
 252   [AS_HELP_STRING([--enable-drbd-barriers],
 253     [enable by default the DRBD barriers functionality (>= 8.0.12) (default: enabled)])],
 254   [[if test "$enableval" != no; then
 255       DRBD_BARRIERS=n
 256       DRBD_NO_META_FLUSH=False
 257     else
 258       DRBD_BARRIERS=bf
 259       DRBD_NO_META_FLUSH=True
 260     fi
 261   ]],
 262   [DRBD_BARRIERS=n
 263    DRBD_NO_META_FLUSH=False
 264   ])
 265 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 266 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 267
 268 # --enable-syslog[=no/yes/only]
 269 AC_ARG_ENABLE([syslog],
 270   [AS_HELP_STRING([--enable-syslog],
 271     [enable use of syslog (default: disabled), one of no/yes/only])],
 272   [[case "$enableval" in
 273       no)
 274         SYSLOG=no
 275         ;;
 276       yes)
 277         SYSLOG=yes
 278         ;;
 279       only)
 280         SYSLOG=only
 281         ;;
 282       *)
 283         SYSLOG=
 284         ;;
 285     esac
 286   ]],
 287   [SYSLOG=no])
 288
 289 if test -z "$SYSLOG"
 290 then
 291   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 292 fi
 293 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 294
 295 # --enable-htools
 296 HTOOLS=
 297 AC_ARG_ENABLE([htools],
 298         [AS_HELP_STRING([--enable-htools],
 299         [enable use of htools (needs GHC and libraries, default: check)])],
 300         [],
 301         [enable_htools=check])
 302
 303 # --enable-htools-rapi
 304 HTOOLS_RAPI=
 305 AC_ARG_ENABLE([htools-rapi],
 306         [AS_HELP_STRING([--enable-htools-rapi],
 307         [enable use of RAPI in htools (needs curl, default: no)])],
 308         [],
 309         [enable_htools_rapi=no])
 310
 311 # --enable-confd
 312 ENABLE_CONFD=
 313 AC_ARG_ENABLE([confd],
 314   [AS_HELP_STRING([--enable-confd],
 315   [enable the ganeti-confd daemon (default: python, options haskell/python/no)])],
 316   [[case "$enableval" in
 317       no)
 318         enable_confd=False
 319         py_confd=False
 320         hs_confd=False
 321         ;;
 322       yes|python)
 323         enable_confd=True
 324         py_confd=True
 325         hs_confd=False
 326         ;;
 327       haskell)
 328         enable_confd=True
 329         py_confd=False
 330         hs_confd=True
 331         ;;
 332       *)
 333         echo "Invalid value for enable-confd '$enableval'"
 334         exit 1
 335         ;;
 336     esac
 337   ]],
 338   [enable_confd=True;py_confd=True;hs_confd=False])
 339 AC_SUBST(ENABLE_CONFD, $enable_confd)
 340 AC_SUBST(PY_CONFD, $py_confd)
 341 AC_SUBST(HS_CONFD, $hs_confd)
 342
 343 AM_CONDITIONAL([WANT_CONFD], [test x$enable_confd = xTrue])
 344 AM_CONDITIONAL([PY_CONFD], [test x$py_confd = xTrue])
 345 AM_CONDITIONAL([HS_CONFD], [test x$hs_confd = xTrue])
 346
 347 # --enable-split-query
 348 ENABLE_SPLIT_QUERY=
 349 AC_ARG_ENABLE([split-query],
 350   [AS_HELP_STRING([--enable-split-query],
 351   [enable use of custom query daemon via Haskell confd])],
 352   [[case "$enableval" in
 353       no)
 354         enable_split_query=False
 355         ;;
 356       yes)
 357         enable_split_query=True
 358         ;;
 359       *)
 360         echo "Invalid value for enable-confd '$enableval'"
 361         exit 1
 362         ;;
 363     esac
 364   ]],
 365   [enable_split_query=False])
 366 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 367
 368 if test x$enable_split_query = xTrue -a x$hs_confd != xTrue; then
 369   AC_MSG_ERROR([Split queries require the Haskell confd])
 370 fi
 371
 372 # --with-disk-separator=...
 373 AC_ARG_WITH([disk-separator],
 374   [AS_HELP_STRING([--with-disk-separator=STRING],
 375     [Disk index separator, useful if the default of ':' is handled]
 376     [ specially by the hypervisor]
 377   )],
 378   [disk_separator="$withval"],
 379   [disk_separator=":"])
 380 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 381
 382 # Check common programs
 383 AC_PROG_INSTALL
 384 AC_PROG_LN_S
 385
 386 # Check for the ip command
 387 AC_ARG_VAR(IP_PATH, [ip path])
 388 AC_PATH_PROG(IP_PATH, [ip], [])
 389 if test -z "$IP_PATH"
 390 then
 391   AC_MSG_ERROR([ip command not found])
 392 fi
 393
 394 # Check for pandoc
 395 AC_ARG_VAR(PANDOC, [pandoc path])
 396 AC_PATH_PROG(PANDOC, [pandoc], [])
 397 if test -z "$PANDOC"
 398 then
 399   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 400 fi
 401
 402 # Check for python-sphinx
 403 AC_ARG_VAR(SPHINX, [sphinx-build path])
 404 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 405 if test -z "$SPHINX"
 406 then
 407   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 408                             not be possible]))
 409 fi
 410
 411 # Check for graphviz (dot)
 412 AC_ARG_VAR(DOT, [dot path])
 413 AC_PATH_PROG(DOT, [dot], [])
 414 if test -z "$DOT"
 415 then
 416   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 417                             documentation rebuild not possible]))
 418 fi
 419
 420 # Check for pylint
 421 AC_ARG_VAR(PYLINT, [pylint path])
 422 AC_PATH_PROG(PYLINT, [pylint], [])
 423 if test -z "$PYLINT"
 424 then
 425   AC_MSG_WARN([pylint not found, checking code will not be possible])
 426 fi
 427
 428 # Check for pep8
 429 AC_ARG_VAR(PEP8, [pep8 path])
 430 AC_PATH_PROG(PEP8, [pep8], [])
 431 if test -z "$PEP8"
 432 then
 433   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 434 fi
 435 AM_CONDITIONAL([HAS_PEP8], [test "$PEP8"])
 436
 437 # Check for socat
 438 AC_ARG_VAR(SOCAT, [socat path])
 439 AC_PATH_PROG(SOCAT, [socat], [])
 440 if test -z "$SOCAT"
 441 then
 442   AC_MSG_ERROR([socat not found])
 443 fi
 444
 445 # Check for qemu-img
 446 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 447 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 448 if test -z "$QEMUIMG_PATH"
 449 then
 450   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 451 fi
 452
 453 if test "$enable_htools" != "no"; then
 454
 455 # Check for ghc
 456 AC_ARG_VAR(GHC, [ghc path])
 457 AC_PATH_PROG(GHC, [ghc], [])
 458 if test -z "$GHC"; then
 459   if test "$enable_htools" != "check"; then
 460     AC_MSG_FAILURE([ghc not found, htools compilation will not possible])
 461   fi
 462 fi
 463
 464 # Check for ghc-pkg
 465 HTOOLS_MODULES=
 466 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 467 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 468 if test -z "$GHC_PKG"; then
 469   if test "$enable_htools" != "check"; then
 470     AC_MSG_FAILURE([ghc-pkg not found, htools compilation will not be possible])
 471   fi
 472 else
 473   # check for modules
 474   AC_MSG_NOTICE([checking for required haskell modules])
 475   HTOOLS_NOCURL=-DNO_CURL
 476   if test "$enable_htools_rapi" != "no"; then
 477     AC_MSG_CHECKING([curl])
 478     GHC_PKG_CURL=$($GHC_PKG latest curl)
 479     if test -z "$GHC_PKG_CURL"; then
 480       if test "$enable_htools_rapi" = "check"; then
 481         AC_MSG_WARN(m4_normalize([The curl library not found, htools will be
 482                                   compiled without RAPI support]))
 483       else
 484         AC_MSG_FAILURE(m4_normalize([The curl library was not found, but it has
 485                                      been requested]))
 486       fi
 487     else
 488       HTOOLS_NOCURL=
 489     fi
 490     AC_MSG_RESULT($GHC_PKG_CURL)
 491   fi
 492   AC_SUBST(GHC_PKG_CURL)
 493   AC_SUBST(HTOOLS_NOCURL)
 494   AC_MSG_CHECKING([parallel])
 495   GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-3.*')
 496   if test -n "$GHC_PKG_PARALLEL"
 497   then
 498     HTOOLS_PARALLEL3=-DPARALLEL3
 499   else
 500     GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-2.*')
 501   fi
 502   if test -z "$GHC_PKG_PARALLEL"
 503   then
 504     GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-1.*')
 505   fi
 506   AC_SUBST(GHC_PKG_PARALLEL)
 507   AC_SUBST(HTOOLS_PARALLEL3)
 508   AC_MSG_RESULT($GHC_PKG_PARALLEL)
 509   AC_MSG_CHECKING([json])
 510   GHC_PKG_JSON=$($GHC_PKG latest json)
 511   AC_MSG_RESULT($GHC_PKG_JSON)
 512   AC_MSG_CHECKING([network])
 513   GHC_PKG_NETWORK=$($GHC_PKG latest network)
 514   AC_MSG_RESULT($GHC_PKG_NETWORK)
 515   AC_MSG_CHECKING([QuickCheck 2.x])
 516   GHC_PKG_QUICKCHECK=$($GHC_PKG --simple-output list 'QuickCheck-2.*')
 517   AC_MSG_RESULT($GHC_PKG_QUICKCHECK)
 518   if test -z "$GHC_PKG_PARALLEL" || test -z "$GHC_PKG_JSON" || \
 519      test -z "$GHC_PKG_NETWORK"; then
 520     if test "$enable_htools" != "check"; then
 521       AC_MSG_FAILURE(m4_normalize([Required Haskell modules not found, htools
 522                                    compilation disabled]))
 523     fi
 524   else
 525     # we leave the other modules to be auto-selected
 526     HTOOLS_MODULES="-package $GHC_PKG_PARALLEL"
 527   fi
 528   if test -z "$GHC_PKG_QUICKCHECK"; then
 529      AC_MSG_WARN(m4_normalize([The QuickCheck 2.x module was not found,
 530                                you won't be able to run Haskell unittests]))
 531   fi
 532 fi
 533 AC_SUBST(HTOOLS_MODULES)
 534 AC_SUBST(GHC_PKG_QUICKCHECK)
 535
 536 if test "$enable_htools" != "no"; then
 537   if test -z "$GHC" || test -z "$HTOOLS_MODULES"; then
 538     AC_MSG_WARN(m4_normalize([Haskell compiler/required libraries not found,
 539                               htools compilation disabled]))
 540   else
 541     HTOOLS=yes
 542   fi
 543 fi
 544 AC_SUBST(HTOOLS)
 545
 546 # Check for HsColour
 547 HTOOLS_APIDOC=no
 548 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 549 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 550 if test -z "$HSCOLOUR"; then
 551   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 552                             not be generated]))
 553 fi
 554
 555 # Check for haddock
 556 AC_ARG_VAR(HADDOCK, [haddock path])
 557 AC_PATH_PROG(HADDOCK, [haddock], [])
 558 if test -z "$HADDOCK"; then
 559   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 560                             not be generated]))
 561 fi
 562 if test "$HADDOCK" && test "$HSCOLOUR"; then
 563   HTOOLS_APIDOC=yes
 564 fi
 565 AC_SUBST(HTOOLS_APIDOC)
 566
 567 # Check for hlint
 568 HLINT=no
 569 AC_ARG_VAR(HLINT, [hlint path])
 570 AC_PATH_PROG(HLINT, [hlint], [])
 571 if test -z "$HLINT"; then
 572   AC_MSG_WARN([hlint not found, checking code will not be possible])
 573 fi
 574
 575 fi # end if enable_htools, define automake conditions
 576
 577 if test "$HTOOLS" != "yes" && test "$HS_CONFD" = "True"; then
 578    AC_MSG_ERROR(m4_normalize([cannot enable Haskell version of ganeti-confd if
 579                               htools support is not enabled]))
 580 fi
 581
 582 AM_CONDITIONAL([WANT_HTOOLS], [test x$HTOOLS = xyes])
 583 AM_CONDITIONAL([WANT_HTOOLSTESTS], [test "x$GHC_PKG_QUICKCHECK" != x])
 584 AM_CONDITIONAL([WANT_HTOOLSAPIDOC], [test x$HTOOLS_APIDOC = xyes])
 585 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 586
 587 # Check for fakeroot
 588 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 589 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 590 if test -z "$FAKEROOT_PATH"; then
 591   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 592                             will not be executed]))
 593 fi
 594 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 595
 596 SOCAT_USE_ESCAPE=
 597 AC_ARG_ENABLE([socat-escape],
 598   [AS_HELP_STRING([--enable-socat-escape],
 599     [use escape functionality available in socat >= 1.7 (default: detect
 600      automatically)])],
 601   [[if test "$enableval" = yes; then
 602       SOCAT_USE_ESCAPE=True
 603     else
 604       SOCAT_USE_ESCAPE=False
 605     fi
 606   ]])
 607
 608 if test -z "$SOCAT_USE_ESCAPE"
 609 then
 610   if $SOCAT -hh | grep -w -q escape; then
 611     SOCAT_USE_ESCAPE=True
 612   else
 613     SOCAT_USE_ESCAPE=False
 614   fi
 615 fi
 616
 617 AC_SUBST(SOCAT_USE_ESCAPE)
 618
 619 SOCAT_USE_COMPRESS=
 620 AC_ARG_ENABLE([socat-compress],
 621   [AS_HELP_STRING([--enable-socat-compress],
 622     [use OpenSSL compression option available in patched socat builds
 623      (see INSTALL for details; default: detect automatically)])],
 624   [[if test "$enableval" = yes; then
 625       SOCAT_USE_COMPRESS=True
 626     else
 627       SOCAT_USE_COMPRESS=False
 628     fi
 629   ]])
 630
 631 if test -z "$SOCAT_USE_COMPRESS"
 632 then
 633   if $SOCAT -hhh | grep -w -q openssl-compress; then
 634     SOCAT_USE_COMPRESS=True
 635   else
 636     SOCAT_USE_COMPRESS=False
 637   fi
 638 fi
 639
 640 AC_SUBST(SOCAT_USE_COMPRESS)
 641
 642 if man --help | grep -q -e --warnings
 643 then
 644   MAN_HAS_WARNINGS=1
 645 else
 646   MAN_HAS_WARNINGS=
 647   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 648                             will not be possible]))
 649 fi
 650
 651 AC_SUBST(MAN_HAS_WARNINGS)
 652
 653 # Check for Python
 654 AM_PATH_PYTHON(2.4)
 655
 656 AC_PYTHON_MODULE(OpenSSL, t)
 657 AC_PYTHON_MODULE(simplejson, t)
 658 AC_PYTHON_MODULE(pyparsing, t)
 659 AC_PYTHON_MODULE(pyinotify, t)
 660 AC_PYTHON_MODULE(pycurl, t)
 661 AC_PYTHON_MODULE(affinity)
 662
 663 # This is optional but then we've limited functionality
 664 AC_PYTHON_MODULE(paramiko)
 665 if test "$HAVE_PYMOD_PARAMIKO" = "no"; then
 666   AC_MSG_WARN(m4_normalize([You do not have Paramiko installed. While this is
 667                             optional you have to configure SSH and the node
 668                             daemon on the joining nodes yourself.]))
 669 fi
 670
 671 AC_CONFIG_FILES([ Makefile ])
 672
 673 AC_OUTPUT