code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [5])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~rc5])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-os-search-path=...
  53 # do a bit of black sed magic to for quoting of the strings in the list
  54 AC_ARG_WITH([os-search-path],
  55   [AS_HELP_STRING([--with-os-search-path=LIST],
  56     [comma separated list of directories to]
  57     [ search for OS images (default is /srv/ganeti/os)]
  58   )],
  59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  60   [os_search_path="'/srv/ganeti/os'"])
  61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  62
  63 # --with-iallocator-search-path=...
  64 # do a bit of black sed magic to for quoting of the strings in the list
  65 AC_ARG_WITH([iallocator-search-path],
  66   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  67     [comma separated list of directories to]
  68     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  69   )],
  70   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  71   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  72 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  73
  74 # --with-xen-bootloader=...
  75 AC_ARG_WITH([xen-bootloader],
  76   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  77     [bootloader for Xen hypervisor (default is empty)]
  78   )],
  79   [xen_bootloader="$withval"],
  80   [xen_bootloader=])
  81 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  82
  83 # --with-xen-kernel=...
  84 AC_ARG_WITH([xen-kernel],
  85   [AS_HELP_STRING([--with-xen-kernel=PATH],
  86     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-2.6-xenU)]
  87   )],
  88   [xen_kernel="$withval"],
  89   [xen_kernel="/boot/vmlinuz-2.6-xenU"])
  90 AC_SUBST(XEN_KERNEL, $xen_kernel)
  91
  92 # --with-xen-initrd=...
  93 AC_ARG_WITH([xen-initrd],
  94   [AS_HELP_STRING([--with-xen-initrd=PATH],
  95     [DomU initrd image for Xen hypervisor (default is /boot/initrd-2.6-xenU)]
  96   )],
  97   [xen_initrd="$withval"],
  98   [xen_initrd="/boot/initrd-2.6-xenU"])
  99 AC_SUBST(XEN_INITRD, $xen_initrd)
 100
 101 # --with-file-storage-dir=...
 102 AC_ARG_WITH([file-storage-dir],
 103   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 104     [directory to store files for file-based backend]
 105     [ (default is /srv/ganeti/file-storage)]
 106   )],
 107   [[file_storage_dir="$withval";
 108     if test "$withval" != no; then
 109       enable_file_storage=True
 110     else
 111       enable_file_storage=False
 112     fi
 113   ]],
 114   [[file_storage_dir="/srv/ganeti/file-storage";
 115     enable_file_storage="True"]])
 116 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 117 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 118
 119 # --with-shared-file-storage-dir=...
 120 AC_ARG_WITH([shared-file-storage-dir],
 121   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 122     [directory to store files for shared file-based backend]
 123     [ (default is /srv/ganeti/shared-file-storage)]
 124   )],
 125   [[shared_file_storage_dir="$withval";
 126     if test "$withval" != no; then
 127       enable_shared_file_storage=True
 128     else
 129       enable_shared_file_storage=False
 130     fi
 131   ]],
 132   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 133     enable_shared_file_storage="True"]])
 134 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 135 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 136
 137 # --with-kvm-path=...
 138 AC_ARG_WITH([kvm-path],
 139   [AS_HELP_STRING([--with-kvm-path=PATH],
 140     [absolute path to the kvm binary]
 141     [ (default is /usr/bin/kvm)]
 142   )],
 143   [kvm_path="$withval"],
 144   [kvm_path="/usr/bin/kvm"])
 145 AC_SUBST(KVM_PATH, $kvm_path)
 146
 147 # --with-lvm-stripecount=...
 148 AC_ARG_WITH([lvm-stripecount],
 149   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 150     [the default number of stripes to use for LVM volumes]
 151     [ (default is 1)]
 152   )],
 153   [lvm_stripecount="$withval"],
 154   [lvm_stripecount="1"])
 155 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 156
 157 # --with-user-prefix=...
 158 AC_ARG_WITH([user-prefix],
 159   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 160     [prefix for daemon users]
 161     [ (default is to run all daemons as root)]
 162   )],
 163   [user_masterd="${withval}masterd";
 164    user_rapi="${withval}rapi";
 165    user_confd="${withval}confd";
 166    user_noded="root"],
 167   [user_masterd="root";
 168    user_rapi="root";
 169    user_confd="root";
 170    user_noded="root"])
 171 AC_SUBST(MASTERD_USER, $user_masterd)
 172 AC_SUBST(RAPI_USER, $user_rapi)
 173 AC_SUBST(CONFD_USER, $user_confd)
 174 AC_SUBST(NODED_USER, $user_noded)
 175
 176 # --with-group-prefix=...
 177 AC_ARG_WITH([group-prefix],
 178   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 179     [prefix for daemon POSIX groups]
 180     [ (default is to run all daemons under group root)]
 181   )],
 182   [group_rapi="${withval}rapi";
 183    group_admin="${withval}admin";
 184    group_confd="${withval}confd";
 185    group_masterd="${withval}masterd";
 186    group_noded="root";
 187    group_daemons="${withval}daemons";],
 188   [group_rapi="root";
 189    group_admin="root";
 190    group_confd="root";
 191    group_masterd="root";
 192    group_noded="root";
 193    group_daemons="root"])
 194 AC_SUBST(RAPI_GROUP, $group_rapi)
 195 AC_SUBST(ADMIN_GROUP, $group_admin)
 196 AC_SUBST(CONFD_GROUP, $group_confd)
 197 AC_SUBST(MASTERD_GROUP, $group_masterd)
 198 AC_SUBST(NODED_GROUP, $group_noded)
 199 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 200
 201 # Print the config to the user
 202 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 203 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 204 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 205 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 206 AC_MSG_NOTICE([Group for clients is $group_admin])
 207
 208 # --enable-drbd-barriers
 209 AC_ARG_ENABLE([drbd-barriers],
 210   [AS_HELP_STRING([--enable-drbd-barriers],
 211     [enable by default the DRBD barriers functionality (>= 8.0.12) (default: enabled)])],
 212   [[if test "$enableval" != no; then
 213       DRBD_BARRIERS=n
 214       DRBD_NO_META_FLUSH=False
 215     else
 216       DRBD_BARRIERS=bfd
 217       DRBD_NO_META_FLUSH=True
 218     fi
 219   ]],
 220   [DRBD_BARRIERS=n
 221    DRBD_NO_META_FLUSH=False
 222   ])
 223 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 224 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 225
 226 # --enable-syslog[=no/yes/only]
 227 AC_ARG_ENABLE([syslog],
 228   [AS_HELP_STRING([--enable-syslog],
 229     [enable use of syslog (default: disabled), one of no/yes/only])],
 230   [[case "$enableval" in
 231       no)
 232         SYSLOG=no
 233         ;;
 234       yes)
 235         SYSLOG=yes
 236         ;;
 237       only)
 238         SYSLOG=only
 239         ;;
 240       *)
 241         SYSLOG=
 242         ;;
 243     esac
 244   ]],
 245   [SYSLOG=no])
 246
 247 if test -z "$SYSLOG"
 248 then
 249   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 250 fi
 251 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 252
 253 # --enable-htools
 254 HTOOLS=
 255 AC_ARG_ENABLE([htools],
 256         [AS_HELP_STRING([--enable-htools],
 257         [enable use of htools (needs GHC and libraries, default: check)])],
 258         [],
 259         [enable_htools=check])
 260
 261 # --enable-htools-rapi
 262 HTOOLS_RAPI=
 263 AC_ARG_ENABLE([htools-rapi],
 264         [AS_HELP_STRING([--enable-htools-rapi],
 265         [enable use of RAPI in htools (needs curl, default: no)])],
 266         [],
 267         [enable_htools_rapi=no])
 268
 269 # --enable-htools
 270 ENABLE_CONFD=
 271 AC_ARG_ENABLE([confd],
 272   [AS_HELP_STRING([--enable-confd],
 273   [enable the ganeti-confd daemon (default: yes)])],
 274   [[case "$enableval" in
 275       no)
 276         enable_confd=False
 277         ;;
 278       yes)
 279         enable_confd=True
 280         ;;
 281       *)
 282         echo "Invalid value for enable-confd '$enableval'"
 283         exit 1
 284         ;;
 285     esac
 286   ]],
 287   [enable_confd=True])
 288 AC_SUBST(ENABLE_CONFD, $enable_confd)
 289
 290 AM_CONDITIONAL([WANT_CONFD], [test x$enable_confd = xTrue])
 291
 292 # --with-disk-separator=...
 293 AC_ARG_WITH([disk-separator],
 294   [AS_HELP_STRING([--with-disk-separator=STRING],
 295     [Disk index separator, useful if the default of ':' is handled]
 296     [ specially by the hypervisor]
 297   )],
 298   [disk_separator="$withval"],
 299   [disk_separator=":"])
 300 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 301
 302 # Check common programs
 303 AC_PROG_INSTALL
 304 AC_PROG_LN_S
 305
 306 # Check for the ip command
 307 AC_ARG_VAR(IP_PATH, [ip path])
 308 AC_PATH_PROG(IP_PATH, [ip], [])
 309 if test -z "$IP_PATH"
 310 then
 311   AC_MSG_ERROR([ip command not found])
 312 fi
 313
 314 # Check for pandoc
 315 AC_ARG_VAR(PANDOC, [pandoc path])
 316 AC_PATH_PROG(PANDOC, [pandoc], [])
 317 if test -z "$PANDOC"
 318 then
 319   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 320 fi
 321
 322 # Check for python-sphinx
 323 AC_ARG_VAR(SPHINX, [sphinx-build path])
 324 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 325 if test -z "$SPHINX"
 326 then
 327   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 328                             not be possible]))
 329 fi
 330
 331 # Check for graphviz (dot)
 332 AC_ARG_VAR(DOT, [dot path])
 333 AC_PATH_PROG(DOT, [dot], [])
 334 if test -z "$DOT"
 335 then
 336   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 337                             documentation rebuild not possible]))
 338 fi
 339
 340 # Check for pylint
 341 AC_ARG_VAR(PYLINT, [pylint path])
 342 AC_PATH_PROG(PYLINT, [pylint], [])
 343 if test -z "$PYLINT"
 344 then
 345   AC_MSG_WARN([pylint not found, checking code will not be possible])
 346 fi
 347
 348 # Check for pep8
 349 AC_ARG_VAR(PEP8, [pep8 path])
 350 AC_PATH_PROG(PEP8, [pep8], [])
 351 if test -z "$PEP8"
 352 then
 353   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 354 fi
 355
 356 # Check for socat
 357 AC_ARG_VAR(SOCAT, [socat path])
 358 AC_PATH_PROG(SOCAT, [socat], [])
 359 if test -z "$SOCAT"
 360 then
 361   AC_MSG_ERROR([socat not found])
 362 fi
 363
 364 # Check for qemu-img
 365 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 366 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 367 if test -z "$QEMUIMG_PATH"
 368 then
 369   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 370 fi
 371
 372 if test "$enable_htools" != "no"; then
 373
 374 # Check for ghc
 375 AC_ARG_VAR(GHC, [ghc path])
 376 AC_PATH_PROG(GHC, [ghc], [])
 377 if test -z "$GHC"; then
 378   if test "$enable_htools" != "check"; then
 379     AC_MSG_FAILURE([ghc not found, htools compilation will not possible])
 380   fi
 381 fi
 382
 383 # Check for ghc-pkg
 384 HTOOLS_MODULES=
 385 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 386 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 387 if test -z "$GHC_PKG"; then
 388   if test "$enable_htools" != "check"; then
 389     AC_MSG_FAILURE([ghc-pkg not found, htools compilation will not be possible])
 390   fi
 391 else
 392   # check for modules
 393   AC_MSG_NOTICE([checking for required haskell modules])
 394   HTOOLS_NOCURL=-DNO_CURL
 395   if test "$enable_htools_rapi" != "no"; then
 396     AC_MSG_CHECKING([curl])
 397     GHC_PKG_CURL=$($GHC_PKG latest curl)
 398     if test -z "$GHC_PKG_CURL"; then
 399       if test "$enable_htools_rapi" = "check"; then
 400         AC_MSG_WARN(m4_normalize([The curl library not found, htools will be
 401                                   compiled without RAPI support]))
 402       else
 403         AC_MSG_FAILURE(m4_normalize([The curl library was not found, but it has
 404                                      been requested]))
 405       fi
 406     else
 407       HTOOLS_NOCURL=
 408     fi
 409     AC_MSG_RESULT($GHC_PKG_CURL)
 410   fi
 411   AC_SUBST(GHC_PKG_CURL)
 412   AC_SUBST(HTOOLS_NOCURL)
 413   AC_MSG_CHECKING([parallel])
 414   GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-3.*')
 415   if test -n "$GHC_PKG_PARALLEL"
 416   then
 417     HTOOLS_PARALLEL3=-DPARALLEL3
 418   else
 419     GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-2.*')
 420   fi
 421   if test -z "$GHC_PKG_PARALLEL"
 422   then
 423     GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-1.*')
 424   fi
 425   AC_SUBST(GHC_PKG_PARALLEL)
 426   AC_SUBST(HTOOLS_PARALLEL3)
 427   AC_MSG_RESULT($GHC_PKG_PARALLEL)
 428   AC_MSG_CHECKING([json])
 429   GHC_PKG_JSON=$($GHC_PKG latest json)
 430   AC_MSG_RESULT($GHC_PKG_JSON)
 431   AC_MSG_CHECKING([network])
 432   GHC_PKG_NETWORK=$($GHC_PKG latest network)
 433   AC_MSG_RESULT($GHC_PKG_NETWORK)
 434   AC_MSG_CHECKING([QuickCheck 2.x])
 435   GHC_PKG_QUICKCHECK=$($GHC_PKG --simple-output list 'QuickCheck-2.*')
 436   AC_MSG_RESULT($GHC_PKG_QUICKCHECK)
 437   if test -z "$GHC_PKG_PARALLEL" || test -z "$GHC_PKG_JSON" || \
 438      test -z "$GHC_PKG_NETWORK"; then
 439     if test "$enable_htools" != "check"; then
 440       AC_MSG_FAILURE(m4_normalize([Required Haskell modules not found, htools
 441                                    compilation disabled]))
 442     fi
 443   else
 444     # we leave the other modules to be auto-selected
 445     HTOOLS_MODULES="-package $GHC_PKG_PARALLEL"
 446   fi
 447   if test -z "$GHC_PKG_QUICKCHECK"; then
 448      AC_MSG_WARN(m4_normalize([The QuickCheck 2.x module was not found,
 449                                you won't be able to run Haskell unittests]))
 450   fi
 451 fi
 452 AC_SUBST(HTOOLS_MODULES)
 453 AC_SUBST(GHC_PKG_QUICKCHECK)
 454
 455 if test "$enable_htools" != "no"; then
 456   if test -z "$GHC" || test -z "$HTOOLS_MODULES"; then
 457     AC_MSG_WARN(m4_normalize([Haskell compiler/required libraries not found,
 458                               htools compilation disabled]))
 459   else
 460     HTOOLS=yes
 461   fi
 462 fi
 463 AC_SUBST(HTOOLS)
 464
 465 # Check for HsColour
 466 HTOOLS_APIDOC=no
 467 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 468 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 469 if test -z "$HSCOLOUR"; then
 470   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 471                             not be generated]))
 472 fi
 473
 474 # Check for haddock
 475 AC_ARG_VAR(HADDOCK, [haddock path])
 476 AC_PATH_PROG(HADDOCK, [haddock], [])
 477 if test -z "$HADDOCK"; then
 478   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 479                             not be generated]))
 480 fi
 481 if test "$HADDOCK" && test "$HSCOLOUR"; then
 482   HTOOLS_APIDOC=yes
 483 fi
 484 AC_SUBST(HTOOLS_APIDOC)
 485
 486 fi # end if enable_htools, define automake conditions
 487
 488 AM_CONDITIONAL([WANT_HTOOLS], [test x$HTOOLS = xyes])
 489 AM_CONDITIONAL([WANT_HTOOLSTESTS], [test "x$GHC_PKG_QUICKCHECK" != x])
 490 AM_CONDITIONAL([WANT_HTOOLSAPIDOC], [test x$HTOOLS_APIDOC = xyes])
 491
 492 # Check for fakeroot
 493 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 494 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 495 if test -z "$FAKEROOT_PATH"; then
 496   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 497                             will not be executed]))
 498 fi
 499 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 500
 501 SOCAT_USE_ESCAPE=
 502 AC_ARG_ENABLE([socat-escape],
 503   [AS_HELP_STRING([--enable-socat-escape],
 504     [use escape functionality available in socat >= 1.7 (default: detect
 505      automatically)])],
 506   [[if test "$enableval" = yes; then
 507       SOCAT_USE_ESCAPE=True
 508     else
 509       SOCAT_USE_ESCAPE=False
 510     fi
 511   ]])
 512
 513 if test -z "$SOCAT_USE_ESCAPE"
 514 then
 515   if $SOCAT -hh | grep -w -q escape; then
 516     SOCAT_USE_ESCAPE=True
 517   else
 518     SOCAT_USE_ESCAPE=False
 519   fi
 520 fi
 521
 522 AC_SUBST(SOCAT_USE_ESCAPE)
 523
 524 SOCAT_USE_COMPRESS=
 525 AC_ARG_ENABLE([socat-compress],
 526   [AS_HELP_STRING([--enable-socat-compress],
 527     [use OpenSSL compression option available in patched socat builds
 528      (see INSTALL for details; default: detect automatically)])],
 529   [[if test "$enableval" = yes; then
 530       SOCAT_USE_COMPRESS=True
 531     else
 532       SOCAT_USE_COMPRESS=False
 533     fi
 534   ]])
 535
 536 if test -z "$SOCAT_USE_COMPRESS"
 537 then
 538   if $SOCAT -hhh | grep -w -q openssl-compress; then
 539     SOCAT_USE_COMPRESS=True
 540   else
 541     SOCAT_USE_COMPRESS=False
 542   fi
 543 fi
 544
 545 AC_SUBST(SOCAT_USE_COMPRESS)
 546
 547 if man --help | grep -q -e --warnings
 548 then
 549   MAN_HAS_WARNINGS=1
 550 else
 551   MAN_HAS_WARNINGS=
 552   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 553                             will not be possible]))
 554 fi
 555
 556 AC_SUBST(MAN_HAS_WARNINGS)
 557
 558 # Check for Python
 559 AM_PATH_PYTHON(2.4)
 560
 561 AC_PYTHON_MODULE(OpenSSL, t)
 562 AC_PYTHON_MODULE(simplejson, t)
 563 AC_PYTHON_MODULE(pyparsing, t)
 564 AC_PYTHON_MODULE(pyinotify, t)
 565 AC_PYTHON_MODULE(pycurl, t)
 566 AC_PYTHON_MODULE(affinity)
 567
 568 # This is optional but then we've limited functionality
 569 AC_PYTHON_MODULE(paramiko)
 570 if test "$HAVE_PYMOD_PARAMIKO" = "no"; then
 571   AC_MSG_WARN(m4_normalize([You do not have Paramiko installed. While this is
 572                             optional you have to configure SSH and the node
 573                             daemon on the joining nodes yourself.]))
 574 fi
 575
 576 AC_CONFIG_FILES([ Makefile ])
 577
 578 AC_OUTPUT