code.grnet.gr Git - ganeti-local/blob - Ganeti/HTools/Utils.hs

   1 {-| Utility functions -}
   2
   3 {-
   4
   5 Copyright (C) 2009 Google Inc.
   6
   7 This program is free software; you can redistribute it and/or modify
   8 it under the terms of the GNU General Public License as published by
   9 the Free Software Foundation; either version 2 of the License, or
  10 (at your option) any later version.
  11
  12 This program is distributed in the hope that it will be useful, but
  13 WITHOUT ANY WARRANTY; without even the implied warranty of
  14 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 General Public License for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with this program; if not, write to the Free Software
  19 Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 02110-1301, USA.
  21
  22 -}
  23
  24 module Ganeti.HTools.Utils
  25     (
  26       debug
  27     , sepSplit
  28     , fst3
  29     , varianceCoeff
  30     , commaJoin
  31     , readEitherString
  32     , loadJSArray
  33     , fromObj
  34     , asJSObject
  35     , asObjectList
  36     , fromJResult
  37     ) where
  38
  39 import Data.List
  40 import Control.Monad
  41 import qualified Text.JSON as J
  42 import Text.Printf (printf)
  43
  44 import Debug.Trace
  45
  46 -- * Debug functions
  47
  48 -- | To be used only for debugging, breaks referential integrity.
  49 debug :: Show a => a -> a
  50 debug x = trace (show x) x
  51
  52 -- * Miscelaneous
  53
  54 -- | Comma-join a string list.
  55 commaJoin :: [String] -> String
  56 commaJoin = intercalate ","
  57
  58 -- | Split a string on a separator and return an array.
  59 sepSplit :: Char -> String -> [String]
  60 sepSplit sep s
  61     | x == "" && xs == [] = []
  62     | xs == []            = [x]
  63     | ys == []            = x:"":[]
  64     | otherwise           = x:(sepSplit sep ys)
  65     where (x, xs) = break (== sep) s
  66           ys = drop 1 xs
  67
  68 -- | Simple version of 'fst' for a triple
  69 fst3 :: (a, b, c) -> a
  70 fst3 (a, _, _) = a
  71
  72 -- * Mathematical functions
  73
  74 -- Simple and slow statistical functions, please replace with better versions
  75
  76 -- | Mean value of a list.
  77 meanValue :: Floating a => [a] -> a
  78 meanValue lst = (sum lst) / (fromIntegral $ length lst)
  79
  80 -- | Squaring function
  81 square :: (Num a) => a -> a
  82 square = (^ 2)
  83
  84 -- | Standard deviation.
  85 stdDev :: Floating a => [a] -> a
  86 stdDev lst =
  87     let mv = meanValue lst
  88         av = sum $ map square $ map (\e -> e - mv) lst
  89         bv = sqrt (av / (fromIntegral $ length lst))
  90     in bv
  91
  92 -- | Coefficient of variation.
  93 varianceCoeff :: Floating a => [a] -> a
  94 varianceCoeff lst = (stdDev lst) / (fromIntegral $ length lst)
  95
  96 -- * JSON-related functions
  97
  98 -- | Converts a JSON Result into a monadic value.
  99 fromJResult :: Monad m => J.Result a -> m a
 100 fromJResult (J.Error x) = fail x
 101 fromJResult (J.Ok x) = return x
 102
 103 -- | Tries to read a string from a JSON value.
 104 --
 105 -- In case the value was not a string, we fail the read (in the
 106 -- context of the current monad.
 107 readEitherString :: (Monad m) => J.JSValue -> m String
 108 readEitherString v =
 109     case v of
 110       J.JSString s -> return $ J.fromJSString s
 111       _ -> fail "Wrong JSON type"
 112
 113 -- | Converts a JSON message into an array of JSON objects.
 114 loadJSArray :: (Monad m) => String -> m [J.JSObject J.JSValue]
 115 loadJSArray s = fromJResult $ J.decodeStrict s
 116
 117 -- | Reads a the value of a key in a JSON object.
 118 fromObj :: (J.JSON a, Monad m) => String -> J.JSObject J.JSValue -> m a
 119 fromObj k o =
 120     case lookup k (J.fromJSObject o) of
 121       Nothing -> fail $ printf "key '%s' not found in %s" k (show o)
 122       Just val -> fromJResult $ J.readJSON val
 123
 124 -- | Converts a JSON value into a JSON object.
 125 asJSObject :: (Monad m) => J.JSValue -> m (J.JSObject J.JSValue)
 126 asJSObject (J.JSObject a) = return a
 127 asJSObject _ = fail "not an object"
 128
 129 -- | Coneverts a list of JSON values into a list of JSON objects.
 130 asObjectList :: (Monad m) => [J.JSValue] -> m [J.JSObject J.JSValue]
 131 asObjectList = sequence . map asJSObject