code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [6])
   4 m4_define([gnt_version_revision], [1])
   5 m4_define([gnt_version_suffix], [])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-os-search-path=...
  53 # do a bit of black sed magic to for quoting of the strings in the list
  54 AC_ARG_WITH([os-search-path],
  55   [AS_HELP_STRING([--with-os-search-path=LIST],
  56     [comma separated list of directories to]
  57     [ search for OS images (default is /srv/ganeti/os)]
  58   )],
  59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  60   [os_search_path="'/srv/ganeti/os'"])
  61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  62
  63 # --with-extstorage-search-path=...
  64 # same black sed magic for quoting of the strings in the list
  65 AC_ARG_WITH([extstorage-search-path],
  66   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  67     [comma separated list of directories to]
  68     [ search for External Storage Providers]
  69     [ (default is /srv/ganeti/extstorage)]
  70   )],
  71   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  72   [es_search_path="'/srv/ganeti/extstorage'"])
  73 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  74
  75 # --with-iallocator-search-path=...
  76 # do a bit of black sed magic to for quoting of the strings in the list
  77 AC_ARG_WITH([iallocator-search-path],
  78   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  79     [comma separated list of directories to]
  80     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  81   )],
  82   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  83   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  84 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  85
  86 # --with-xen-bootloader=...
  87 AC_ARG_WITH([xen-bootloader],
  88   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  89     [bootloader for Xen hypervisor (default is empty)]
  90   )],
  91   [xen_bootloader="$withval"],
  92   [xen_bootloader=])
  93 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  94
  95 # --with-xen-kernel=...
  96 AC_ARG_WITH([xen-kernel],
  97   [AS_HELP_STRING([--with-xen-kernel=PATH],
  98     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
  99   )],
 100   [xen_kernel="$withval"],
 101   [xen_kernel="/boot/vmlinuz-3-xenU"])
 102 AC_SUBST(XEN_KERNEL, $xen_kernel)
 103
 104 # --with-xen-initrd=...
 105 AC_ARG_WITH([xen-initrd],
 106   [AS_HELP_STRING([--with-xen-initrd=PATH],
 107     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 108   )],
 109   [xen_initrd="$withval"],
 110   [xen_initrd="/boot/initrd-3-xenU"])
 111 AC_SUBST(XEN_INITRD, $xen_initrd)
 112
 113 # --with-xen-cmd=...
 114 AC_ARG_WITH([xen-cmd],
 115   [AS_HELP_STRING([--with-xen-cmd=CMD],
 116     [Sets the xen cli interface command (default is xm)]
 117   )],
 118   [xen_cmd="$withval"],
 119   [xen_cmd="xm"])
 120 AC_SUBST(XEN_CMD, $xen_cmd)
 121
 122 if ! test "$XEN_CMD" = xl -o "$XEN_CMD" = xm; then
 123   AC_MSG_ERROR([Unsupported xen command specified])
 124 fi
 125
 126 # --with-kvm-kernel=...
 127 AC_ARG_WITH([kvm-kernel],
 128   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 129     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 130   )],
 131   [kvm_kernel="$withval"],
 132   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 133 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 134
 135 # --with-file-storage-dir=...
 136 AC_ARG_WITH([file-storage-dir],
 137   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 138     [directory to store files for file-based backend]
 139     [ (default is /srv/ganeti/file-storage)]
 140   )],
 141   [[file_storage_dir="$withval";
 142     if test "$withval" != no; then
 143       enable_file_storage=True
 144     else
 145       enable_file_storage=False
 146     fi
 147   ]],
 148   [[file_storage_dir="/srv/ganeti/file-storage";
 149     enable_file_storage="True"]])
 150 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 151 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 152
 153 # --with-shared-file-storage-dir=...
 154 AC_ARG_WITH([shared-file-storage-dir],
 155   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 156     [directory to store files for shared file-based backend]
 157     [ (default is /srv/ganeti/shared-file-storage)]
 158   )],
 159   [[shared_file_storage_dir="$withval";
 160     if test "$withval" != no; then
 161       enable_shared_file_storage=True
 162     else
 163       enable_shared_file_storage=False
 164     fi
 165   ]],
 166   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 167     enable_shared_file_storage="True"]])
 168 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 169 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 170
 171 # --with-kvm-path=...
 172 AC_ARG_WITH([kvm-path],
 173   [AS_HELP_STRING([--with-kvm-path=PATH],
 174     [absolute path to the kvm binary]
 175     [ (default is /usr/bin/kvm)]
 176   )],
 177   [kvm_path="$withval"],
 178   [kvm_path="/usr/bin/kvm"])
 179 AC_SUBST(KVM_PATH, $kvm_path)
 180
 181 # --with-lvm-stripecount=...
 182 AC_ARG_WITH([lvm-stripecount],
 183   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 184     [the default number of stripes to use for LVM volumes]
 185     [ (default is 1)]
 186   )],
 187   [lvm_stripecount="$withval"],
 188   [lvm_stripecount="1"])
 189 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 190
 191 # --with-user-prefix=...
 192 AC_ARG_WITH([user-prefix],
 193   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 194     [prefix for daemon users]
 195     [ (default is to run all daemons as root)]
 196   )],
 197   [user_masterd="${withval}masterd";
 198    user_rapi="${withval}rapi";
 199    user_confd="${withval}confd";
 200    user_noded="root"],
 201   [user_masterd="root";
 202    user_rapi="root";
 203    user_confd="root";
 204    user_noded="root"])
 205 AC_SUBST(MASTERD_USER, $user_masterd)
 206 AC_SUBST(RAPI_USER, $user_rapi)
 207 AC_SUBST(CONFD_USER, $user_confd)
 208 AC_SUBST(NODED_USER, $user_noded)
 209
 210 # --with-group-prefix=...
 211 AC_ARG_WITH([group-prefix],
 212   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 213     [prefix for daemon POSIX groups]
 214     [ (default is to run all daemons under group root)]
 215   )],
 216   [group_rapi="${withval}rapi";
 217    group_admin="${withval}admin";
 218    group_confd="${withval}confd";
 219    group_masterd="${withval}masterd";
 220    group_noded="root";
 221    group_daemons="${withval}daemons";],
 222   [group_rapi="root";
 223    group_admin="root";
 224    group_confd="root";
 225    group_masterd="root";
 226    group_noded="root";
 227    group_daemons="root"])
 228 AC_SUBST(RAPI_GROUP, $group_rapi)
 229 AC_SUBST(ADMIN_GROUP, $group_admin)
 230 AC_SUBST(CONFD_GROUP, $group_confd)
 231 AC_SUBST(MASTERD_GROUP, $group_masterd)
 232 AC_SUBST(NODED_GROUP, $group_noded)
 233 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 234
 235 # Print the config to the user
 236 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 237 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 238 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 239 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 240 AC_MSG_NOTICE([Group for clients is $group_admin])
 241
 242 # --enable-drbd-barriers
 243 AC_ARG_ENABLE([drbd-barriers],
 244   [AS_HELP_STRING([--enable-drbd-barriers],
 245     [enable by default the DRBD barriers functionality (>= 8.0.12) (default: enabled)])],
 246   [[if test "$enableval" != no; then
 247       DRBD_BARRIERS=n
 248       DRBD_NO_META_FLUSH=False
 249     else
 250       DRBD_BARRIERS=bf
 251       DRBD_NO_META_FLUSH=True
 252     fi
 253   ]],
 254   [DRBD_BARRIERS=n
 255    DRBD_NO_META_FLUSH=False
 256   ])
 257 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 258 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 259
 260 # --enable-syslog[=no/yes/only]
 261 AC_ARG_ENABLE([syslog],
 262   [AS_HELP_STRING([--enable-syslog],
 263     [enable use of syslog (default: disabled), one of no/yes/only])],
 264   [[case "$enableval" in
 265       no)
 266         SYSLOG=no
 267         ;;
 268       yes)
 269         SYSLOG=yes
 270         ;;
 271       only)
 272         SYSLOG=only
 273         ;;
 274       *)
 275         SYSLOG=
 276         ;;
 277     esac
 278   ]],
 279   [SYSLOG=no])
 280
 281 if test -z "$SYSLOG"
 282 then
 283   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 284 fi
 285 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 286
 287 # --enable-htools
 288 HTOOLS=
 289 AC_ARG_ENABLE([htools],
 290         [AS_HELP_STRING([--enable-htools],
 291         [enable use of htools (needs GHC and libraries, default: check)])],
 292         [],
 293         [enable_htools=check])
 294
 295 # --enable-htools-rapi
 296 HTOOLS_RAPI=
 297 AC_ARG_ENABLE([htools-rapi],
 298         [AS_HELP_STRING([--enable-htools-rapi],
 299         [enable use of RAPI in htools (needs curl, default: no)])],
 300         [],
 301         [enable_htools_rapi=no])
 302
 303 # --enable-htools
 304 ENABLE_CONFD=
 305 AC_ARG_ENABLE([confd],
 306   [AS_HELP_STRING([--enable-confd],
 307   [enable the ganeti-confd daemon (default: python, options haskell/python/no)])],
 308   [[case "$enableval" in
 309       no)
 310         enable_confd=False
 311         py_confd=False
 312         hs_confd=False
 313         ;;
 314       yes|python)
 315         enable_confd=True
 316         py_confd=True
 317         hs_confd=False
 318         ;;
 319       haskell)
 320         enable_confd=True
 321         py_confd=False
 322         hs_confd=True
 323         ;;
 324       *)
 325         echo "Invalid value for enable-confd '$enableval'"
 326         exit 1
 327         ;;
 328     esac
 329   ]],
 330   [enable_confd=True;py_confd=True;hs_confd=False])
 331 AC_SUBST(ENABLE_CONFD, $enable_confd)
 332 AC_SUBST(PY_CONFD, $py_confd)
 333 AC_SUBST(HS_CONFD, $hs_confd)
 334
 335 AM_CONDITIONAL([WANT_CONFD], [test x$enable_confd = xTrue])
 336 AM_CONDITIONAL([PY_CONFD], [test x$py_confd = xTrue])
 337 AM_CONDITIONAL([HS_CONFD], [test x$hs_confd = xTrue])
 338
 339 # --with-disk-separator=...
 340 AC_ARG_WITH([disk-separator],
 341   [AS_HELP_STRING([--with-disk-separator=STRING],
 342     [Disk index separator, useful if the default of ':' is handled]
 343     [ specially by the hypervisor]
 344   )],
 345   [disk_separator="$withval"],
 346   [disk_separator=":"])
 347 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 348
 349 # Check common programs
 350 AC_PROG_INSTALL
 351 AC_PROG_LN_S
 352
 353 # Check for the ip command
 354 AC_ARG_VAR(IP_PATH, [ip path])
 355 AC_PATH_PROG(IP_PATH, [ip], [])
 356 if test -z "$IP_PATH"
 357 then
 358   AC_MSG_ERROR([ip command not found])
 359 fi
 360
 361 # Check for pandoc
 362 AC_ARG_VAR(PANDOC, [pandoc path])
 363 AC_PATH_PROG(PANDOC, [pandoc], [])
 364 if test -z "$PANDOC"
 365 then
 366   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 367 fi
 368
 369 # Check for python-sphinx
 370 AC_ARG_VAR(SPHINX, [sphinx-build path])
 371 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 372 if test -z "$SPHINX"
 373 then
 374   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 375                             not be possible]))
 376 fi
 377
 378 # Check for graphviz (dot)
 379 AC_ARG_VAR(DOT, [dot path])
 380 AC_PATH_PROG(DOT, [dot], [])
 381 if test -z "$DOT"
 382 then
 383   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 384                             documentation rebuild not possible]))
 385 fi
 386
 387 # Check for pylint
 388 AC_ARG_VAR(PYLINT, [pylint path])
 389 AC_PATH_PROG(PYLINT, [pylint], [])
 390 if test -z "$PYLINT"
 391 then
 392   AC_MSG_WARN([pylint not found, checking code will not be possible])
 393 fi
 394
 395 # Check for pep8
 396 AC_ARG_VAR(PEP8, [pep8 path])
 397 AC_PATH_PROG(PEP8, [pep8], [])
 398 if test -z "$PEP8"
 399 then
 400   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 401 fi
 402 AM_CONDITIONAL([HAS_PEP8], [test "$PEP8"])
 403
 404 # Check for socat
 405 AC_ARG_VAR(SOCAT, [socat path])
 406 AC_PATH_PROG(SOCAT, [socat], [])
 407 if test -z "$SOCAT"
 408 then
 409   AC_MSG_ERROR([socat not found])
 410 fi
 411
 412 # Check for qemu-img
 413 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 414 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 415 if test -z "$QEMUIMG_PATH"
 416 then
 417   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 418 fi
 419
 420 if test "$enable_htools" != "no"; then
 421
 422 # Check for ghc
 423 AC_ARG_VAR(GHC, [ghc path])
 424 AC_PATH_PROG(GHC, [ghc], [])
 425 if test -z "$GHC"; then
 426   if test "$enable_htools" != "check"; then
 427     AC_MSG_FAILURE([ghc not found, htools compilation will not possible])
 428   fi
 429 fi
 430
 431 # Check for ghc-pkg
 432 HTOOLS_MODULES=
 433 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 434 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 435 if test -z "$GHC_PKG"; then
 436   if test "$enable_htools" != "check"; then
 437     AC_MSG_FAILURE([ghc-pkg not found, htools compilation will not be possible])
 438   fi
 439 else
 440   # check for modules
 441   AC_MSG_NOTICE([checking for required haskell modules])
 442   HTOOLS_NOCURL=-DNO_CURL
 443   if test "$enable_htools_rapi" != "no"; then
 444     AC_MSG_CHECKING([curl])
 445     GHC_PKG_CURL=$($GHC_PKG latest curl)
 446     if test -z "$GHC_PKG_CURL"; then
 447       if test "$enable_htools_rapi" = "check"; then
 448         AC_MSG_WARN(m4_normalize([The curl library not found, htools will be
 449                                   compiled without RAPI support]))
 450       else
 451         AC_MSG_FAILURE(m4_normalize([The curl library was not found, but it has
 452                                      been requested]))
 453       fi
 454     else
 455       HTOOLS_NOCURL=
 456     fi
 457     AC_MSG_RESULT($GHC_PKG_CURL)
 458   fi
 459   AC_SUBST(GHC_PKG_CURL)
 460   AC_SUBST(HTOOLS_NOCURL)
 461   AC_MSG_CHECKING([parallel])
 462   GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-3.*')
 463   if test -n "$GHC_PKG_PARALLEL"
 464   then
 465     HTOOLS_PARALLEL3=-DPARALLEL3
 466   else
 467     GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-2.*')
 468   fi
 469   if test -z "$GHC_PKG_PARALLEL"
 470   then
 471     GHC_PKG_PARALLEL=$($GHC_PKG --simple-output list 'parallel-1.*')
 472   fi
 473   AC_SUBST(GHC_PKG_PARALLEL)
 474   AC_SUBST(HTOOLS_PARALLEL3)
 475   AC_MSG_RESULT($GHC_PKG_PARALLEL)
 476   AC_MSG_CHECKING([json])
 477   GHC_PKG_JSON=$($GHC_PKG latest json)
 478   AC_MSG_RESULT($GHC_PKG_JSON)
 479   AC_MSG_CHECKING([network])
 480   GHC_PKG_NETWORK=$($GHC_PKG latest network)
 481   AC_MSG_RESULT($GHC_PKG_NETWORK)
 482   AC_MSG_CHECKING([QuickCheck 2.x])
 483   GHC_PKG_QUICKCHECK=$($GHC_PKG --simple-output list 'QuickCheck-2.*')
 484   AC_MSG_RESULT($GHC_PKG_QUICKCHECK)
 485   if test -z "$GHC_PKG_PARALLEL" || test -z "$GHC_PKG_JSON" || \
 486      test -z "$GHC_PKG_NETWORK"; then
 487     if test "$enable_htools" != "check"; then
 488       AC_MSG_FAILURE(m4_normalize([Required Haskell modules not found, htools
 489                                    compilation disabled]))
 490     fi
 491   else
 492     # we leave the other modules to be auto-selected
 493     HTOOLS_MODULES="-package $GHC_PKG_PARALLEL"
 494   fi
 495   if test -z "$GHC_PKG_QUICKCHECK"; then
 496      AC_MSG_WARN(m4_normalize([The QuickCheck 2.x module was not found,
 497                                you won't be able to run Haskell unittests]))
 498   fi
 499 fi
 500 AC_SUBST(HTOOLS_MODULES)
 501 AC_SUBST(GHC_PKG_QUICKCHECK)
 502
 503 if test "$enable_htools" != "no"; then
 504   if test -z "$GHC" || test -z "$HTOOLS_MODULES"; then
 505     AC_MSG_WARN(m4_normalize([Haskell compiler/required libraries not found,
 506                               htools compilation disabled]))
 507   else
 508     HTOOLS=yes
 509   fi
 510 fi
 511 AC_SUBST(HTOOLS)
 512
 513 # Check for HsColour
 514 HTOOLS_APIDOC=no
 515 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 516 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 517 if test -z "$HSCOLOUR"; then
 518   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 519                             not be generated]))
 520 fi
 521
 522 # Check for haddock
 523 AC_ARG_VAR(HADDOCK, [haddock path])
 524 AC_PATH_PROG(HADDOCK, [haddock], [])
 525 if test -z "$HADDOCK"; then
 526   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 527                             not be generated]))
 528 fi
 529 if test "$HADDOCK" && test "$HSCOLOUR"; then
 530   HTOOLS_APIDOC=yes
 531 fi
 532 AC_SUBST(HTOOLS_APIDOC)
 533
 534 # Check for hlint
 535 HLINT=no
 536 AC_ARG_VAR(HLINT, [hlint path])
 537 AC_PATH_PROG(HLINT, [hlint], [])
 538 if test -z "$HLINT"; then
 539   AC_MSG_WARN([hlint not found, checking code will not be possible])
 540 fi
 541
 542 fi # end if enable_htools, define automake conditions
 543
 544 if test "$HTOOLS" != "yes" && test "$HS_CONFD" = "True"; then
 545    AC_MSG_ERROR(m4_normalize([cannot enable Haskell version of ganeti-confd if
 546                               htools support is not enabled]))
 547 fi
 548
 549 AM_CONDITIONAL([WANT_HTOOLS], [test x$HTOOLS = xyes])
 550 AM_CONDITIONAL([WANT_HTOOLSTESTS], [test "x$GHC_PKG_QUICKCHECK" != x])
 551 AM_CONDITIONAL([WANT_HTOOLSAPIDOC], [test x$HTOOLS_APIDOC = xyes])
 552 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 553
 554 # Check for fakeroot
 555 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 556 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 557 if test -z "$FAKEROOT_PATH"; then
 558   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 559                             will not be executed]))
 560 fi
 561 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 562
 563 SOCAT_USE_ESCAPE=
 564 AC_ARG_ENABLE([socat-escape],
 565   [AS_HELP_STRING([--enable-socat-escape],
 566     [use escape functionality available in socat >= 1.7 (default: detect
 567      automatically)])],
 568   [[if test "$enableval" = yes; then
 569       SOCAT_USE_ESCAPE=True
 570     else
 571       SOCAT_USE_ESCAPE=False
 572     fi
 573   ]])
 574
 575 if test -z "$SOCAT_USE_ESCAPE"
 576 then
 577   if $SOCAT -hh | grep -w -q escape; then
 578     SOCAT_USE_ESCAPE=True
 579   else
 580     SOCAT_USE_ESCAPE=False
 581   fi
 582 fi
 583
 584 AC_SUBST(SOCAT_USE_ESCAPE)
 585
 586 SOCAT_USE_COMPRESS=
 587 AC_ARG_ENABLE([socat-compress],
 588   [AS_HELP_STRING([--enable-socat-compress],
 589     [use OpenSSL compression option available in patched socat builds
 590      (see INSTALL for details; default: detect automatically)])],
 591   [[if test "$enableval" = yes; then
 592       SOCAT_USE_COMPRESS=True
 593     else
 594       SOCAT_USE_COMPRESS=False
 595     fi
 596   ]])
 597
 598 if test -z "$SOCAT_USE_COMPRESS"
 599 then
 600   if $SOCAT -hhh | grep -w -q openssl-compress; then
 601     SOCAT_USE_COMPRESS=True
 602   else
 603     SOCAT_USE_COMPRESS=False
 604   fi
 605 fi
 606
 607 AC_SUBST(SOCAT_USE_COMPRESS)
 608
 609 if man --help | grep -q -e --warnings
 610 then
 611   MAN_HAS_WARNINGS=1
 612 else
 613   MAN_HAS_WARNINGS=
 614   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 615                             will not be possible]))
 616 fi
 617
 618 AC_SUBST(MAN_HAS_WARNINGS)
 619
 620 # Check for Python
 621 AM_PATH_PYTHON(2.4)
 622
 623 AC_PYTHON_MODULE(OpenSSL, t)
 624 AC_PYTHON_MODULE(simplejson, t)
 625 AC_PYTHON_MODULE(pyparsing, t)
 626 AC_PYTHON_MODULE(pyinotify, t)
 627 AC_PYTHON_MODULE(pycurl, t)
 628 AC_PYTHON_MODULE(affinity)
 629
 630 # This is optional but then we've limited functionality
 631 AC_PYTHON_MODULE(paramiko)
 632 if test "$HAVE_PYMOD_PARAMIKO" = "no"; then
 633   AC_MSG_WARN(m4_normalize([You do not have Paramiko installed. While this is
 634                             optional you have to configure SSH and the node
 635                             daemon on the joining nodes yourself.]))
 636 fi
 637
 638 AC_CONFIG_FILES([ Makefile ])
 639
 640 AC_OUTPUT