code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [1])
   3 m4_define([gnt_version_minor], [2])
   4 m4_define([gnt_version_revision], [3])
   5 m4_define([gnt_version_suffix], [])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([foreign tar-ustar])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-os-search-path=...
  43 # do a bit of black sed magic to for quoting of the strings in the list
  44 AC_ARG_WITH([os-search-path],
  45   [AS_HELP_STRING([--with-os-search-path=LIST],
  46     [comma separated list of directories to]
  47     [ search for OS images (default is /srv/ganeti/os)]
  48   )],
  49   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  50   [os_search_path="'/srv/ganeti/os'"])
  51 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  52
  53 # --with-xen-kernel=...
  54 AC_ARG_WITH([xen-kernel],
  55   [AS_HELP_STRING([--with-xen-kernel=PATH],
  56     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-2.6-xenU)]
  57   )],
  58   [xen_kernel="$withval"],
  59   [xen_kernel="/boot/vmlinuz-2.6-xenU"])
  60 AC_SUBST(XEN_KERNEL, $xen_kernel)
  61
  62 # --with-xen-initrd=...
  63 AC_ARG_WITH([xen-initrd],
  64   [AS_HELP_STRING([--with-xen-initrd=PATH],
  65     [DomU initrd image for Xen hypervisor (default is /boot/initrd-2.6-xenU)]
  66   )],
  67   [xen_initrd="$withval"],
  68   [xen_initrd="/boot/initrd-2.6-xenU"])
  69 AC_SUBST(XEN_INITRD, $xen_initrd)
  70
  71 # --with-file-storage-dir=...
  72 AC_ARG_WITH([file-storage-dir],
  73   [AS_HELP_STRING([--with-file-storage-dir=PATH],
  74     [directory to store files for file-based backend]
  75     [ (default is /srv/ganeti/file-storage)]
  76   )],
  77   [file_storage_dir="$withval"],
  78   [file_storage_dir="/srv/ganeti/file-storage"])
  79 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
  80
  81 # Check common programs
  82 AC_PROG_INSTALL
  83 AC_PROG_LN_S
  84
  85 # Check for Python
  86 AM_PATH_PYTHON(2.4)
  87
  88 AC_PYTHON_MODULE(twisted.internet, t)
  89 AC_PYTHON_MODULE(twisted.cred, t)
  90 AC_PYTHON_MODULE(twisted.spread, t)
  91 AC_PYTHON_MODULE(OpenSSL, t)
  92 AC_PYTHON_MODULE(simplejson, t)
  93 AC_PYTHON_MODULE(pyparsing, t)
  94
  95 # Check for docbook2man
  96 found_docbook2man=
  97 AC_CHECK_PROG(found_docbook2man, [docbook2man], [yes])
  98 if test "$found_docbook2man" != "yes"
  99 then
 100   AC_MSG_WARN([docbook2man not found.])
 101 fi
 102
 103 AC_CONFIG_FILES([
 104   Makefile
 105   daemons/Makefile
 106   doc/Makefile
 107   doc/examples/Makefile
 108   lib/Makefile
 109   man/Makefile
 110   qa/Makefile
 111   qa/hooks/Makefile
 112   scripts/Makefile
 113   test/Makefile
 114   tools/Makefile
 115 ])
 116
 117 AC_OUTPUT