code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [6])
   4 m4_define([gnt_version_revision], [2])
   5 m4_define([gnt_version_suffix], [])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-os-search-path=...
  53 # do a bit of black sed magic to for quoting of the strings in the list
  54 AC_ARG_WITH([os-search-path],
  55   [AS_HELP_STRING([--with-os-search-path=LIST],
  56     [comma separated list of directories to]
  57     [ search for OS images (default is /srv/ganeti/os)]
  58   )],
  59   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  60   [os_search_path="'/srv/ganeti/os'"])
  61 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  62
  63 # --with-extstorage-search-path=...
  64 # same black sed magic for quoting of the strings in the list
  65 AC_ARG_WITH([extstorage-search-path],
  66   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  67     [comma separated list of directories to]
  68     [ search for External Storage Providers]
  69     [ (default is /srv/ganeti/extstorage)]
  70   )],
  71   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  72   [es_search_path="'/srv/ganeti/extstorage'"])
  73 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  74
  75 # --with-iallocator-search-path=...
  76 # do a bit of black sed magic to for quoting of the strings in the list
  77 AC_ARG_WITH([iallocator-search-path],
  78   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  79     [comma separated list of directories to]
  80     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  81   )],
  82   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  83   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  84 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  85
  86 # --with-xen-bootloader=...
  87 AC_ARG_WITH([xen-bootloader],
  88   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  89     [bootloader for Xen hypervisor (default is empty)]
  90   )],
  91   [xen_bootloader="$withval"],
  92   [xen_bootloader=])
  93 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
  94
  95 # --with-xen-kernel=...
  96 AC_ARG_WITH([xen-kernel],
  97   [AS_HELP_STRING([--with-xen-kernel=PATH],
  98     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
  99   )],
 100   [xen_kernel="$withval"],
 101   [xen_kernel="/boot/vmlinuz-3-xenU"])
 102 AC_SUBST(XEN_KERNEL, $xen_kernel)
 103
 104 # --with-xen-initrd=...
 105 AC_ARG_WITH([xen-initrd],
 106   [AS_HELP_STRING([--with-xen-initrd=PATH],
 107     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 108   )],
 109   [xen_initrd="$withval"],
 110   [xen_initrd="/boot/initrd-3-xenU"])
 111 AC_SUBST(XEN_INITRD, $xen_initrd)
 112
 113 # --with-xen-cmd=...
 114 AC_ARG_WITH([xen-cmd],
 115   [AS_HELP_STRING([--with-xen-cmd=CMD],
 116     [Sets the xen cli interface command (default is xm)]
 117   )],
 118   [xen_cmd="$withval"],
 119   [xen_cmd=xm])
 120 AC_SUBST(XEN_CMD, $xen_cmd)
 121
 122 if ! test "$XEN_CMD" = xl -o "$XEN_CMD" = xm; then
 123   AC_MSG_ERROR([Unsupported xen command specified])
 124 fi
 125
 126 # --with-kvm-kernel=...
 127 AC_ARG_WITH([kvm-kernel],
 128   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 129     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 130   )],
 131   [kvm_kernel="$withval"],
 132   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 133 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 134
 135 # --with-file-storage-dir=...
 136 AC_ARG_WITH([file-storage-dir],
 137   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 138     [directory to store files for file-based backend]
 139     [ (default is /srv/ganeti/file-storage)]
 140   )],
 141   [[file_storage_dir="$withval";
 142     if test "$withval" != no; then
 143       enable_file_storage=True
 144     else
 145       enable_file_storage=False
 146     fi
 147   ]],
 148   [[file_storage_dir="/srv/ganeti/file-storage";
 149     enable_file_storage=True]])
 150 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 151 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 152
 153 # --with-shared-file-storage-dir=...
 154 AC_ARG_WITH([shared-file-storage-dir],
 155   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 156     [directory to store files for shared file-based backend]
 157     [ (default is /srv/ganeti/shared-file-storage)]
 158   )],
 159   [[shared_file_storage_dir="$withval";
 160     if test "$withval" != no; then
 161       enable_shared_file_storage=True
 162     else
 163       enable_shared_file_storage=False
 164     fi
 165   ]],
 166   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 167     enable_shared_file_storage=True]])
 168 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 169 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 170
 171 # --with-kvm-path=...
 172 AC_ARG_WITH([kvm-path],
 173   [AS_HELP_STRING([--with-kvm-path=PATH],
 174     [absolute path to the kvm binary]
 175     [ (default is /usr/bin/kvm)]
 176   )],
 177   [kvm_path="$withval"],
 178   [kvm_path="/usr/bin/kvm"])
 179 AC_SUBST(KVM_PATH, $kvm_path)
 180
 181 # --with-lvm-stripecount=...
 182 AC_ARG_WITH([lvm-stripecount],
 183   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 184     [the default number of stripes to use for LVM volumes]
 185     [ (default is 1)]
 186   )],
 187   [lvm_stripecount="$withval"],
 188   [lvm_stripecount=1])
 189 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 190
 191 # --with-ssh-login-user=...
 192 AC_ARG_WITH([ssh-login-user],
 193   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 194     [user to use for SSH logins within the cluster (default is root)]
 195   )],
 196   [ssh_login_user="$withval"],
 197   [ssh_login_user=root])
 198 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 199
 200 # --with-ssh-console-user=...
 201 AC_ARG_WITH([ssh-console-user],
 202   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 203     [user to use for SSH logins to access instance consoles (default is root)]
 204   )],
 205   [ssh_console_user="$withval"],
 206   [ssh_console_user=root])
 207 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 208
 209 # --with-default-user=...
 210 AC_ARG_WITH([default-user],
 211   [AS_HELP_STRING([--with-default-user=USERNAME],
 212     [default user for daemons]
 213     [ (default is to run all daemons as root)]
 214   )],
 215   [user_default="$withval"],
 216   [user_default=root])
 217
 218 # --with-default-group=...
 219 AC_ARG_WITH([default-group],
 220   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 221     [default group for daemons]
 222     [ (default is to run all daemons under group root)]
 223   )],
 224   [group_default="$withval"],
 225   [group_default=root])
 226
 227 # --with-user-prefix=...
 228 AC_ARG_WITH([user-prefix],
 229   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 230     [prefix for daemon users]
 231     [ (default is to run all daemons as root; use --with-default-user]
 232     [ to change the default)]
 233   )],
 234   [user_masterd="${withval}masterd";
 235    user_rapi="${withval}rapi";
 236    user_confd="${withval}confd";
 237    user_noded="$user_default"],
 238   [user_masterd="$user_default";
 239    user_rapi="$user_default";
 240    user_confd="$user_default";
 241    user_noded="$user_default"])
 242 AC_SUBST(MASTERD_USER, $user_masterd)
 243 AC_SUBST(RAPI_USER, $user_rapi)
 244 AC_SUBST(CONFD_USER, $user_confd)
 245 AC_SUBST(NODED_USER, $user_noded)
 246
 247 # --with-group-prefix=...
 248 AC_ARG_WITH([group-prefix],
 249   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 250     [prefix for daemon POSIX groups]
 251     [ (default is to run all daemons under group root; use]
 252     [ --with-default-group to change the default)]
 253   )],
 254   [group_rapi="${withval}rapi";
 255    group_admin="${withval}admin";
 256    group_confd="${withval}confd";
 257    group_masterd="${withval}masterd";
 258    group_noded="$group_default";
 259    group_daemons="${withval}daemons";],
 260   [group_rapi="$group_default";
 261    group_admin="$group_default";
 262    group_confd="$group_default";
 263    group_masterd="$group_default";
 264    group_noded="$group_default";
 265    group_daemons="$group_default"])
 266 AC_SUBST(RAPI_GROUP, $group_rapi)
 267 AC_SUBST(ADMIN_GROUP, $group_admin)
 268 AC_SUBST(CONFD_GROUP, $group_confd)
 269 AC_SUBST(MASTERD_GROUP, $group_masterd)
 270 AC_SUBST(NODED_GROUP, $group_noded)
 271 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 272
 273 # Print the config to the user
 274 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 275 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 276 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 277 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 278 AC_MSG_NOTICE([Group for clients is $group_admin])
 279
 280 # --enable-drbd-barriers
 281 AC_ARG_ENABLE([drbd-barriers],
 282   [AS_HELP_STRING([--enable-drbd-barriers],
 283                   m4_normalize([enable the DRBD barriers functionality by
 284                                 default (>= 8.0.12) (default: enabled)]))],
 285   [[if test "$enableval" != no; then
 286       DRBD_BARRIERS=n
 287       DRBD_NO_META_FLUSH=False
 288     else
 289       DRBD_BARRIERS=bf
 290       DRBD_NO_META_FLUSH=True
 291     fi
 292   ]],
 293   [DRBD_BARRIERS=n
 294    DRBD_NO_META_FLUSH=False
 295   ])
 296 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 297 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 298
 299 # --enable-syslog[=no/yes/only]
 300 AC_ARG_ENABLE([syslog],
 301   [AS_HELP_STRING([--enable-syslog],
 302     [enable use of syslog (default: disabled), one of no/yes/only])],
 303   [[case "$enableval" in
 304       no)
 305         SYSLOG=no
 306         ;;
 307       yes)
 308         SYSLOG=yes
 309         ;;
 310       only)
 311         SYSLOG=only
 312         ;;
 313       *)
 314         SYSLOG=
 315         ;;
 316     esac
 317   ]],
 318   [SYSLOG=no])
 319
 320 if test -z "$SYSLOG"
 321 then
 322   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 323 fi
 324 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 325
 326 AC_ARG_ENABLE([restricted-commands],
 327   [AS_HELP_STRING([--enable-restricted-commands],
 328                   m4_normalize([enable restricted commands in the node daemon
 329                                 (default: disabled)]))],
 330   [[if test "$enableval" = no; then
 331       enable_restricted_commands=False
 332     else
 333       enable_restricted_commands=True
 334     fi
 335   ]],
 336   [enable_restricted_commands=False])
 337 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 338
 339 # --with-disk-separator=...
 340 AC_ARG_WITH([disk-separator],
 341   [AS_HELP_STRING([--with-disk-separator=STRING],
 342     [Disk index separator, useful if the default of ':' is handled]
 343     [ specially by the hypervisor]
 344   )],
 345   [disk_separator="$withval"],
 346   [disk_separator=":"])
 347 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 348
 349 # Check common programs
 350 AC_PROG_INSTALL
 351 AC_PROG_LN_S
 352
 353 # Check for the ip command
 354 AC_ARG_VAR(IP_PATH, [ip path])
 355 AC_PATH_PROG(IP_PATH, [ip], [])
 356 if test -z "$IP_PATH"
 357 then
 358   AC_MSG_ERROR([ip command not found])
 359 fi
 360
 361 # Check for pandoc
 362 AC_ARG_VAR(PANDOC, [pandoc path])
 363 AC_PATH_PROG(PANDOC, [pandoc], [])
 364 if test -z "$PANDOC"
 365 then
 366   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 367 fi
 368
 369 # Check for python-sphinx
 370 AC_ARG_VAR(SPHINX, [sphinx-build path])
 371 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 372 if test -z "$SPHINX"
 373 then
 374   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 375                             not be possible]))
 376 fi
 377
 378 # Check for graphviz (dot)
 379 AC_ARG_VAR(DOT, [dot path])
 380 AC_PATH_PROG(DOT, [dot], [])
 381 if test -z "$DOT"
 382 then
 383   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 384                             documentation rebuild not possible]))
 385 fi
 386
 387 # Check for pylint
 388 AC_ARG_VAR(PYLINT, [pylint path])
 389 AC_PATH_PROG(PYLINT, [pylint], [])
 390 if test -z "$PYLINT"
 391 then
 392   AC_MSG_WARN([pylint not found, checking code will not be possible])
 393 fi
 394
 395 # Check for pep8
 396 AC_ARG_VAR(PEP8, [pep8 path])
 397 AC_PATH_PROG(PEP8, [pep8], [])
 398 if test -z "$PEP8"
 399 then
 400   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 401 fi
 402 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 403
 404 # Check for python-coverage
 405 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 406 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 407 if test -z "$PYCOVERAGE"
 408 then
 409   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 410                             Python test coverage will not be possible]))
 411 fi
 412
 413 # Check for socat
 414 AC_ARG_VAR(SOCAT, [socat path])
 415 AC_PATH_PROG(SOCAT, [socat], [])
 416 if test -z "$SOCAT"
 417 then
 418   AC_MSG_ERROR([socat not found])
 419 fi
 420
 421 # Check for qemu-img
 422 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 423 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 424 if test -z "$QEMUIMG_PATH"
 425 then
 426   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 427 fi
 428
 429 # --enable-htools-rapi
 430 HTOOLS_RAPI=
 431 AC_ARG_ENABLE([htools-rapi],
 432         [AS_HELP_STRING([--enable-htools-rapi],
 433         [enable use of curl in the Haskell code (default: check)])],
 434         [],
 435         [enable_htools_rapi=check])
 436
 437 # --enable-confd
 438 ENABLE_CONFD=
 439 AC_ARG_ENABLE([confd],
 440   [AS_HELP_STRING([--enable-confd],
 441   [enable the ganeti-confd daemon (default: check)])],
 442   [],
 443   [enable_confd=check])
 444
 445 ENABLE_MONITORING=
 446 AC_ARG_ENABLE([monitoring],
 447   [AS_HELP_STRING([--enable-monitoring],
 448   [enable the ganeti monitoring agent (default: check)])],
 449   [],
 450   [enable_monitoring=check])
 451
 452 # Check for ghc
 453 AC_ARG_VAR(GHC, [ghc path])
 454 AC_PATH_PROG(GHC, [ghc], [])
 455 if test -z "$GHC"; then
 456   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 457 fi
 458
 459 AC_MSG_CHECKING([checking for extra GHC flags])
 460 GHC_BYVERSION_FLAGS=
 461 # check for GHC supported flags that vary accross versions
 462 for flag in -fwarn-incomplete-uni-patterns; do
 463   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 464    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 465   fi
 466 done
 467 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 468 AC_SUBST(GHC_BYVERSION_FLAGS)
 469
 470 # Check for ghc-pkg
 471 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 472 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 473 if test -z "$GHC_PKG"; then
 474   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 475 fi
 476
 477 # check for modules, first custom/special checks
 478 AC_MSG_NOTICE([checking for required haskell modules])
 479 HS_NOCURL=-DNO_CURL
 480 if test "$enable_htools_rapi" != no; then
 481   AC_GHC_PKG_CHECK([curl], [HS_NOCURL=], [])
 482   if test -n "$HS_NOCURL"; then
 483     if test "$enable_htools_rapi" = check; then
 484       AC_MSG_WARN(m4_normalize([The curl library was not found, Haskell
 485                                 code will be compiled without RAPI support]))
 486     else
 487       AC_MSG_FAILURE(m4_normalize([The curl library was not found, but it has
 488                                    been requested]))
 489     fi
 490   else
 491     AC_MSG_NOTICE([Enabling curl/RAPI/RPC usage in Haskell code])
 492   fi
 493 fi
 494 AC_SUBST(HS_NOCURL)
 495
 496 HS_PARALLEL3=
 497 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 498                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 499 AC_SUBST(HS_PARALLEL3)
 500
 501 # and now standard modules
 502 AC_GHC_PKG_REQUIRE(json)
 503 AC_GHC_PKG_REQUIRE(network)
 504 AC_GHC_PKG_REQUIRE(mtl)
 505 AC_GHC_PKG_REQUIRE(bytestring)
 506 AC_GHC_PKG_REQUIRE(utf8-string)
 507
 508 # extra modules for confd functionality
 509 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 510 has_confd=False
 511 if test "$enable_confd" != no; then
 512   CONFD_PKG=
 513   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 514                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 515   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 516   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 517   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 518   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 519   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 520   if test -z "$CONFD_PKG"; then
 521     has_confd=True
 522   elif test "$enable_confd" = check; then
 523     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 524                               not found ($CONFD_PKG), confd disabled]))
 525   else
 526     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 527                                  required libraries were not found:
 528                                  $CONFD_PKG]))
 529   fi
 530 fi
 531 AC_SUBST(HS_REGEX_PCRE)
 532 if test "$has_confd" = True; then
 533   AC_MSG_NOTICE([Enabling confd usage])
 534 fi
 535 AC_SUBST(ENABLE_CONFD, $has_confd)
 536 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 537
 538 #extra modules for monitoring agent functionality
 539 has_monitoring=False
 540 if test "$enable_monitoring" != no; then
 541   MONITORING_PKG=
 542   AC_GHC_PKG_CHECK([attoparsec], [],
 543                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 544   if test -z "$MONITORING_PKG"; then
 545     has_monitoring=True
 546   elif test "$enable_monitoring" = check; then
 547     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 548                               agent were not found ($MONITORING_PKG),
 549                               monitoring disabled]))
 550   else
 551     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 552                                  required libraries were not found:
 553                                  $MONITORING_PKG]))
 554   fi
 555 fi
 556 if test "$has_monitoring" = True; then
 557   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 558 fi
 559 AC_SUBST(ENABLE_MONITORING, $has_monitoring)
 560 AM_CONDITIONAL([ENABLE_MONITORING], [test "$has_monitoring" = True])
 561
 562 # development modules
 563 HS_NODEV=
 564 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 565 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 566 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 567 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 568 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 569 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 570 #        that are needed to execute the tests, avoiding the duplication
 571 #        of the checks.
 572 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 573 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 574 if test -n "$HS_NODEV"; then
 575    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 576                              you won't be able to run Haskell unittests]))
 577 else
 578    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 579 fi
 580 AC_SUBST(HS_NODEV)
 581
 582 HTOOLS=yes
 583 AC_SUBST(HTOOLS)
 584
 585 # --enable-split-query
 586 ENABLE_SPLIT_QUERY=
 587 AC_ARG_ENABLE([split-query],
 588   [AS_HELP_STRING([--enable-split-query],
 589   [enable use of custom query daemon via confd])],
 590   [[case "$enableval" in
 591       no)
 592         enable_split_query=False
 593         ;;
 594       yes)
 595         enable_split_query=True
 596         ;;
 597       *)
 598         echo "Invalid value for enable-confd '$enableval'"
 599         exit 1
 600         ;;
 601     esac
 602   ]],
 603   [[case "x${has_confd}x${HS_NOCURL}x" in
 604      xTruexx)
 605        enable_split_query=True
 606        ;;
 607      *)
 608        enable_split_query=False
 609        ;;
 610    esac]])
 611 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 612
 613 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 614   AC_MSG_ERROR([Split queries require the confd daemon])
 615 fi
 616
 617 if test x$enable_split_query = xTrue -a x$HS_NOCURL != x; then
 618   AC_MSG_ERROR([Split queries require the htools-rapi feature (curl library)])
 619 fi
 620
 621 if test x$enable_split_query = xTrue; then
 622   AC_MSG_NOTICE([Split query functionality enabled])
 623 fi
 624
 625 # Check for HsColour
 626 HS_APIDOC=no
 627 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 628 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 629 if test -z "$HSCOLOUR"; then
 630   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 631                             not be generated]))
 632 fi
 633
 634 # Check for haddock
 635 AC_ARG_VAR(HADDOCK, [haddock path])
 636 AC_PATH_PROG(HADDOCK, [haddock], [])
 637 if test -z "$HADDOCK"; then
 638   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 639                             not be generated]))
 640 fi
 641 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 642   HS_APIDOC=yes
 643 fi
 644 AC_SUBST(HS_APIDOC)
 645
 646 # Check for hlint
 647 AC_ARG_VAR(HLINT, [hlint path])
 648 AC_PATH_PROG(HLINT, [hlint], [])
 649 if test -z "$HLINT"; then
 650   AC_MSG_WARN([hlint not found, checking code will not be possible])
 651 fi
 652
 653 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 654   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 655                              htools support is not enabled]))
 656 fi
 657
 658 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 659 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 660 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 661 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 662
 663 # Check for fakeroot
 664 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 665 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 666 if test -z "$FAKEROOT_PATH"; then
 667   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 668                             will not be executed]))
 669 fi
 670 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 671
 672 SOCAT_USE_ESCAPE=
 673 AC_ARG_ENABLE([socat-escape],
 674   [AS_HELP_STRING([--enable-socat-escape],
 675     [use escape functionality available in socat >= 1.7 (default: detect
 676      automatically)])],
 677   [[if test "$enableval" = yes; then
 678       SOCAT_USE_ESCAPE=True
 679     else
 680       SOCAT_USE_ESCAPE=False
 681     fi
 682   ]])
 683
 684 if test -z "$SOCAT_USE_ESCAPE"
 685 then
 686   if $SOCAT -hh | grep -w -q escape; then
 687     SOCAT_USE_ESCAPE=True
 688   else
 689     SOCAT_USE_ESCAPE=False
 690   fi
 691 fi
 692
 693 AC_SUBST(SOCAT_USE_ESCAPE)
 694
 695 SOCAT_USE_COMPRESS=
 696 AC_ARG_ENABLE([socat-compress],
 697   [AS_HELP_STRING([--enable-socat-compress],
 698     [use OpenSSL compression option available in patched socat builds
 699      (see INSTALL for details; default: detect automatically)])],
 700   [[if test "$enableval" = yes; then
 701       SOCAT_USE_COMPRESS=True
 702     else
 703       SOCAT_USE_COMPRESS=False
 704     fi
 705   ]])
 706
 707 if test -z "$SOCAT_USE_COMPRESS"
 708 then
 709   if $SOCAT -hhh | grep -w -q openssl-compress; then
 710     SOCAT_USE_COMPRESS=True
 711   else
 712     SOCAT_USE_COMPRESS=False
 713   fi
 714 fi
 715
 716 AC_SUBST(SOCAT_USE_COMPRESS)
 717
 718 if man --help | grep -q -e --warnings
 719 then
 720   MAN_HAS_WARNINGS=1
 721 else
 722   MAN_HAS_WARNINGS=
 723   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 724                             will not be possible]))
 725 fi
 726
 727 AC_SUBST(MAN_HAS_WARNINGS)
 728
 729 # Check for Python
 730 AM_PATH_PYTHON(2.4)
 731
 732 AC_PYTHON_MODULE(OpenSSL, t)
 733 AC_PYTHON_MODULE(simplejson, t)
 734 AC_PYTHON_MODULE(pyparsing, t)
 735 AC_PYTHON_MODULE(pyinotify, t)
 736 AC_PYTHON_MODULE(pycurl, t)
 737 AC_PYTHON_MODULE(bitarray, t)
 738 AC_PYTHON_MODULE(ipaddr, t)
 739 AC_PYTHON_MODULE(affinity)
 740 AC_PYTHON_MODULE(paramiko)
 741
 742 AC_CONFIG_FILES([ Makefile ])
 743
 744 AC_OUTPUT