code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [7])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-xen-config-dir=...
  53 AC_ARG_WITH([xen-config-dir],
  54   [AS_HELP_STRING([--with-xen-config-dir=DIR],
  55                   m4_normalize([Xen configuration directory
  56                                 (default: /etc/xen)]))],
  57   [xen_config_dir="$withval"],
  58   [xen_config_dir=/etc/xen])
  59 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
  60
  61 # --with-os-search-path=...
  62 # do a bit of black sed magic to for quoting of the strings in the list
  63 AC_ARG_WITH([os-search-path],
  64   [AS_HELP_STRING([--with-os-search-path=LIST],
  65     [comma separated list of directories to]
  66     [ search for OS images (default is /srv/ganeti/os)]
  67   )],
  68   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  69   [os_search_path="'/srv/ganeti/os'"])
  70 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  71
  72 # --with-extstorage-search-path=...
  73 # same black sed magic for quoting of the strings in the list
  74 AC_ARG_WITH([extstorage-search-path],
  75   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  76     [comma separated list of directories to]
  77     [ search for External Storage Providers]
  78     [ (default is /srv/ganeti/extstorage)]
  79   )],
  80   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  81   [es_search_path="'/srv/ganeti/extstorage'"])
  82 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  83
  84 # --with-iallocator-search-path=...
  85 # do a bit of black sed magic to for quoting of the strings in the list
  86 AC_ARG_WITH([iallocator-search-path],
  87   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  88     [comma separated list of directories to]
  89     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  90   )],
  91   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  92   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  93 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  94
  95 # --with-xen-bootloader=...
  96 AC_ARG_WITH([xen-bootloader],
  97   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  98     [bootloader for Xen hypervisor (default is empty)]
  99   )],
 100   [xen_bootloader="$withval"],
 101   [xen_bootloader=])
 102 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
 103
 104 # --with-xen-kernel=...
 105 AC_ARG_WITH([xen-kernel],
 106   [AS_HELP_STRING([--with-xen-kernel=PATH],
 107     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
 108   )],
 109   [xen_kernel="$withval"],
 110   [xen_kernel="/boot/vmlinuz-3-xenU"])
 111 AC_SUBST(XEN_KERNEL, $xen_kernel)
 112
 113 # --with-xen-initrd=...
 114 AC_ARG_WITH([xen-initrd],
 115   [AS_HELP_STRING([--with-xen-initrd=PATH],
 116     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 117   )],
 118   [xen_initrd="$withval"],
 119   [xen_initrd="/boot/initrd-3-xenU"])
 120 AC_SUBST(XEN_INITRD, $xen_initrd)
 121
 122 # --with-xen-cmd=...
 123 AC_ARG_WITH([xen-cmd],
 124   [AS_HELP_STRING([--with-xen-cmd=CMD],
 125     [Sets the xen cli interface command (default is xm)]
 126   )],
 127   [xen_cmd="$withval"],
 128   [xen_cmd=xm])
 129 AC_SUBST(XEN_CMD, $xen_cmd)
 130
 131 if ! test "$XEN_CMD" = xl -o "$XEN_CMD" = xm; then
 132   AC_MSG_ERROR([Unsupported xen command specified])
 133 fi
 134
 135 # --with-kvm-kernel=...
 136 AC_ARG_WITH([kvm-kernel],
 137   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 138     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 139   )],
 140   [kvm_kernel="$withval"],
 141   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 142 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 143
 144 # --with-file-storage-dir=...
 145 AC_ARG_WITH([file-storage-dir],
 146   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 147     [directory to store files for file-based backend]
 148     [ (default is /srv/ganeti/file-storage)]
 149   )],
 150   [[file_storage_dir="$withval";
 151     if test "$withval" != no; then
 152       enable_file_storage=True
 153     else
 154       enable_file_storage=False
 155     fi
 156   ]],
 157   [[file_storage_dir="/srv/ganeti/file-storage";
 158     enable_file_storage=True]])
 159 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 160 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 161
 162 # --with-shared-file-storage-dir=...
 163 AC_ARG_WITH([shared-file-storage-dir],
 164   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 165     [directory to store files for shared file-based backend]
 166     [ (default is /srv/ganeti/shared-file-storage)]
 167   )],
 168   [[shared_file_storage_dir="$withval";
 169     if test "$withval" != no; then
 170       enable_shared_file_storage=True
 171     else
 172       enable_shared_file_storage=False
 173     fi
 174   ]],
 175   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 176     enable_shared_file_storage=True]])
 177 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 178 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 179
 180 # --with-kvm-path=...
 181 AC_ARG_WITH([kvm-path],
 182   [AS_HELP_STRING([--with-kvm-path=PATH],
 183     [absolute path to the kvm binary]
 184     [ (default is /usr/bin/kvm)]
 185   )],
 186   [kvm_path="$withval"],
 187   [kvm_path="/usr/bin/kvm"])
 188 AC_SUBST(KVM_PATH, $kvm_path)
 189
 190 # --with-lvm-stripecount=...
 191 AC_ARG_WITH([lvm-stripecount],
 192   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 193     [the default number of stripes to use for LVM volumes]
 194     [ (default is 1)]
 195   )],
 196   [lvm_stripecount="$withval"],
 197   [lvm_stripecount=1])
 198 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 199
 200 # --with-ssh-login-user=...
 201 AC_ARG_WITH([ssh-login-user],
 202   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 203     [user to use for SSH logins within the cluster (default is root)]
 204   )],
 205   [ssh_login_user="$withval"],
 206   [ssh_login_user=root])
 207 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 208
 209 # --with-ssh-console-user=...
 210 AC_ARG_WITH([ssh-console-user],
 211   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 212     [user to use for SSH logins to access instance consoles (default is root)]
 213   )],
 214   [ssh_console_user="$withval"],
 215   [ssh_console_user=root])
 216 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 217
 218 # --with-default-user=...
 219 AC_ARG_WITH([default-user],
 220   [AS_HELP_STRING([--with-default-user=USERNAME],
 221     [default user for daemons]
 222     [ (default is to run all daemons as root)]
 223   )],
 224   [user_default="$withval"],
 225   [user_default=root])
 226
 227 # --with-default-group=...
 228 AC_ARG_WITH([default-group],
 229   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 230     [default group for daemons]
 231     [ (default is to run all daemons under group root)]
 232   )],
 233   [group_default="$withval"],
 234   [group_default=root])
 235
 236 # --with-user-prefix=...
 237 AC_ARG_WITH([user-prefix],
 238   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 239     [prefix for daemon users]
 240     [ (default is to run all daemons as root; use --with-default-user]
 241     [ to change the default)]
 242   )],
 243   [user_masterd="${withval}masterd";
 244    user_rapi="${withval}rapi";
 245    user_confd="${withval}confd";
 246    user_noded="$user_default"],
 247   [user_masterd="$user_default";
 248    user_rapi="$user_default";
 249    user_confd="$user_default";
 250    user_noded="$user_default"])
 251 AC_SUBST(MASTERD_USER, $user_masterd)
 252 AC_SUBST(RAPI_USER, $user_rapi)
 253 AC_SUBST(CONFD_USER, $user_confd)
 254 AC_SUBST(NODED_USER, $user_noded)
 255
 256 # --with-group-prefix=...
 257 AC_ARG_WITH([group-prefix],
 258   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 259     [prefix for daemon POSIX groups]
 260     [ (default is to run all daemons under group root; use]
 261     [ --with-default-group to change the default)]
 262   )],
 263   [group_rapi="${withval}rapi";
 264    group_admin="${withval}admin";
 265    group_confd="${withval}confd";
 266    group_masterd="${withval}masterd";
 267    group_noded="$group_default";
 268    group_daemons="${withval}daemons";],
 269   [group_rapi="$group_default";
 270    group_admin="$group_default";
 271    group_confd="$group_default";
 272    group_masterd="$group_default";
 273    group_noded="$group_default";
 274    group_daemons="$group_default"])
 275 AC_SUBST(RAPI_GROUP, $group_rapi)
 276 AC_SUBST(ADMIN_GROUP, $group_admin)
 277 AC_SUBST(CONFD_GROUP, $group_confd)
 278 AC_SUBST(MASTERD_GROUP, $group_masterd)
 279 AC_SUBST(NODED_GROUP, $group_noded)
 280 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 281
 282 # Print the config to the user
 283 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 284 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 285 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 286 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 287 AC_MSG_NOTICE([Group for clients is $group_admin])
 288
 289 # --enable-drbd-barriers
 290 AC_ARG_ENABLE([drbd-barriers],
 291   [AS_HELP_STRING([--enable-drbd-barriers],
 292                   m4_normalize([enable the DRBD barriers functionality by
 293                                 default (>= 8.0.12) (default: enabled)]))],
 294   [[if test "$enableval" != no; then
 295       DRBD_BARRIERS=n
 296       DRBD_NO_META_FLUSH=False
 297     else
 298       DRBD_BARRIERS=bf
 299       DRBD_NO_META_FLUSH=True
 300     fi
 301   ]],
 302   [DRBD_BARRIERS=n
 303    DRBD_NO_META_FLUSH=False
 304   ])
 305 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 306 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 307
 308 # --enable-syslog[=no/yes/only]
 309 AC_ARG_ENABLE([syslog],
 310   [AS_HELP_STRING([--enable-syslog],
 311     [enable use of syslog (default: disabled), one of no/yes/only])],
 312   [[case "$enableval" in
 313       no)
 314         SYSLOG=no
 315         ;;
 316       yes)
 317         SYSLOG=yes
 318         ;;
 319       only)
 320         SYSLOG=only
 321         ;;
 322       *)
 323         SYSLOG=
 324         ;;
 325     esac
 326   ]],
 327   [SYSLOG=no])
 328
 329 if test -z "$SYSLOG"
 330 then
 331   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 332 fi
 333 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 334
 335 AC_ARG_ENABLE([restricted-commands],
 336   [AS_HELP_STRING([--enable-restricted-commands],
 337                   m4_normalize([enable restricted commands in the node daemon
 338                                 (default: disabled)]))],
 339   [[if test "$enableval" = no; then
 340       enable_restricted_commands=False
 341     else
 342       enable_restricted_commands=True
 343     fi
 344   ]],
 345   [enable_restricted_commands=False])
 346 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 347
 348 # --with-disk-separator=...
 349 AC_ARG_WITH([disk-separator],
 350   [AS_HELP_STRING([--with-disk-separator=STRING],
 351     [Disk index separator, useful if the default of ':' is handled]
 352     [ specially by the hypervisor]
 353   )],
 354   [disk_separator="$withval"],
 355   [disk_separator=":"])
 356 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 357
 358 # Check common programs
 359 AC_PROG_INSTALL
 360 AC_PROG_LN_S
 361
 362 # Check for the ip command
 363 AC_ARG_VAR(IP_PATH, [ip path])
 364 AC_PATH_PROG(IP_PATH, [ip], [])
 365 if test -z "$IP_PATH"
 366 then
 367   AC_MSG_ERROR([ip command not found])
 368 fi
 369
 370 # Check for pandoc
 371 AC_ARG_VAR(PANDOC, [pandoc path])
 372 AC_PATH_PROG(PANDOC, [pandoc], [])
 373 if test -z "$PANDOC"
 374 then
 375   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 376 fi
 377
 378 # Check for python-sphinx
 379 AC_ARG_VAR(SPHINX, [sphinx-build path])
 380 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 381 if test -z "$SPHINX"
 382 then
 383   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 384                             not be possible]))
 385 else
 386   # Sphinx exits with code 1 when it prints its usage
 387   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
 388
 389   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
 390     AC_MSG_ERROR([Unable to determine Sphinx version])
 391
 392   # Note: Character classes ([...]) need to be double quoted due to autoconf
 393   # using m4
 394   elif ! echo "$sphinxver" | grep -q -E '^Sphinx[[[:space:]]]+v[[1-9]]\>'; then
 395     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
 396   fi
 397 fi
 398
 399 AC_ARG_ENABLE([manpages-in-doc],
 400   [AS_HELP_STRING([--enable-manpages-in-doc],
 401                   m4_normalize([include man pages in HTML documentation
 402                                 (requires sphinx; default disabled)]))],
 403   [case "$enableval" in
 404       yes) manpages_in_doc=yes ;;
 405       no) manpages_in_doc= ;;
 406       *)
 407         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 408         ;;
 409     esac
 410   ],
 411   [manpages_in_doc=])
 412 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 413 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 414
 415 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 416   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 417 fi
 418
 419 # Check for graphviz (dot)
 420 AC_ARG_VAR(DOT, [dot path])
 421 AC_PATH_PROG(DOT, [dot], [])
 422 if test -z "$DOT"
 423 then
 424   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 425                             documentation rebuild not possible]))
 426 fi
 427
 428 # Check for pylint
 429 AC_ARG_VAR(PYLINT, [pylint path])
 430 AC_PATH_PROG(PYLINT, [pylint], [])
 431 if test -z "$PYLINT"
 432 then
 433   AC_MSG_WARN([pylint not found, checking code will not be possible])
 434 fi
 435
 436 # Check for pep8
 437 AC_ARG_VAR(PEP8, [pep8 path])
 438 AC_PATH_PROG(PEP8, [pep8], [])
 439 if test -z "$PEP8"
 440 then
 441   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 442 fi
 443 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 444
 445 # Check for python-coverage
 446 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 447 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 448 if test -z "$PYCOVERAGE"
 449 then
 450   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 451                             Python test coverage will not be possible]))
 452 fi
 453
 454 # Check for socat
 455 AC_ARG_VAR(SOCAT, [socat path])
 456 AC_PATH_PROG(SOCAT, [socat], [])
 457 if test -z "$SOCAT"
 458 then
 459   AC_MSG_ERROR([socat not found])
 460 fi
 461
 462 # Check for qemu-img
 463 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 464 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 465 if test -z "$QEMUIMG_PATH"
 466 then
 467   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 468 fi
 469
 470 # --enable-htools-rapi
 471 HTOOLS_RAPI=
 472 AC_ARG_ENABLE([htools-rapi],
 473         [AS_HELP_STRING([--enable-htools-rapi],
 474         [enable use of curl in the Haskell code (default: check)])],
 475         [],
 476         [enable_htools_rapi=check])
 477
 478 # --enable-confd
 479 ENABLE_CONFD=
 480 AC_ARG_ENABLE([confd],
 481   [AS_HELP_STRING([--enable-confd],
 482   [enable the ganeti-confd daemon (default: check)])],
 483   [],
 484   [enable_confd=check])
 485
 486 ENABLE_MONITORING=
 487 AC_ARG_ENABLE([monitoring],
 488   [AS_HELP_STRING([--enable-monitoring],
 489   [enable the ganeti monitoring agent (default: check)])],
 490   [],
 491   [enable_monitoring=check])
 492
 493 # Check for ghc
 494 AC_ARG_VAR(GHC, [ghc path])
 495 AC_PATH_PROG(GHC, [ghc], [])
 496 if test -z "$GHC"; then
 497   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 498 fi
 499
 500 AC_MSG_CHECKING([checking for extra GHC flags])
 501 GHC_BYVERSION_FLAGS=
 502 # check for GHC supported flags that vary accross versions
 503 for flag in -fwarn-incomplete-uni-patterns; do
 504   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 505    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 506   fi
 507 done
 508 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 509 AC_SUBST(GHC_BYVERSION_FLAGS)
 510
 511 # Check for ghc-pkg
 512 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 513 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 514 if test -z "$GHC_PKG"; then
 515   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 516 fi
 517
 518 # check for modules, first custom/special checks
 519 AC_MSG_NOTICE([checking for required haskell modules])
 520 HS_NOCURL=-DNO_CURL
 521 if test "$enable_htools_rapi" != no; then
 522   AC_GHC_PKG_CHECK([curl], [HS_NOCURL=], [])
 523   if test -n "$HS_NOCURL"; then
 524     if test "$enable_htools_rapi" = check; then
 525       AC_MSG_WARN(m4_normalize([The curl library was not found, Haskell
 526                                 code will be compiled without RAPI support]))
 527     else
 528       AC_MSG_FAILURE(m4_normalize([The curl library was not found, but it has
 529                                    been requested]))
 530     fi
 531   else
 532     AC_MSG_NOTICE([Enabling curl/RAPI/RPC usage in Haskell code])
 533   fi
 534 fi
 535 AC_SUBST(HS_NOCURL)
 536
 537 HS_PARALLEL3=
 538 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 539                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 540 AC_SUBST(HS_PARALLEL3)
 541
 542 # and now standard modules
 543 AC_GHC_PKG_REQUIRE(json)
 544 AC_GHC_PKG_REQUIRE(network)
 545 AC_GHC_PKG_REQUIRE(mtl)
 546 AC_GHC_PKG_REQUIRE(bytestring)
 547 AC_GHC_PKG_REQUIRE(utf8-string)
 548
 549 # extra modules for confd functionality
 550 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 551 has_confd=False
 552 if test "$enable_confd" != no; then
 553   CONFD_PKG=
 554   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 555                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 556   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 557   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 558   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 559   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 560   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 561   if test -z "$CONFD_PKG"; then
 562     has_confd=True
 563   elif test "$enable_confd" = check; then
 564     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 565                               not found ($CONFD_PKG), confd disabled]))
 566   else
 567     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 568                                  required libraries were not found:
 569                                  $CONFD_PKG]))
 570   fi
 571 fi
 572 AC_SUBST(HS_REGEX_PCRE)
 573 if test "$has_confd" = True; then
 574   AC_MSG_NOTICE([Enabling confd usage])
 575 fi
 576 AC_SUBST(ENABLE_CONFD, $has_confd)
 577 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 578
 579 #extra modules for monitoring agent functionality
 580 has_monitoring=False
 581 if test "$enable_monitoring" != no; then
 582   MONITORING_PKG=
 583   AC_GHC_PKG_CHECK([attoparsec], [],
 584                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 585   MONITORING_DEP=
 586   if test "$has_confd" = False; then
 587     MONITORING_DEP="$MONITORING_DEP confd"
 588   fi
 589   has_monitoring_pkg=False
 590   if test -z "$MONITORING_PKG"; then
 591     has_monitoring_pkg=True
 592   elif test "$enable_monitoring" = check; then
 593     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 594                               agent were not found ($MONITORING_PKG),
 595                               monitoring disabled]))
 596   else
 597     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 598                                  required libraries were not found:
 599                                  $MONITORING_PKG]))
 600   fi
 601   has_monitoring_dep=False
 602   if test -z "$MONITORING_DEP"; then
 603     has_monitoring_dep=True
 604   elif test "$enable_monitoring" = check; then
 605     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
 606                               monitoring agent were not enabled
 607                               ($MONITORING_DEP), monitoring disabled]))
 608   else
 609     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 610                                  required optional Ganeti components were not
 611                                  found: $MONITORING_DEP]))
 612   fi
 613
 614 fi
 615 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
 616   has_monitoring=True
 617   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 618 fi
 619 AC_SUBST(ENABLE_MONITORING, $has_monitoring)
 620 AM_CONDITIONAL([ENABLE_MONITORING], [test "$has_monitoring" = True])
 621
 622 # development modules
 623 HS_NODEV=
 624 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 625 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 626 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 627 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 628 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 629 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 630 #        that are needed to execute the tests, avoiding the duplication
 631 #        of the checks.
 632 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 633 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 634 if test -n "$HS_NODEV"; then
 635    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 636                              you won't be able to run Haskell unittests]))
 637 else
 638    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 639 fi
 640 AC_SUBST(HS_NODEV)
 641
 642 HTOOLS=yes
 643 AC_SUBST(HTOOLS)
 644
 645 # --enable-split-query
 646 ENABLE_SPLIT_QUERY=
 647 AC_ARG_ENABLE([split-query],
 648   [AS_HELP_STRING([--enable-split-query],
 649   [enable use of custom query daemon via confd])],
 650   [[case "$enableval" in
 651       no)
 652         enable_split_query=False
 653         ;;
 654       yes)
 655         enable_split_query=True
 656         ;;
 657       *)
 658         echo "Invalid value for enable-confd '$enableval'"
 659         exit 1
 660         ;;
 661     esac
 662   ]],
 663   [[case "x${has_confd}x${HS_NOCURL}x" in
 664      xTruexx)
 665        enable_split_query=True
 666        ;;
 667      *)
 668        enable_split_query=False
 669        ;;
 670    esac]])
 671 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 672
 673 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 674   AC_MSG_ERROR([Split queries require the confd daemon])
 675 fi
 676
 677 if test x$enable_split_query = xTrue -a x$HS_NOCURL != x; then
 678   AC_MSG_ERROR([Split queries require the htools-rapi feature (curl library)])
 679 fi
 680
 681 if test x$enable_split_query = xTrue; then
 682   AC_MSG_NOTICE([Split query functionality enabled])
 683 fi
 684
 685 # Check for HsColour
 686 HS_APIDOC=no
 687 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 688 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 689 if test -z "$HSCOLOUR"; then
 690   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 691                             not be generated]))
 692 fi
 693
 694 # Check for haddock
 695 AC_ARG_VAR(HADDOCK, [haddock path])
 696 AC_PATH_PROG(HADDOCK, [haddock], [])
 697 if test -z "$HADDOCK"; then
 698   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 699                             not be generated]))
 700 fi
 701 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 702   HS_APIDOC=yes
 703 fi
 704 AC_SUBST(HS_APIDOC)
 705
 706 # Check for hlint
 707 AC_ARG_VAR(HLINT, [hlint path])
 708 AC_PATH_PROG(HLINT, [hlint], [])
 709 if test -z "$HLINT"; then
 710   AC_MSG_WARN([hlint not found, checking code will not be possible])
 711 fi
 712
 713 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 714   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 715                              htools support is not enabled]))
 716 fi
 717
 718 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 719 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 720 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 721 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 722
 723 # Check for fakeroot
 724 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 725 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 726 if test -z "$FAKEROOT_PATH"; then
 727   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 728                             will not be executed]))
 729 fi
 730 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 731
 732 SOCAT_USE_ESCAPE=
 733 AC_ARG_ENABLE([socat-escape],
 734   [AS_HELP_STRING([--enable-socat-escape],
 735     [use escape functionality available in socat >= 1.7 (default: detect
 736      automatically)])],
 737   [[if test "$enableval" = yes; then
 738       SOCAT_USE_ESCAPE=True
 739     else
 740       SOCAT_USE_ESCAPE=False
 741     fi
 742   ]])
 743
 744 if test -z "$SOCAT_USE_ESCAPE"
 745 then
 746   if $SOCAT -hh | grep -w -q escape; then
 747     SOCAT_USE_ESCAPE=True
 748   else
 749     SOCAT_USE_ESCAPE=False
 750   fi
 751 fi
 752
 753 AC_SUBST(SOCAT_USE_ESCAPE)
 754
 755 SOCAT_USE_COMPRESS=
 756 AC_ARG_ENABLE([socat-compress],
 757   [AS_HELP_STRING([--enable-socat-compress],
 758     [use OpenSSL compression option available in patched socat builds
 759      (see INSTALL for details; default: detect automatically)])],
 760   [[if test "$enableval" = yes; then
 761       SOCAT_USE_COMPRESS=True
 762     else
 763       SOCAT_USE_COMPRESS=False
 764     fi
 765   ]])
 766
 767 if test -z "$SOCAT_USE_COMPRESS"
 768 then
 769   if $SOCAT -hhh | grep -w -q openssl-compress; then
 770     SOCAT_USE_COMPRESS=True
 771   else
 772     SOCAT_USE_COMPRESS=False
 773   fi
 774 fi
 775
 776 AC_SUBST(SOCAT_USE_COMPRESS)
 777
 778 if man --help | grep -q -e --warnings
 779 then
 780   MAN_HAS_WARNINGS=1
 781 else
 782   MAN_HAS_WARNINGS=
 783   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 784                             will not be possible]))
 785 fi
 786
 787 AC_SUBST(MAN_HAS_WARNINGS)
 788
 789 # Check for Python
 790 AM_PATH_PYTHON(2.4)
 791
 792 AC_PYTHON_MODULE(OpenSSL, t)
 793 AC_PYTHON_MODULE(simplejson, t)
 794 AC_PYTHON_MODULE(pyparsing, t)
 795 AC_PYTHON_MODULE(pyinotify, t)
 796 AC_PYTHON_MODULE(pycurl, t)
 797 AC_PYTHON_MODULE(bitarray, t)
 798 AC_PYTHON_MODULE(ipaddr, t)
 799 AC_PYTHON_MODULE(affinity)
 800 AC_PYTHON_MODULE(paramiko)
 801
 802 AC_CONFIG_FILES([ Makefile ])
 803
 804 AC_OUTPUT