code.grnet.gr Git - ganeti-local/blob - configure.ac

   1 # Configure script for Ganeti
   2 m4_define([gnt_version_major], [2])
   3 m4_define([gnt_version_minor], [9])
   4 m4_define([gnt_version_revision], [0])
   5 m4_define([gnt_version_suffix], [~alpha1])
   6 m4_define([gnt_version_full],
   7           m4_format([%d.%d.%d%s],
   8                     gnt_version_major, gnt_version_minor,
   9                     gnt_version_revision, gnt_version_suffix))
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT(ganeti, gnt_version_full, ganeti@googlegroups.com)
  13 AC_CONFIG_AUX_DIR(autotools)
  14 AC_CONFIG_SRCDIR(configure)
  15 AM_INIT_AUTOMAKE([1.9 foreign tar-ustar -Wall -Wno-portability])
  16
  17 AC_SUBST([VERSION_MAJOR], gnt_version_major)
  18 AC_SUBST([VERSION_MINOR], gnt_version_minor)
  19 AC_SUBST([VERSION_REVISION], gnt_version_revision)
  20 AC_SUBST([VERSION_SUFFIX], gnt_version_suffix)
  21 AC_SUBST([VERSION_FULL], gnt_version_full)
  22
  23 # --with-ssh-initscript=...
  24 AC_ARG_WITH([ssh-initscript],
  25   [AS_HELP_STRING([--with-ssh-initscript=SCRIPT],
  26     [SSH init script to use (default is /etc/init.d/ssh)]
  27   )],
  28   [ssh_initd_script="$withval"],
  29   [ssh_initd_script="/etc/init.d/ssh"])
  30 AC_SUBST(SSH_INITD_SCRIPT, $ssh_initd_script)
  31
  32 # --with-export-dir=...
  33 AC_ARG_WITH([export-dir],
  34   [AS_HELP_STRING([--with-export-dir=DIR],
  35     [directory to use by default for instance image]
  36     [ exports (default is /srv/ganeti/export)]
  37   )],
  38   [export_dir="$withval"],
  39   [export_dir="/srv/ganeti/export"])
  40 AC_SUBST(EXPORT_DIR, $export_dir)
  41
  42 # --with-ssh-config-dir=...
  43 AC_ARG_WITH([ssh-config-dir],
  44   [AS_HELP_STRING([--with-ssh-config-dir=DIR],
  45     [ directory with ssh host keys ]
  46     [ (default is /etc/ssh)]
  47   )],
  48   [ssh_config_dir="$withval"],
  49   [ssh_config_dir="/etc/ssh"])
  50 AC_SUBST(SSH_CONFIG_DIR, $ssh_config_dir)
  51
  52 # --with-xen-config-dir=...
  53 AC_ARG_WITH([xen-config-dir],
  54   [AS_HELP_STRING([--with-xen-config-dir=DIR],
  55                   m4_normalize([Xen configuration directory
  56                                 (default: /etc/xen)]))],
  57   [xen_config_dir="$withval"],
  58   [xen_config_dir=/etc/xen])
  59 AC_SUBST(XEN_CONFIG_DIR, $xen_config_dir)
  60
  61 # --with-os-search-path=...
  62 # do a bit of black sed magic to for quoting of the strings in the list
  63 AC_ARG_WITH([os-search-path],
  64   [AS_HELP_STRING([--with-os-search-path=LIST],
  65     [comma separated list of directories to]
  66     [ search for OS images (default is /srv/ganeti/os)]
  67   )],
  68   [os_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  69   [os_search_path="'/srv/ganeti/os'"])
  70 AC_SUBST(OS_SEARCH_PATH, $os_search_path)
  71
  72 # --with-extstorage-search-path=...
  73 # same black sed magic for quoting of the strings in the list
  74 AC_ARG_WITH([extstorage-search-path],
  75   [AS_HELP_STRING([--with-extstorage-search-path=LIST],
  76     [comma separated list of directories to]
  77     [ search for External Storage Providers]
  78     [ (default is /srv/ganeti/extstorage)]
  79   )],
  80   [es_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  81   [es_search_path="'/srv/ganeti/extstorage'"])
  82 AC_SUBST(ES_SEARCH_PATH, $es_search_path)
  83
  84 # --with-iallocator-search-path=...
  85 # do a bit of black sed magic to for quoting of the strings in the list
  86 AC_ARG_WITH([iallocator-search-path],
  87   [AS_HELP_STRING([--with-iallocator-search-path=LIST],
  88     [comma separated list of directories to]
  89     [ search for instance allocators (default is $libdir/ganeti/iallocators)]
  90   )],
  91   [iallocator_search_path=`echo -n "$withval" | sed -e "s/\([[^,]]*\)/'\1'/g"`],
  92   [iallocator_search_path="'$libdir/$PACKAGE_NAME/iallocators'"])
  93 AC_SUBST(IALLOCATOR_SEARCH_PATH, $iallocator_search_path)
  94
  95 # --with-xen-bootloader=...
  96 AC_ARG_WITH([xen-bootloader],
  97   [AS_HELP_STRING([--with-xen-bootloader=PATH],
  98     [bootloader for Xen hypervisor (default is empty)]
  99   )],
 100   [xen_bootloader="$withval"],
 101   [xen_bootloader=])
 102 AC_SUBST(XEN_BOOTLOADER, $xen_bootloader)
 103
 104 # --with-xen-kernel=...
 105 AC_ARG_WITH([xen-kernel],
 106   [AS_HELP_STRING([--with-xen-kernel=PATH],
 107     [DomU kernel image for Xen hypervisor (default is /boot/vmlinuz-3-xenU)]
 108   )],
 109   [xen_kernel="$withval"],
 110   [xen_kernel="/boot/vmlinuz-3-xenU"])
 111 AC_SUBST(XEN_KERNEL, $xen_kernel)
 112
 113 # --with-xen-initrd=...
 114 AC_ARG_WITH([xen-initrd],
 115   [AS_HELP_STRING([--with-xen-initrd=PATH],
 116     [DomU initrd image for Xen hypervisor (default is /boot/initrd-3-xenU)]
 117   )],
 118   [xen_initrd="$withval"],
 119   [xen_initrd="/boot/initrd-3-xenU"])
 120 AC_SUBST(XEN_INITRD, $xen_initrd)
 121
 122 # --with-kvm-kernel=...
 123 AC_ARG_WITH([kvm-kernel],
 124   [AS_HELP_STRING([--with-kvm-kernel=PATH],
 125     [Guest kernel image for KVM hypervisor (default is /boot/vmlinuz-3-kvmU)]
 126   )],
 127   [kvm_kernel="$withval"],
 128   [kvm_kernel="/boot/vmlinuz-3-kvmU"])
 129 AC_SUBST(KVM_KERNEL, $kvm_kernel)
 130
 131 # --with-file-storage-dir=...
 132 AC_ARG_WITH([file-storage-dir],
 133   [AS_HELP_STRING([--with-file-storage-dir=PATH],
 134     [directory to store files for file-based backend]
 135     [ (default is /srv/ganeti/file-storage)]
 136   )],
 137   [[file_storage_dir="$withval";
 138     if test "$withval" != no; then
 139       enable_file_storage=True
 140     else
 141       enable_file_storage=False
 142     fi
 143   ]],
 144   [[file_storage_dir="/srv/ganeti/file-storage";
 145     enable_file_storage=True]])
 146 AC_SUBST(FILE_STORAGE_DIR, $file_storage_dir)
 147 AC_SUBST(ENABLE_FILE_STORAGE, $enable_file_storage)
 148
 149 # --with-shared-file-storage-dir=...
 150 AC_ARG_WITH([shared-file-storage-dir],
 151   [AS_HELP_STRING([--with-shared-file-storage-dir=PATH],
 152     [directory to store files for shared file-based backend]
 153     [ (default is /srv/ganeti/shared-file-storage)]
 154   )],
 155   [[shared_file_storage_dir="$withval";
 156     if test "$withval" != no; then
 157       enable_shared_file_storage=True
 158     else
 159       enable_shared_file_storage=False
 160     fi
 161   ]],
 162   [[shared_file_storage_dir="/srv/ganeti/shared-file-storage";
 163     enable_shared_file_storage=True]])
 164 AC_SUBST(SHARED_FILE_STORAGE_DIR, $shared_file_storage_dir)
 165 AC_SUBST(ENABLE_SHARED_FILE_STORAGE, $enable_shared_file_storage)
 166
 167 # --with-kvm-path=...
 168 AC_ARG_WITH([kvm-path],
 169   [AS_HELP_STRING([--with-kvm-path=PATH],
 170     [absolute path to the kvm binary]
 171     [ (default is /usr/bin/kvm)]
 172   )],
 173   [kvm_path="$withval"],
 174   [kvm_path="/usr/bin/kvm"])
 175 AC_SUBST(KVM_PATH, $kvm_path)
 176
 177 # --with-lvm-stripecount=...
 178 AC_ARG_WITH([lvm-stripecount],
 179   [AS_HELP_STRING([--with-lvm-stripecount=NUM],
 180     [the default number of stripes to use for LVM volumes]
 181     [ (default is 1)]
 182   )],
 183   [lvm_stripecount="$withval"],
 184   [lvm_stripecount=1])
 185 AC_SUBST(LVM_STRIPECOUNT, $lvm_stripecount)
 186
 187 # --with-ssh-login-user=...
 188 AC_ARG_WITH([ssh-login-user],
 189   [AS_HELP_STRING([--with-ssh-login-user=USERNAME],
 190     [user to use for SSH logins within the cluster (default is root)]
 191   )],
 192   [ssh_login_user="$withval"],
 193   [ssh_login_user=root])
 194 AC_SUBST(SSH_LOGIN_USER, $ssh_login_user)
 195
 196 # --with-ssh-console-user=...
 197 AC_ARG_WITH([ssh-console-user],
 198   [AS_HELP_STRING([--with-ssh-console-user=USERNAME],
 199     [user to use for SSH logins to access instance consoles (default is root)]
 200   )],
 201   [ssh_console_user="$withval"],
 202   [ssh_console_user=root])
 203 AC_SUBST(SSH_CONSOLE_USER, $ssh_console_user)
 204
 205 # --with-default-user=...
 206 AC_ARG_WITH([default-user],
 207   [AS_HELP_STRING([--with-default-user=USERNAME],
 208     [default user for daemons]
 209     [ (default is to run all daemons as root)]
 210   )],
 211   [user_default="$withval"],
 212   [user_default=root])
 213
 214 # --with-default-group=...
 215 AC_ARG_WITH([default-group],
 216   [AS_HELP_STRING([--with-default-group=GROUPNAME],
 217     [default group for daemons]
 218     [ (default is to run all daemons under group root)]
 219   )],
 220   [group_default="$withval"],
 221   [group_default=root])
 222
 223 # --with-user-prefix=...
 224 AC_ARG_WITH([user-prefix],
 225   [AS_HELP_STRING([--with-user-prefix=PREFIX],
 226     [prefix for daemon users]
 227     [ (default is to run all daemons as root; use --with-default-user]
 228     [ to change the default)]
 229   )],
 230   [user_masterd="${withval}masterd";
 231    user_rapi="${withval}rapi";
 232    user_confd="${withval}confd";
 233    user_noded="$user_default";
 234    user_mond="$user_default"],
 235   [user_masterd="$user_default";
 236    user_rapi="$user_default";
 237    user_confd="$user_default";
 238    user_noded="$user_default";
 239    user_mond="$user_default"])
 240 AC_SUBST(MASTERD_USER, $user_masterd)
 241 AC_SUBST(RAPI_USER, $user_rapi)
 242 AC_SUBST(CONFD_USER, $user_confd)
 243 AC_SUBST(NODED_USER, $user_noded)
 244 AC_SUBST(MOND_USER, $user_mond)
 245
 246 # --with-group-prefix=...
 247 AC_ARG_WITH([group-prefix],
 248   [AS_HELP_STRING([--with-group-prefix=PREFIX],
 249     [prefix for daemon POSIX groups]
 250     [ (default is to run all daemons under group root; use]
 251     [ --with-default-group to change the default)]
 252   )],
 253   [group_rapi="${withval}rapi";
 254    group_admin="${withval}admin";
 255    group_confd="${withval}confd";
 256    group_masterd="${withval}masterd";
 257    group_noded="$group_default";
 258    group_daemons="${withval}daemons";
 259    group_mond="$group_default"],
 260   [group_rapi="$group_default";
 261    group_admin="$group_default";
 262    group_confd="$group_default";
 263    group_masterd="$group_default";
 264    group_noded="$group_default";
 265    group_daemons="$group_default";
 266    group_mond="$group_default"])
 267 AC_SUBST(RAPI_GROUP, $group_rapi)
 268 AC_SUBST(ADMIN_GROUP, $group_admin)
 269 AC_SUBST(CONFD_GROUP, $group_confd)
 270 AC_SUBST(MASTERD_GROUP, $group_masterd)
 271 AC_SUBST(NODED_GROUP, $group_noded)
 272 AC_SUBST(DAEMONS_GROUP, $group_daemons)
 273 AC_SUBST(MOND_GROUP, $group_mond)
 274
 275 # Print the config to the user
 276 AC_MSG_NOTICE([Running ganeti-masterd as $group_masterd:$group_masterd])
 277 AC_MSG_NOTICE([Running ganeti-rapi as $user_rapi:$group_rapi])
 278 AC_MSG_NOTICE([Running ganeti-confd as $user_confd:$group_confd])
 279 AC_MSG_NOTICE([Group for daemons is $group_daemons])
 280 AC_MSG_NOTICE([Group for clients is $group_admin])
 281
 282 # --enable-drbd-barriers
 283 AC_ARG_ENABLE([drbd-barriers],
 284   [AS_HELP_STRING([--enable-drbd-barriers],
 285                   m4_normalize([enable the DRBD barriers functionality by
 286                                 default (>= 8.0.12) (default: enabled)]))],
 287   [[if test "$enableval" != no; then
 288       DRBD_BARRIERS=n
 289       DRBD_NO_META_FLUSH=False
 290     else
 291       DRBD_BARRIERS=bf
 292       DRBD_NO_META_FLUSH=True
 293     fi
 294   ]],
 295   [DRBD_BARRIERS=n
 296    DRBD_NO_META_FLUSH=False
 297   ])
 298 AC_SUBST(DRBD_BARRIERS, $DRBD_BARRIERS)
 299 AC_SUBST(DRBD_NO_META_FLUSH, $DRBD_NO_META_FLUSH)
 300
 301 # --enable-syslog[=no/yes/only]
 302 AC_ARG_ENABLE([syslog],
 303   [AS_HELP_STRING([--enable-syslog],
 304     [enable use of syslog (default: disabled), one of no/yes/only])],
 305   [[case "$enableval" in
 306       no)
 307         SYSLOG=no
 308         ;;
 309       yes)
 310         SYSLOG=yes
 311         ;;
 312       only)
 313         SYSLOG=only
 314         ;;
 315       *)
 316         SYSLOG=
 317         ;;
 318     esac
 319   ]],
 320   [SYSLOG=no])
 321
 322 if test -z "$SYSLOG"
 323 then
 324   AC_MSG_ERROR([invalid value for syslog, choose one of no/yes/only])
 325 fi
 326 AC_SUBST(SYSLOG_USAGE, $SYSLOG)
 327
 328 AC_ARG_ENABLE([restricted-commands],
 329   [AS_HELP_STRING([--enable-restricted-commands],
 330                   m4_normalize([enable restricted commands in the node daemon
 331                                 (default: disabled)]))],
 332   [[if test "$enableval" = no; then
 333       enable_restricted_commands=False
 334     else
 335       enable_restricted_commands=True
 336     fi
 337   ]],
 338   [enable_restricted_commands=False])
 339 AC_SUBST(ENABLE_RESTRICTED_COMMANDS, $enable_restricted_commands)
 340
 341 # --with-disk-separator=...
 342 AC_ARG_WITH([disk-separator],
 343   [AS_HELP_STRING([--with-disk-separator=STRING],
 344     [Disk index separator, useful if the default of ':' is handled]
 345     [ specially by the hypervisor]
 346   )],
 347   [disk_separator="$withval"],
 348   [disk_separator=":"])
 349 AC_SUBST(DISK_SEPARATOR, $disk_separator)
 350
 351 # Check common programs
 352 AC_PROG_INSTALL
 353 AC_PROG_LN_S
 354
 355 # Check for the ip command
 356 AC_ARG_VAR(IP_PATH, [ip path])
 357 AC_PATH_PROG(IP_PATH, [ip], [])
 358 if test -z "$IP_PATH"
 359 then
 360   AC_MSG_ERROR([ip command not found])
 361 fi
 362
 363 # Check for pandoc
 364 AC_ARG_VAR(PANDOC, [pandoc path])
 365 AC_PATH_PROG(PANDOC, [pandoc], [])
 366 if test -z "$PANDOC"
 367 then
 368   AC_MSG_WARN([pandoc not found, man pages rebuild will not be possible])
 369 fi
 370
 371 # Check for python-sphinx
 372 AC_ARG_VAR(SPHINX, [sphinx-build path])
 373 AC_PATH_PROG(SPHINX, [sphinx-build], [])
 374 if test -z "$SPHINX"
 375 then
 376   AC_MSG_WARN(m4_normalize([sphinx-build not found, documentation rebuild will
 377                             not be possible]))
 378 else
 379   # Sphinx exits with code 1 when it prints its usage
 380   sphinxver=`{ $SPHINX --version 2>&1 || :; } | head -n 3`
 381
 382   if ! echo "$sphinxver" | grep -q -w -e '^Sphinx' -e '^Usage:'; then
 383     AC_MSG_ERROR([Unable to determine Sphinx version])
 384
 385   # Note: Character classes ([...]) need to be double quoted due to autoconf
 386   # using m4
 387   elif ! echo "$sphinxver" | grep -q -E '^Sphinx[[[:space:]]]+v[[1-9]]\>'; then
 388     AC_MSG_ERROR([Sphinx 1.0 or higher is required])
 389   fi
 390 fi
 391
 392 AC_ARG_ENABLE([manpages-in-doc],
 393   [AS_HELP_STRING([--enable-manpages-in-doc],
 394                   m4_normalize([include man pages in HTML documentation
 395                                 (requires sphinx; default disabled)]))],
 396   [case "$enableval" in
 397       yes) manpages_in_doc=yes ;;
 398       no) manpages_in_doc= ;;
 399       *)
 400         AC_MSG_ERROR([Bad value $enableval for --enable-manpages-in-doc])
 401         ;;
 402     esac
 403   ],
 404   [manpages_in_doc=])
 405 AM_CONDITIONAL([MANPAGES_IN_DOC], [test -n "$manpages_in_doc"])
 406 AC_SUBST(MANPAGES_IN_DOC, $manpages_in_doc)
 407
 408 if test -z "$SPHINX" -a -n "$manpages_in_doc"; then
 409   AC_MSG_ERROR([Including man pages in HTML documentation requires sphinx])
 410 fi
 411
 412 # Check for graphviz (dot)
 413 AC_ARG_VAR(DOT, [dot path])
 414 AC_PATH_PROG(DOT, [dot], [])
 415 if test -z "$DOT"
 416 then
 417   AC_MSG_WARN(m4_normalize([dot (from the graphviz suite) not found,
 418                             documentation rebuild not possible]))
 419 fi
 420
 421 # Check for pylint
 422 AC_ARG_VAR(PYLINT, [pylint path])
 423 AC_PATH_PROG(PYLINT, [pylint], [])
 424 if test -z "$PYLINT"
 425 then
 426   AC_MSG_WARN([pylint not found, checking code will not be possible])
 427 fi
 428
 429 # Check for pep8
 430 AC_ARG_VAR(PEP8, [pep8 path])
 431 AC_PATH_PROG(PEP8, [pep8], [])
 432 if test -z "$PEP8"
 433 then
 434   AC_MSG_WARN([pep8 not found, checking code will not be complete])
 435 fi
 436 AM_CONDITIONAL([HAS_PEP8], [test -n "$PEP8"])
 437
 438 # Check for python-coverage
 439 AC_ARG_VAR(PYCOVERAGE, [python-coverage path])
 440 AC_PATH_PROGS(PYCOVERAGE, [python-coverage coverage], [])
 441 if test -z "$PYCOVERAGE"
 442 then
 443   AC_MSG_WARN(m4_normalize([python-coverage or coverage not found, evaluating
 444                             Python test coverage will not be possible]))
 445 fi
 446
 447 # Check for socat
 448 AC_ARG_VAR(SOCAT, [socat path])
 449 AC_PATH_PROG(SOCAT, [socat], [])
 450 if test -z "$SOCAT"
 451 then
 452   AC_MSG_ERROR([socat not found])
 453 fi
 454
 455 # Check for qemu-img
 456 AC_ARG_VAR(QEMUIMG_PATH, [qemu-img path])
 457 AC_PATH_PROG(QEMUIMG_PATH, [qemu-img], [])
 458 if test -z "$QEMUIMG_PATH"
 459 then
 460   AC_MSG_WARN([qemu-img not found, using ovfconverter will not be possible])
 461 fi
 462
 463 # --enable-confd
 464 ENABLE_CONFD=
 465 AC_ARG_ENABLE([confd],
 466   [AS_HELP_STRING([--enable-confd],
 467   [enable the ganeti-confd daemon (default: check)])],
 468   [],
 469   [enable_confd=check])
 470
 471 ENABLE_MOND=
 472 AC_ARG_ENABLE([monitoring],
 473   [AS_HELP_STRING([--enable-monitoring],
 474   [enable the ganeti monitoring daemon (default: check)])],
 475   [],
 476   [enable_monitoring=check])
 477
 478 # Check for ghc
 479 AC_ARG_VAR(GHC, [ghc path])
 480 AC_PATH_PROG(GHC, [ghc], [])
 481 if test -z "$GHC"; then
 482   AC_MSG_FAILURE([ghc not found, compilation will not possible])
 483 fi
 484
 485 AC_MSG_CHECKING([checking for extra GHC flags])
 486 GHC_BYVERSION_FLAGS=
 487 # check for GHC supported flags that vary accross versions
 488 for flag in -fwarn-incomplete-uni-patterns; do
 489   if $GHC -e '0' $flag >/dev/null 2>/dev/null; then
 490    GHC_BYVERSION_FLAGS="$GHC_BYVERSION_FLAGS $flag"
 491   fi
 492 done
 493 AC_MSG_RESULT($GHC_BYVERSION_FLAGS)
 494 AC_SUBST(GHC_BYVERSION_FLAGS)
 495
 496 # Check for ghc-pkg
 497 AC_ARG_VAR(GHC_PKG, [ghc-pkg path])
 498 AC_PATH_PROG(GHC_PKG, [ghc-pkg], [])
 499 if test -z "$GHC_PKG"; then
 500   AC_MSG_FAILURE([ghc-pkg not found, compilation will not be possible])
 501 fi
 502
 503 # check for modules, first custom/special checks
 504 AC_MSG_NOTICE([checking for required haskell modules])
 505 HS_PARALLEL3=
 506 AC_GHC_PKG_CHECK([parallel-3.*], [HS_PARALLEL3=-DPARALLEL3],
 507                  [AC_GHC_PKG_REQUIRE(parallel)], t)
 508 AC_SUBST(HS_PARALLEL3)
 509
 510 # and now standard modules
 511 AC_GHC_PKG_REQUIRE(curl)
 512 AC_GHC_PKG_REQUIRE(json)
 513 AC_GHC_PKG_REQUIRE(network)
 514 AC_GHC_PKG_REQUIRE(mtl)
 515 AC_GHC_PKG_REQUIRE(bytestring)
 516 AC_GHC_PKG_REQUIRE(utf8-string)
 517
 518 # extra modules for confd functionality
 519 HS_REGEX_PCRE=-DNO_REGEX_PCRE
 520 has_confd=False
 521 if test "$enable_confd" != no; then
 522   CONFD_PKG=
 523   AC_GHC_PKG_CHECK([regex-pcre], [HS_REGEX_PCRE=],
 524                    [CONFD_PKG="$CONFD_PKG regex-pcre"])
 525   AC_GHC_PKG_CHECK([hslogger], [], [CONFD_PKG="$CONFD_PKG hslogger"])
 526   AC_GHC_PKG_CHECK([Crypto], [], [CONFD_PKG="$CONFD_PKG Crypto"])
 527   AC_GHC_PKG_CHECK([text], [], [CONFD_PKG="$CONFD_PKG text"])
 528   AC_GHC_PKG_CHECK([hinotify], [], [CONFD_PKG="$CONFD_PKG hinotify"])
 529   AC_GHC_PKG_CHECK([vector], [], [CONFD_PKG="$CONFD_PKG vector"])
 530   if test -z "$CONFD_PKG"; then
 531     has_confd=True
 532   elif test "$enable_confd" = check; then
 533     AC_MSG_WARN(m4_normalize([The required extra libraries for confd were
 534                               not found ($CONFD_PKG), confd disabled]))
 535   else
 536     AC_MSG_FAILURE(m4_normalize([The confd functionality was requested, but
 537                                  required libraries were not found:
 538                                  $CONFD_PKG]))
 539   fi
 540 fi
 541 AC_SUBST(HS_REGEX_PCRE)
 542 if test "$has_confd" = True; then
 543   AC_MSG_NOTICE([Enabling confd usage])
 544 fi
 545 AC_SUBST(ENABLE_CONFD, $has_confd)
 546 AM_CONDITIONAL([ENABLE_CONFD], [test x$has_confd = xTrue])
 547
 548 #extra modules for monitoring daemon functionality
 549 has_monitoring=False
 550 if test "$enable_monitoring" != no; then
 551   MONITORING_PKG=
 552   AC_GHC_PKG_CHECK([attoparsec], [],
 553                    [MONITORING_PKG="$MONITORING_PKG attoparsec"])
 554   AC_GHC_PKG_CHECK([snap-server], [],
 555                    [MONITORING_PKG="$MONITORING_PKG snap-server"])
 556   AC_GHC_PKG_CHECK([process], [],
 557                    [MONITORING_PKG="$MONITORING_PKG process"])
 558   MONITORING_DEP=
 559   if test "$has_confd" = False; then
 560     MONITORING_DEP="$MONITORING_DEP confd"
 561   fi
 562   has_monitoring_pkg=False
 563   if test -z "$MONITORING_PKG"; then
 564     has_monitoring_pkg=True
 565   elif test "$enable_monitoring" = check; then
 566     AC_MSG_WARN(m4_normalize([The required extra libraries for the monitoring
 567                               daemon were not found ($MONITORING_PKG),
 568                               monitoring disabled]))
 569   else
 570     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 571                                  required libraries were not found:
 572                                  $MONITORING_PKG]))
 573   fi
 574   has_monitoring_dep=False
 575   if test -z "$MONITORING_DEP"; then
 576     has_monitoring_dep=True
 577   elif test "$enable_monitoring" = check; then
 578     AC_MSG_WARN(m4_normalize([The optional Ganeti components required for the
 579                               monitoring agent were not enabled
 580                               ($MONITORING_DEP), monitoring disabled]))
 581   else
 582     AC_MSG_FAILURE(m4_normalize([The monitoring functionality was requested, but
 583                                  required optional Ganeti components were not
 584                                  found: $MONITORING_DEP]))
 585   fi
 586
 587 fi
 588 if test "$has_monitoring_pkg" = True -a "$has_monitoring_dep" = True; then
 589   has_monitoring=True
 590   AC_MSG_NOTICE([Enabling the monitoring agent usage])
 591 fi
 592 AC_SUBST(ENABLE_MOND, $has_monitoring)
 593 AM_CONDITIONAL([ENABLE_MOND], [test "$has_monitoring" = True])
 594
 595 # development modules
 596 HS_NODEV=
 597 AC_GHC_PKG_CHECK([QuickCheck-2.*], [], [HS_NODEV=1], t)
 598 AC_GHC_PKG_CHECK([test-framework-0.6*], [], [HS_NODEV=1], t)
 599 AC_GHC_PKG_CHECK([test-framework-hunit], [], [HS_NODEV=1])
 600 AC_GHC_PKG_CHECK([test-framework-quickcheck2], [], [HS_NODEV=1])
 601 AC_GHC_PKG_CHECK([temporary], [], [HS_NODEV=1])
 602 # FIXME: unify checks for non-test libraries (attoparsec, hinotify, ...)
 603 #        that are needed to execute the tests, avoiding the duplication
 604 #        of the checks.
 605 AC_GHC_PKG_CHECK([attoparsec], [], [HS_NODEV=1])
 606 AC_GHC_PKG_CHECK([vector], [], [HS_NODEV=1])
 607 AC_GHC_PKG_CHECK([process], [],
 608                  [MONITORING_PKG="$MONITORING_PKG process"])
 609 if test -n "$HS_NODEV"; then
 610    AC_MSG_WARN(m4_normalize([Required development modules were not found,
 611                              you won't be able to run Haskell unittests]))
 612 else
 613    AC_MSG_NOTICE([Haskell development modules found, unittests enabled])
 614 fi
 615 AC_SUBST(HS_NODEV)
 616
 617 HTOOLS=yes
 618 AC_SUBST(HTOOLS)
 619
 620 # --enable-split-query
 621 ENABLE_SPLIT_QUERY=
 622 AC_ARG_ENABLE([split-query],
 623   [AS_HELP_STRING([--enable-split-query],
 624   [enable use of custom query daemon via confd])],
 625   [[case "$enableval" in
 626       no)
 627         enable_split_query=False
 628         ;;
 629       yes)
 630         enable_split_query=True
 631         ;;
 632       *)
 633         echo "Invalid value for enable-confd '$enableval'"
 634         exit 1
 635         ;;
 636     esac
 637   ]],
 638   [[case "x${has_confd}x" in
 639      xTruex)
 640        enable_split_query=True
 641        ;;
 642      *)
 643        enable_split_query=False
 644        ;;
 645    esac]])
 646 AC_SUBST(ENABLE_SPLIT_QUERY, $enable_split_query)
 647
 648 if test x$enable_split_query = xTrue -a x$has_confd != xTrue; then
 649   AC_MSG_ERROR([Split queries require the confd daemon])
 650 fi
 651
 652 if test x$enable_split_query = xTrue; then
 653   AC_MSG_NOTICE([Split query functionality enabled])
 654 fi
 655
 656 # Check for HsColour
 657 HS_APIDOC=no
 658 AC_ARG_VAR(HSCOLOUR, [HsColour path])
 659 AC_PATH_PROG(HSCOLOUR, [HsColour], [])
 660 if test -z "$HSCOLOUR"; then
 661   AC_MSG_WARN(m4_normalize([HsColour not found, htools API documentation will
 662                             not be generated]))
 663 fi
 664
 665 # Check for haddock
 666 AC_ARG_VAR(HADDOCK, [haddock path])
 667 AC_PATH_PROG(HADDOCK, [haddock], [])
 668 if test -z "$HADDOCK"; then
 669   AC_MSG_WARN(m4_normalize([haddock not found, htools API documentation will
 670                             not be generated]))
 671 fi
 672 if test -n "$HADDOCK" && test -n "$HSCOLOUR"; then
 673   HS_APIDOC=yes
 674 fi
 675 AC_SUBST(HS_APIDOC)
 676
 677 # Check for hlint
 678 AC_ARG_VAR(HLINT, [hlint path])
 679 AC_PATH_PROG(HLINT, [hlint], [])
 680 if test -z "$HLINT"; then
 681   AC_MSG_WARN([hlint not found, checking code will not be possible])
 682 fi
 683
 684 if test "$HTOOLS" != yes && test "$ENABLE_CONFD" = True; then
 685   AC_MSG_ERROR(m4_normalize([cannot enable ganeti-confd if
 686                              htools support is not enabled]))
 687 fi
 688
 689 AM_CONDITIONAL([WANT_HTOOLS], [test "$HTOOLS" = yes])
 690 AM_CONDITIONAL([WANT_HSTESTS], [test "x$HS_NODEV" = x])
 691 AM_CONDITIONAL([WANT_HSAPIDOC], [test "$HS_APIDOC" = yes])
 692 AM_CONDITIONAL([HAS_HLINT], [test "$HLINT"])
 693
 694 # Check for fakeroot
 695 AC_ARG_VAR(FAKEROOT_PATH, [fakeroot path])
 696 AC_PATH_PROG(FAKEROOT_PATH, [fakeroot], [])
 697 if test -z "$FAKEROOT_PATH"; then
 698   AC_MSG_WARN(m4_normalize([fakeroot not found, tests that must run as root
 699                             will not be executed]))
 700 fi
 701 AM_CONDITIONAL([HAS_FAKEROOT], [test "x$FAKEROOT_PATH" != x])
 702
 703 SOCAT_USE_ESCAPE=
 704 AC_ARG_ENABLE([socat-escape],
 705   [AS_HELP_STRING([--enable-socat-escape],
 706     [use escape functionality available in socat >= 1.7 (default: detect
 707      automatically)])],
 708   [[if test "$enableval" = yes; then
 709       SOCAT_USE_ESCAPE=True
 710     else
 711       SOCAT_USE_ESCAPE=False
 712     fi
 713   ]])
 714
 715 if test -z "$SOCAT_USE_ESCAPE"
 716 then
 717   if $SOCAT -hh | grep -w -q escape; then
 718     SOCAT_USE_ESCAPE=True
 719   else
 720     SOCAT_USE_ESCAPE=False
 721   fi
 722 fi
 723
 724 AC_SUBST(SOCAT_USE_ESCAPE)
 725
 726 SOCAT_USE_COMPRESS=
 727 AC_ARG_ENABLE([socat-compress],
 728   [AS_HELP_STRING([--enable-socat-compress],
 729     [use OpenSSL compression option available in patched socat builds
 730      (see INSTALL for details; default: detect automatically)])],
 731   [[if test "$enableval" = yes; then
 732       SOCAT_USE_COMPRESS=True
 733     else
 734       SOCAT_USE_COMPRESS=False
 735     fi
 736   ]])
 737
 738 if test -z "$SOCAT_USE_COMPRESS"
 739 then
 740   if $SOCAT -hhh | grep -w -q openssl-compress; then
 741     SOCAT_USE_COMPRESS=True
 742   else
 743     SOCAT_USE_COMPRESS=False
 744   fi
 745 fi
 746
 747 AC_SUBST(SOCAT_USE_COMPRESS)
 748
 749 if man --help | grep -q -e --warnings
 750 then
 751   MAN_HAS_WARNINGS=1
 752 else
 753   MAN_HAS_WARNINGS=
 754   AC_MSG_WARN(m4_normalize([man does not support --warnings, man page checks
 755                             will not be possible]))
 756 fi
 757
 758 AC_SUBST(MAN_HAS_WARNINGS)
 759
 760 # Check for Python
 761 AM_PATH_PYTHON(2.6)
 762
 763 AC_PYTHON_MODULE(OpenSSL, t)
 764 AC_PYTHON_MODULE(simplejson, t)
 765 AC_PYTHON_MODULE(pyparsing, t)
 766 AC_PYTHON_MODULE(pyinotify, t)
 767 AC_PYTHON_MODULE(pycurl, t)
 768 AC_PYTHON_MODULE(bitarray, t)
 769 AC_PYTHON_MODULE(ipaddr, t)
 770 AC_PYTHON_MODULE(yaml, t)
 771 AC_PYTHON_MODULE(mock)
 772 AC_PYTHON_MODULE(affinity)
 773 AC_PYTHON_MODULE(paramiko)
 774
 775 AC_CONFIG_FILES([ Makefile ])
 776
 777 AC_OUTPUT